Office: (Office 2013) Nummerierung automatisch anpassen bei löschen einer Zeile

aloys78 · 10. März 2016

Hallo Alex,

hier folgt der 2. Teil, der die Neu-Nummerierung durchführt. Am besten in einem eigenen Modul ablegen.
Es wird vorausgesetzt, dass die Nummerierung aufsteigend und konsistent ist; in dieser Richtung wird keine Plausibilitätsprüfung durchgeführt.
Im Code habe ich ein paar Bemerkungen eingefügt.
Zum grundsätzlichen Verständnis:

Deine Löschroutine wurde ergänzt (siehe vorhergehenden Beitrag). Nach dem Löschen einer Zeile bzw Zeilengruppe wird die Neu_Nummerierung aufgerufen, wobei übergeben werden: Kategorie, Zeilen# der ersten gelöschten Zeile sowie der Key aus Sp A für diese erste Zeile.
In Neu-Nummerierung werden die anzupassenden Zeilen identifiziert und die anzupassende Nummer einfach um 1 vermindert.

Gruß
Aloys
Code:

Option Explicit

Dim LoL As Long 'Zeilen# letzte Eintragung
Dim sKey As String 'zu untersuchender Key
Dim sKeyNext As String 'geänderter Key
Dim nPt As Long 'Anzahl Punkte im Key
Dim iAnzahl As Long 'Anzahl Zahlen im Key
Dim nArr As Long 'maximale Größe Array
Dim na As Long 'Index letzter Eintrag in arr
Dim iPos As Long 'Ergebnis instr-Funktion
Dim z As Long 'Zeilen#
Dim arr() As Long 'Array zur Zerlegung des Keys
Dim a1 As Long, a2 As Long 'Indices arr
Dim i As Long, j As Long 'Schleifenzähler
Dim iStart As Long 'Start-Adresse für inst-Funktion
Dim iVAnzahl As Long 'Anzahl Zahlen für Vergleich
Dim swF As Boolean 'Schalter, True = aktueller Key passt nicht zu vorhergehendem

Sub Neu_Nummerierung(Kategorie As String, ZeilenNr As Long, sKeyOld)
'===================================================================================
' Steuerung der Key-Anpassung nach dem Löschen einer Zeile bzw Zeilengruppe
' Grundlage ist der gelöschte Key; bei n Zahlen bilden die ersten n-1 Zahlen den
' Vergleichsbegriff für alle nachfolgend noch vorhandenen Zahlenausdrücke.
' Diese werden in einzelne Zahlen aufgesplittet und in einem Array gespeichert;
' die letzte Zahl des gelöschten Keys gibt die Position der folgenden Keys für die Anpassung
' vor
'
' Übergabe aus der Löschroutine
' Kategorie = Name Tabellenblatt
' ZeilenNr = Zeilen# des gelöschten Key / des ersten gelöschten Key einer
' Zeilengruppe
' sKeyOld = der gelöschte (erste) Key
'
' Ergebnis
' die der gelöschten Zeile folgenden Zeilen sind Nummern-mäßig angepasst
'===================================================================================

'Initialisieren
With Worksheets(Kategorie)
'Initialisierung
LoL = .Cells(Rows.Count, "A").End(xlUp).Row 'Zeilen# der letzten Eintragung
nArr = LoL - iAnzahl + 1 'max. Anzahl Zeilen des Arrays
sKeyNext = "" 'Ergebnis - der angepasste Key

'Strukturdaten aus gelöschtem Key ableiten
sKey = sKeyOld 'der gelöschte Key
a1 = 0 'erste Zeile im Array
Call Split_Nummer 'splitte Key auf in Zahlen

'auf Basis der Strukturdaten alle der Struktur entsprechenden folgenden Keys in arr speichern
For z = ZeilenNr To LoL 'maximla Umfang: Position gelöschte Zeile bis zum Ende
sKey = .Range("A" & z) 'aktueller Key
a1 = a1 + 1 'nächster Index 1 im Array
Call Split_Nummer 'speichere Key in Array
If swF = True Then Exit For 'alle zutreffenden Keys wurden in Array gespeichert
Next z

'Nummern anpassen
i = iVAnzahl + 1 'position der anzupassenden Zahl in den Keys
For a1 = 1 To na 'alle diese Ausdrücke im Array werden verändert, indem
arr(a1, i) = arr(a1, i) - 1 'die Zahl an dieser Position um 1 vermindert wird
Next

'Keys in Tabelle ausgeben
z = ZeilenNr 'Position des gelöschten Keys = 1. Position der folgenden Keys
Application.ScreenUpdating = False
For a1 = 1 To na
sKeyNext = "'" 'angepasste Keys als Text speichern
For i = 1 To arr(a1, 0)
sKeyNext = sKeyNext & arr(a1, i) & IIf(i < arr(a1, 0), ".", "") 'Key zusammensetzen
Next i
.Range("A" & z) = sKeyNext 'Key asugeben
z = z + 1
Next a1
Application.ScreenUpdating = True
End With

'Programm abgeschlossen
MsgBox "Anpassung ist abgeschlossen !", vbInformation
End Sub

Sub Split_Nummer()
'===================================================================================
' Aufsplitten des Keys in die einzelnen Zahlenbestandteile
' Ein vorangestelltes Hochkomma wird entfernt, und die einelnen Zahlen
' in einem Array abgelegt.
' Bespiel: '5.2.2 wurde gelöscht
' Vergleichsbegriffs für nachfolgende Keys ist 5.2; alle nachfolgenden Keys, die
' mit diesem Vergleichsbegriff beginnen, werden im Array gespeichert und
' anschließend angepasst.

' Array arr(0 to n, 0 to 3)
' arr(0,0) = 3 'Anzahl Zahlen gelöschter Key
' arr(0,1) = 5 'Aufteilung des Ausdrucks auf die Spalten des Arrays
' arr(0,2) = 2
' arr(0,3) = 2
'
' arr(1,0) = 3 'Anzahl Zahlen des ersten folgenden Keys 5.2.3
' arr(1,1) = 5
' arr(1,2) = 2
' arr(1,3) = 3

' arr(2,x) 'nach gleichem System Abbildung von 5.2.4
' arr(3,x) 'und 5.2.5

' Übergabe-Parameter
' sKey = zu untersuchender Key
' a1 = Index 1 (0 = gelöschter Key, > 0: einer der folgenden Keys
'
' Rückgabe
' arrK(a1) = aktuell aufgeteilter Key in Array nach vorstehendem Muster
'===================================================================================

'Anzahl Trennzeichen (Punkte) im Key) ermitteln
sKey = WorksheetFunction.Substitute(sKey, "'", "") 'übergebener Key
nPt = Len(sKey) - Len(WorksheetFunction.Substitute(sKey, ".", "")) 'Anzahl Punkte im Key

'Aktion beim ersten Aufruf (Grundlage ist der gelöschte Key)
If a1 = 0 Then
iVAnzahl = nPt 'Anzahl Zahlen für Vergleich mit den nachfolgenden Keys
ReDim arr(0 To nArr, 0 To nPt + 1) 'Start-Struktur Array
End If

'Vorbereitung für aktuellen Key
i = nPt + 1 'Anzahl Zahlen des aktuellen Key
If i > UBound(arr, 2) Then ReDim Preserve arr(0 To nArr, 0 To i) '2. Dimension bei längeren Keys anpassen
arr(a1, 0) = i 'Anzahl Zahlen im Key
iStart = 1 'Start-Position

'Split Key und speichern Bestandteile in arr
For j = 1 To nPt
iPos = InStr(iStart, sKey, ".")
If iPos > 0 Then
arr(a1, j) = CLng(Mid(sKey, iStart, iPos - iStart)) 'speichere Key-Bestandteil als Zahl
iStart = iPos + 1
Else 'dürfte nie vorkommen
MsgBox "Key '" & sKey & "'" & "Split-Fehler !", vbCritical
Exit Sub
End If
Next j

'die Zahl nach dem letzten Punkt
arr(a1, i) = CLng(Right(sKey, Len(sKey) - iStart + 1)) 'Letzter Teil
na = a1 'Anzahl der anzupassenden Ausdrücke
If a1 = 0 Then GoTo Ende 'beim 1. Key (der gelöschte) ist hier das Ende

'check, ob aktueller Key noch zur Vegleichsgruppe passt
swF = False 'Grundstellung: kein Fehler
For i = 1 To iVAnzahl 'von links beginnend werden alle Bestandteile des Vergleichsbegriffs verglichen
If arr(a1, i) = arr(0, i) Then 'Zahl aus aktuellem Ausdruck mit entsprechender Position des gelöschten Keys vergleichen
'keine Aktion
Else
swF = True 'keine Deckungsgleichheit über alle Zahlen des Vergleich begriffes
Exit For
End If
Next i

If swF = True Then na = na - 1 'Gesamtzahl der anzupassenden Zahlen korrigieren
Ende:
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

chin842 · 10. März 2016

Hey Aloys,

WOW!! Bin begeistert und mit mega der guten Kommentierung.
Gruß und 1000 Dank!

Alex

Edit: Was mir aufgefallen ist, wenn man jetzt über die Userform Inhalte löscht, wird dieses nicht im Changelog protokolliert, woran liegt das? (Bei Eingabe über die Userform wird das protokolliert)

aloys78 · 10. März 2016

Hallo Alex,

ich habe es überwiegend über eine Schnittstellen-Simulation getestet:
- Daten manuell gelöscht
- Code mit den 3 Parametern Kategorie, Zeilen# und gelöschter Schlüssel aufgerufen, bis mein Code funktionierte.

Im zweiten Schritt bin ich, wie von Dir beschrieben, über Deine von mir angepasste Löschfunktion vorgegangen; funktionierte mit Deiner Beispieldatei einwandfrei.

Fragen:
- Kommt die Nachricht "Anpassung ist abgeschlossen" ?
- tritt es bei allen Löschoperationen auf, oder nur bei bestimmten Konstellationen ?

Gruß
Aloys

aloys78 · 10. März 2016

Hallo Alex,

Edit: Was mir aufgefallen ist, wenn man jetzt über die Userform Inhalte löscht, wird dieses nicht im Changelog protokolliert, woran liegt das? (Bei Eingabe über die Userform wird das protokolliert)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich sehe im Moment da keinen Zusammenhang; aber Du kannst mal in der Löschroutine die Anweisung Call Neu_Nummerierung ...
versuchsweise auskommentieren.

Gruß
Aloys

chin842 · 11. März 2016

Hey Aloys,

er erfasst allg. nicht die Einträge, die über eine Userform gelöscht werden.

Was mir aufgefallen ist, wenn ich einen letzten Punkt in einer Tabelle lösche, hängt sich Excel auf, Meldung Msgbox kommt nicht. (Lässt sich beenden, "rechtsclick" auf Excel in der Taskleiste, nicht speichern, dann hat sich Excel gefangen... scheint wohl Excel bleibt dann in einer Schleife hängen).
Hab auf die schnelle noch nicht schauen können ,wo er hängen bleiben könnte im Code von Dir.

Code Changelog:

Code:

Dim vOldVal

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim bBold As Boolean

If Target.Cells.Count > 1 Or Sh.name = "PM" Then Exit Sub
On Error Resume Next
If Not Intersect(Target, Range("B:B")) Is Nothing Then
Application.EnableEvents = False

With Application
.ScreenUpdating = False
.EnableEvents = False
End With

If IsEmpty(vOldVal) Then vOldVal = "Leere Zelle"
bBold = Target.HasFormula
With Sheets("Changelog")
.Unprotect Password:="Secret"
If .Range("A1") = vbNullString Then
.Range("A1:G1") = Array("Veränderte Zelle", "Verändertes Arbeitsblatt", "Alter Inhalt", _
"Neuer Inhalt", "Änderungszeit", "Änderungsdatum", "Benutzer")
End If
With .Cells(.Rows.Count, 1).End(xlUp)(2, 1)
.Value = Target.Address
.Offset(0, 1) = Sh.name
.Offset(0, 2) = vOldVal
With .Offset(0, 3)
.Value = Target
.Font.Bold = bBold
End With

.Offset(0, 4) = Time
.Offset(0, 5) = Date
.Offset(0, 6) = Application.UserName

End With
.Cells.Columns.AutoFit
.Protect Password:="Secret"
End With
vOldVal = vbNullString

With Application
.ScreenUpdating = True
.EnableEvents = True
End With
On Error GoTo 0
End If
Application.EnableEvents = True

End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
vOldVal = Target
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß+Danke Alex

aloys78 · 11. März 2016

Hallo Alex,

er erfasst allg. nicht die Einträge, die über eine Userform gelöscht werden
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

.
Verstehe ich nicht. Bei welchen Fällen tritt welcher Fehler auf ?

Was mir aufgefallen ist, wenn ich einen letzten Punkt in einer Tabelle lösche, hängt sich Excel auf, ..
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Kommentiere mal meine Call-Anweisung aus, dann wirst Du sehen, dass das an Deinem Code liegt.

Dass Du alle Änderungen loggst, ist für mich neu. Wenn ein Key angepasst wird, dann wird natürlich ein Change-Ereignis ausgelöst. Wenn dabei ein Problem auftriit, dann vermute ich mal die Ursache in diesem Code.

Gruß
Aloys

chin842 · 11. März 2016

Hey Aloys,

ja, der Fehler lag in meiner Löschfunktion, blieb in der Loop Schleife hängen, zusätzlich Abbruchkriterium, wenn die nächste Zelle leer ist, war die Lösung:

Code:

Do 'funktion
Cells(lngZeile, 1).EntireRow.Delete 'funktion
lngezeile = lngZeile + 1 'funktion
nächsteZelle = Cells(lngZeile, 1).Value 'funktion
Loop Until Len(ausgangsZelle) = Len(nächsteZelle) Or Cells(lngZeile, 1).Value = "" 'funktion
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Perfekt! Damit funktioniert löschen+alle zusätze perfekt *Smilie

Ja, die Idee des Changelog kam spontan auf und habe ich die letzten Tage recht zügig umgesetzt.
Mich wundert es eben, dass er nicht erfasst, wenn eine Zeile oder mehrere gelöscht werden, da der Code ja eigentlich ein "Change-Ereignis" auslöst...

Eine Idee, woran das liegen könnte?
Danke!

Gruß Alex

aloys78 · 11. März 2016

Hallo Alex,

Eine Idee, woran das liegen könnte?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Es gehört nicht zu meinen Stärken, aus einem nicht funktionierenden Code die Aufgabenstellung auszulesen.

Also - beschreibe doch mal kurz, was Du wann protokollieren willst.
Braucht man überhaupt ein Change-Ereignis, oder kann das Logbuch zB in der Löschroutine geführt werden ?

Gruß
Aloys

chin842 · 14. März 2016

Hallo Aloys,

Sorry für die verspätete Rückmeldung!
Die Löschfunktion kennst da ja schon.
Code für den Changelog:

Problem:
Wenn die Löschfunktion Zellen löscht, wird das nicht mit geloggt, wenn ich die "von Hand" lösche per Entf wird das wiederum protokolliert.
Muss ich in der Löschfunktion sonst die Funktion explicit aufrufen?

Code:

Dim vOldVal '

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim bBold As Boolean

If Target.Cells.Count > 1 Or Target.Column 2 Or Sh.name = "PM" Then Exit Sub
On Error Resume Next
If Not Intersect(Target, Range("B:B")) Is Nothing Then
Application.EnableEvents = False

With Application
.ScreenUpdating = False
.EnableEvents = False
End With

If IsEmpty(vOldVal) Then vOldVal = "Leere Zelle"
bBold = Target.HasFormula
With Sheets("Changelog")
.Unprotect Password:="Secret"
If .Range("A1") = vbNullString Then
.Range("A1:G1") = Array("Veränderte Zelle", "Verändertes Arbeitsblatt", "Alter Inhalt", _
"Neuer Inhalt", "Änderungszeit", "Änderungsdatum", "Benutzer")
End If
With .Cells(.Rows.Count, 1).End(xlUp)(2, 1)
.Value = Target.Address
.Offset(0, 1) = Sh.name
.Offset(0, 2) = vOldVal
With .Offset(0, 3)
.Value = Target
.Font.Bold = bBold
End With

.Offset(0, 4) = Time
.Offset(0, 5) = Date
.Offset(0, 6) = Application.UserName

End With
.Cells.Columns.AutoFit
.Protect Password:="Secret"
End With
vOldVal = vbNullString

With Application
.ScreenUpdating = True
.EnableEvents = True
End With
On Error GoTo 0
End If
Application.EnableEvents = True

End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
vOldVal = Target
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Danke für Hilfe!

Gruß Alex

aloys78 · 14. März 2016

Hallo Alex

Was die Protokollierung betrifft, willst Du offenbar nur den Wert in Sp B protokollieren (mit den Infos, die im Code behandelt werden), wenn Zeilen gelöscht oder geändert werden.
Ich gehe mal davon aus, dass nur über die Userform gelöscht werden soll, dann würde ich

auf das Change-Ereignis verzichten,

Die eigentliche Protokollierung für eine geänderte / gelöschte Zeile in ein Sub auslagern (Übergabe: Kategorie, Zeilen#, alter und neuer Wert)

Das Sub beim Löschen von Zeilen, ggf in Schleife bei mehr als 1 Zeile, zur Protokollierung in der Löschroutine aufrufen

Das Sub ebenfalls bei der Änderung jedes Keys in Sub Neu-Nummerierung aufrufen

Manuelle Löschungen per Blattschutz unterbinden.

Gruß
Aloys

chin842 · 14. März 2016

Hey Alyos,

genau, nur die Änderungen in Spalte B und es nicht das Worksheet("PM") ist.
Okay, dann bastel ich mal den Code um und probiere es über eine Sub function mit den Übergabeparametern aus. Kann ich Leute erst heute Mittag/Abend machen.

•Das Sub ebenfalls bei der Änderung jedes Keys in Sub Neu-Nummerierung aufrufen
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Den Punkt habe ich nicht verstanden.
Wenn ich Zeilen "nur" verschiebe, soll das nicht protokolliert werden, wirklich nur, das löschen und einfügen.

Danke für die Tipps,
Gruß Alex

aloys78 · 14. März 2016

Hallo Alex,

Wenn ich Zeilen "nur" verschiebe, soll das nicht protokolliert werden, wirklich nur, das löschen und einfügen.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Da sind wir wieder beim Thema Aufgabenstellung.
Du weißt ja besser als ich, dass bei der Verschiebung auch Zahlenbestandteile der Nummerierung angepaßt werden; insofern verändern diese Keys nicht nur ihre Position, sondern auch ihren Wert.
Wenn ich Dich nun richtig verstanden habe, willst Du diese Veränderungen nicht protokollieren.
Letzten Endes geht es ja um die Frage, wofür erfolgt die Protokollierung eigentlich.

Gruß
Aloys

chin842 · 15. März 2016

Hey Alyos,

die Protokollierung dient dazu, wenn jemand "Mist" einträgt oder was gelöscht hat, nachzuvollziehen, welcher "User" verantwortlich dafür war.
Oder bei Nachfragen zu bestimmten Einträgen.

Ich habe jetzt eine "Sub Changelog" mir gebastelt, jetzt muss die nur noch an die richtigen Stellen im Code rein *wink.gif*
Bei Speichern schon eingebaut und funktioniert.

1. Problem was mir gerade gekommen ist:
Durch die Sortierfunktion, kann ja sein, dass Einträge an andere Stellen verschoben werden, wenn ich ein neuen Eintrag anlege.
Mein Gedanke:
jedes mal, wenn ich das blatt "Changelog" öffne, kontrolliere, ob die Zellen noch stimme...
Spalte D in Changelog = enthält zu suchender Inhalt
Spalte B in Changelog = enthält in welchem Worksheet gesucht werden soll
Saplte A in Changelog = soll die aktualisierte rng.address zugewiesen bekommen

leider funktioniert der Code nicht so und meckert an der Stelle: Set ws = Worksheets(Cells(i, 2))

Code:

Private Sub Worksheet_Activate()
Dim rng As Range
Dim i As Integer
Dim lngzeile As Long
Dim ws As Worksheet

lngzeile = Worksheets("Changelog").UsedRange.Rows.Count

For i = 1 To lngzeile
Set ws = Worksheets(Cells(i, 2))

Set rng = Sheets(ws).Cells.Find(What:=sheets("Changelog").Cells(i, 4).Text, after:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
, SearchFormat:=False)

Cells(i, 1) = rng.Address
Next i

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

P.S. nur der Infohalber die log funktion

Code:

Sub log(NWert As String, AWert As String, rng As Range, ws As Worksheet)
Dim bBold As Boolean

If rng.Cells.Count > 1 Or rng.Column 2 Or ws.name = "PM" Then Exit Sub
On Error Resume Next

With Application
.ScreenUpdating = False
.EnableEvents = False
End With

If IsEmpty(rng) Then AWert = "Leere Zelle"
bBold = rng.HasFormula
With Sheets("Changelog")
.Unprotect Password:="Secret"
If .Range("A1") = vbNullString Then
.Range("A1:G1") = Array("Veränderte Zelle", "Verändertes Arbeitsblatt", "Alter Inhalt", _
"Neuer Inhalt", "Änderungszeit", "Änderungsdatum", "Benutzer")
End If
With .Cells(.Rows.Count, 1).End(xlUp)(2, 1)
.Value = rng.Address
.Offset(0, 1) = ws.name
.Offset(0, 2) = AWert
With .Offset(0, 3)
.Value = NWert
.Font.Bold = bBold
End With

.Offset(0, 4) = Time
.Offset(0, 5) = Date
.Offset(0, 6) = Application.UserName

End With
.Cells.Columns.AutoFit
.Protect Password:="Secret"
End With
With Application
.ScreenUpdating = True
.EnableEvents = True
End With
On Error GoTo 0

Application.EnableEvents = True

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

aloys78 · 15. März 2016

Hallo Alex,
Code:

Set ws = Worksheets(Cells(i, 2))
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Was steht denn da drin ?

die Protokollierung dient dazu, wenn jemand "Mist" einträgt oder was gelöscht hat, nachzuvollziehen, welcher "User" verantwortlich dafür war.
Oder bei Nachfragen zu bestimmten Einträgen.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wozu brauchst Du überhaupt einen Anpassungscode ?
- bei "gelöschtem" nicht erforderlich,
- bei "Mist" und Nachfragen wäre doch auch denkbar, per DoppelClick eine Suche im Protokoll anzustoßen und sich die zutreffende(n) Position(en) gezielt anzeigen zu lassen.

Gruß
Aloys

Office: (Office 2013) Nummerierung automatisch anpassen bei löschen einer Zeile

Nummerierung automatisch anpassen bei löschen einer Zeile

Nummerierung automatisch anpassen bei löschen einer Zeile

Nummerierung automatisch anpassen bei löschen einer Zeile

Nummerierung automatisch anpassen bei löschen einer Zeile

Nummerierung automatisch anpassen bei löschen einer Zeile

Nummerierung automatisch anpassen bei löschen einer Zeile - Similar Threads - Nummerierung automatisch anpassen

Automatische Nummerierung Excel, wenn in Nachbarzelle bestimmter Wert

Automatische Nummerierung Kapitel gemischt

Tabellenspalte mit automatischer Nummerierung immer zu schmal

Automatische Nummerierung

Automatische Nummerierung einzelner Wörter in Fliesstext

Aktivieren oder Deaktivieren automatischer Aufzählungen und Nummerierungen

Word 2013 - automatische Nummerierung in Tabellen