Office: On Error GoTo...

Hallo,

ich möchte durch eine Textbox eingabe eine Datei öffen. Falles die Datei nicht gefunden wird, möchte ich das eine Fehlermeldung auftaucht und das Makro beendet wird.
Leider leider kommt die Fehlermeldung auch, wenn die Datei gefunden wird. Wo ist da der Fehler?

MfG, Marius

Code:

Sub blos08()

Dim TextV As String
Dim TextV2 As String
Dim lng As Long

UserForm1.Hide

On Error GoTo Ende
Workbooks.OpenText Filename:= _
        "Y:\edv-listen\BLOS08-B-KST-PRUEFLISTE\blos08-" & UserForm1.TextBox1 & ".txt", Origin:= _
        xlWindows, StartRow:=1, DataType:=xlFixedWidth, FieldInfo:=Array(Array(0, _
        1), Array(5, 1), Array(13, 2), Array(26, 1), Array(36, 1), Array(43, 1), Array(54, 2))
'Exit Sub

lng = Cells(65536, 1).End(xlUp).Row
Range(Cells(lng, 1), Cells(lng - 1, 6)).ClearContents

Ende:
MsgBox "Das angegebene Datum konnte nicht gefunden werden!"
Exit Sub
End Sub

 

Hi Marius,

verwende nicht On Error sondern prüfe das Vorhandensein mit Dir()

Code:

   Dim strDatei As String
   strDatei = Dir("Y:\edv-listen\BLOS08-B-KST-PRUEFLISTE\blos08-" & UserForm1.TextBox1 & ".txt")
   If strDatei = "" Then MsgBox "Datei nicht vorhanden"

Bis später,
Karin

 

Hallo Marius,

oder mit folgender Variante:

Code:

Option Explicit

Sub blos08()

    Dim TextV As String
    Dim TextV2 As String
    Dim lng As Long
    Dim strDatei As String
    
    On Error GoTo Ende
    
    strDatei = "Y:\edv-listen\BLOS08-B-KST-PRUEFLISTE\blos08-" & UserForm1.TextBox1 & ".txt"
    
    UserForm1.Hide
    
    Workbooks.OpenText Filename:=strDatei, _
            Origin:=xlWindows, StartRow:=1, DataType:=xlFixedWidth, _
            FieldInfo:=Array(Array(0, 1), Array(5, 1), Array(13, 2), _
                             Array(26, 1), Array(36, 1), Array(43, 1), Array(54, 2))
    
    lng = Cells(65536, 1).End(xlUp).Row
    Range(Cells(lng, 1), Cells(lng - 1, 6)).ClearContents
    
    Exit Sub
    
Ende:
    MsgBox "Das angegebene Datum konnte nicht gefunden werden!"
    
End Sub

 

Hallo,

vielen Dank, genau das hab ich gesucht!!!