Office: (Office 365) OnTime mit Parameter

Hallo

Wie kann ich mit OnTime eine Funktion aufrufen, und dabei zwei Variablen mitgeben:
Parameter 1 als String
Parameter 2 als Array

Bisher ist mir nur die Übergabe eines numerischen Wertes gelungen.

 

Hi,

was willst Du erreichen, wie sieht Dein Code aus?

 

du könntest das Array als Text erstellen.
das funktioniert bei mir:

Code:

Sub test()
Dim x
x = Array("du", "da", "im", "Radio")
Application.OnTime Now, "'xxx ""Hallo Welt"", Array(""Du"", ""Da"", ""im"", ""Radio"")'"
End Sub


Sub xxx(txt As String, y)
Debug.Print txt, Join(y)
End Sub

aber ob man eine Variable auch als solche übergeben kann, weiß ich nicht.
ein möglicher Workaround wäre die Nutzung von Projektweit gültigen Variablen (also einer Variable, die alle Makros nutzen können)

Gruß Daniel

 

Hallo BoskoBiati

Das ist mein Test-Code:
Option Explicit
Public LocalVar As Variant
Sub MainSub()
ReDim LocalVar(1 To 3)
LocalVar(2) = "Prima"
Dim Zeile As Long
Zeile = 17
Application.OnTime Now + TimeValue("00:00:10"), "'OnTimeSub (" & Zeile & ")" & "'"
End Sub

Function OnTimeSub(Optional ByVal P1 As String, Optional ByVal P2 As String)
Debug.Print "OnTimeSub " & Time
Debug.Print P1
Debug.Print P2
End Function

Es macht keinen Sinn, in der aufgerufenen Funktion auf eine globale Variable zuzugreifen. Die beiden Codes sollten unabhängig von einander funktionieren. Was benötigt ist, muss als Parameter übergeben werden.

Warum OnTime?
In meiner Main-Routine werden Befehle ausgeführt, die den "Unterbrechungsmodus" ausschalten. Das gilt - nach meiner Erfahrung - bis dem Ende des aktuellen Prozess. Mit OnTime könnte ich einen neuen Prozess starten, in dem dann auch wieder Haltepunkt möglich sind. Dazu muss ich aber die von der Main-Routine ermittelten Daten weiterverarbeiten und das Ergebnis dem Aufrufer bereitstellen.

 

Hi Daniel.

Sorry. Dein Beispiel hilft mir nicht weiter.

 

Korrektur zu meimem dargestellten Code:

Wie der Name (LocalVar) schon erkennen lässt, sollte es eine lokale Variable sein. Eine globale Variable muss ich nicht unbedingt als Parameter übergeben.l

 

Hi
so läuft dein Code bei mir:

Code:

Option Explicit
Public LocalVar As Variant

Sub MainSub()
ReDim LocalVar(1 To 3)
LocalVar(2) = "Prima"
Dim Zeile As Long
Zeile = 17
Application.OnTime Now + TimeValue("00:00:00"), "'OnTimeSub " & Zeile & ", """ & LocalVar(2) & """'"
End Sub

Function OnTimeSub(Optional ByVal P1 As String, Optional ByVal P2 As String)
Debug.Print "OnTimeSub " & Time
Debug.Print P1
Debug.Print P2
End Function

du kannst über das Ontime nur feste Werte übergeben und diese müssen in einem Textstring geschrieben werden.
da es hier ein einfacher Aufruf ist, werden die Parameter ohne Klammern hinter das Makro geschrieben.

Gruß Daniel

 

Gallo Daniel.

Dank deines Codes bin ich schon einen Schritt weiter.

Wenn ich in der OnTime-Routine nur auf ein Element zugriffen habe, dann war das nur ein Nachweis, das die Array richtig bereitgestellt wurde.

Dein Code, wie du ein Variant testweise füllst, hat mich daran erinnert, dass es auch die Funktion "Join" gibt. Die nutze ich nun, um alle Einträge zu übergeben. Und in der OnTime-Routine mache ich mit Split wieder eine Array.

Das ist gelöst und funktioniert bestens.

Ein Problem habe ich noch: neben der Zeilennummer und der Array brauche ich einen dritten Parameter. Es ist ein Begriff der zuvor ermittelt wurde. Zwar könnte ich den Begriff auch erneut ermitteln. Aber die Übergabe als weiteren Parameter wäre logischer.

Mir ist es aber nicht gelungen, den Code so zu verändern, dass noch ein dritter Parameter übergeben wird. Hier bitte ich dich um deine Unterstützung.

Grundsätzlich ist mir die Reihenfolge der Parameter egal, würde aber vorschlagen, dass die Array der erste Parameter ist.

Mein aktueller Code:

Option Explicit
Sub MainSub()
Dim PrivVar As Variant
Dim Zeile As Long
Dim N As String
PrivVar = Split("vielen,Dank,Daniel,für,die,Untestützung", ",")
Zeile = 17
N = "Temp4711"
Application.OnTime Now(), Procedure:="'OnTimeSub " & Zeile & ", """ & Join(PrivVar, vbTab) & """'"
End Sub

Function OnTimeSub(ByVal P1 As String, _
ByVal P2 As String, _
Optional ByVal P3 As String) 'optional, weil derzeit nur 2 Parameter übergeben werden
Debug.Print "Zeile = " & P1
Debug.Print P2
Dim XVar As Variant
XVar = Split(P2, vbTab)
Debug.Print XVar(2)
Stop
End Function

 

naja, jetzt solltest du das hinbekommen
das Prinzip kennst du doch jetzt, du brauchst einen Text der so aufgebaut ist:

"Markoname, Parameter1, Parameter2, Parameter3"

und Texte in Anführungzeichen.
Parameter 3 wird genauso angefügt wie Parameter2
klar kommt man dann mit den Vielen Anführungszeichen auch mal durcheinander.

ich würde mir auch immer den Text erstmal in einer Variabeln zusammstellen, dann kann man leicher prüfen, ob der Text stimmt:

Code:

Aufruf = "'OnTimeSub " & Zeile & ", """ & Join(PrivVar, vbTab) & """, """ & N & """'"
Debug.Print Aufruf
Application.OnTime Now(), Procedure:=Aufruf

eine andere Methode für besser Übersicht ist, den Text erstmal als gesamtText zu erstellen und dann die Parameter mit Replace einzubauen.

Code:

Aufruf = "'OnTimeSub xxx, ""yyy"", ""zzz""'"
Aufruf = Replace(Aufruf, "xxx"; Zeile)
Aufruf = Replace(Aufruf, "yyy"; Join(PrivVar, vTab))
Aufruf = Replace(Aufruf, "zzz"; N)

klar ein paar Programmzeilen mehr, aber man hat mehr Übersicht beim Erstellen des Textes und macht weniger Fehler bzw findet diese leichter
Gruß Daniel

 

Guten Morgen, Daniel.

Der Vorschlag, den String zuerst in eine Variable zu stellen und dann mit "Debug.Print" anzuzeigen, war eine sehr gute Idee. Jetzt habe ich den Aufbau der Parameter verstanden.

Inzwischen habe ich die Reihenfolge erfolgreich umgestellt und einen weiteren Parameter aufgenommen.

Problem gelöst. Danke.