Office: (Office 2016) ODER in Verbindung mit RECHTS in WENN-Bedingungen

Moin zusammen,

steh grad auf dem Schlauch. Muss in Spalte A Identnummern auslesen in Abhängigkeit der letzten Ziffer und benutze dazu die folgende Formel:

=WENN(RECHTS(A1;1)*1=3;1;0)

Soweit funktioniert alles, allerdings funktioniert die Formel nicht mehr wenn ich mehrere Zahlen mit ODER abfragen will.

=WENN(RECHTS(A1;1)*1=ODER(3;5;9);1;0)

Könnt ihr mir auf die Sprünge helfen, wo mein Denkfehler ist?
Vielen Dank im Voraus

 

Hola,

du du kannst das nicht so einfach abfragen, sondern musst die Werte einzeln bestimmen.

=wenn(oder(rechts(.....);(rechts(......);(rechts(.....));DANN;SONST)

Gruss,
steve1da

 

=--oder(index(--rechts(a1)={3.5.9};))

{=--oder(--rechts(a1)={3.5.9})}

 

Vielen Dank, funktioniert wie gewollt :)

=wenn(oder(rechts(..);rechts(..);1;0) hatte ich sogar selber davor getestet, allerdings im Nachhinein einen festen Bezug übersehen, weswegen es bei mir nicht lief.

Formeln mit "--" hab ich noch nie gesehen, werd ich mich mal einlesen. Wieder was neues gelernt, merci.

 

Hi lupo,

=--oder(--rechts(a1)={3.5.9}) sollte doch eigentlich auch ohne INDEX() und ohne Matrixabschluß funktionieren, oder nich?

Gruß Jonas

 

Hast recht. Das enthaltene harte Array ermöglicht es. Stehen 3, 5 und 9 hingegen in A2:A4, dann reicht
=--oder(--rechts(a1)=A2:A4) nicht aus.

Und da den Fremdprogrammen Google-Docs, OO und SpreadCE harte Arraybestandteile dafür nicht ausreichen, anders als Excel und Planmaker, tendiere ich dazu, meine beiden Varianten anzubieten.

Bei Docs gleichermaßen ok:
=--or(index(--RIGHT(A1;1)=C1:C3;))
=--or(index(--RIGHT(A1;1)={3;5;9};))
=arrayformula(--or(--RIGHT(A1;1)=C1:C3))
=arrayformula(--or(--RIGHT(A1;1)={3;5;9}))

=--or(--RIGHT(A1;1)={3;5;9})
=--or(--RIGHT(A1;1)=C1:C3) hingegen reichen nicht.