Office: Orte ausgeben bei KKLEINSTE

Hallo zusammen

Kann mir jemand sagen, ob er eine Formel für Excel kennt, die mir den Zellort eines Wertes angibt?



D.h. wenn ich z.B. mehrere Werte habe, per Formel auslesen will, welcher davon am niedrigsten ist und die Formel mir dann nicht den Wert wiedergibt, sondern die Spalte. Ich verzweifel hier.



Beispiel:

Ich habe vier Lieferanten in den Zellen A1 bis D1.
In der Zeile darunter - in den Zellen A2 bis D2 - deren jeweilige Artikelpreise.
Per KKLEINSTE-Formel kann ich ja bekanntlich ausgeben lassen, wieviel der günstigste Artikel kosten mag. Allerdings suche ich nun eine Formel, die mir ausgibt in welcher Spalte dieser Wert steht, ergo: wer ebendiesen günstigsten Artikel liefert. Any ideas?

Zweites Problem:
Diese Problematik besteht natürlich auch für die folgenden Zeilen mit den anderen Artikeln. Was nutze ich denn da, wenn erst gecheckt werden soll, um welchen Artikel es geht? SVERWEIS? WVERWEIS?
Entweder sehe ich den Wald vor lauter Bäumen nicht, es war die Woche einfach zu viel oder es ist tatsächlich so schwer.

Hiiiiilfe

 

Hallo,

	A	B	C	D	E	F
1	Lief1	Lief2	Lief3	Lief4		Lief3
2	35	39	10	24		3
3

Zelle	Formel
F1	=INDEX(A1:D1;1;F2)
F2	=VERGLEICH(MIN(A2:D2);A2:D2;0)

 

hey super!!!
vielen lieben dank.
hab privat leider kein excel zur verfügung. aber: was passiert wenn zwei werte gleich sind?

und:
kann man so auch den zweit- oder drittkleinsten wert ausgeben?

wenn ich jetzt zB einen backup lieferanten auswählen will, der entweder gleich günstig oder halt am zweitgünstigsten ist, geht das auch?

und wie war die sache mit dem verweis?

 

Hallo,

im folgenden Beispiel habe ich mit maximal 2 kleinsten Preisen gerechnet.
Um dieses Problem zu lösen, habe ich eine Hilfszeile A3:D3 mit garantiert lauter unterschiedlichen Preisen eingezogen.
Um die Eventualität mit 2 kleinsten Preisen darzustellen, habe ich die 2 Spalten F und G geschaffen, wo man in Zelle F4 und G4 die Nummer des Preises (1=kleinster, 2=zweitkleinster, ...) eingeben kann.
Im folgenden Beispiel sieht man sofort, dass der kleinste und zweitkleinste Preis in Wahrheit 2 gleich große Preise (Zelle F2 und G2) darstellen.
In Zelle F4 und G4 kann man natürlich auch 2 andere Preisnummern eingeben (Nummerierung natürlich nach aufsteigenden Preisen des Bereiches A3:D3).

	A	B	C	D	E	F	G	H
1	Lief1	Lief2	Lief3	Lief4		Lief4	Lief3	Lieferant
2	35	39	10	10		10	10	Preise
3	34,999999	38,999998	9,999997	9,999996		4	3	Spalte
4						1	2	Nr.kleinster Preis
5

Zelle	Formel
F1	=INDEX($A1:$D1;1;F$3)
G1	=INDEX($A1:$D1;1;G$3)
F2	=INDEX($A2:$D2;1;F$3)
G2	=INDEX($A2:$D2;1;G$3)
A3	=A2-SPALTE()/1000000
B3	=B2-SPALTE()/1000000
C3	=C2-SPALTE()/1000000
D3	=D2-SPALTE()/1000000
F3	{=VERGLEICH(KKLEINSTE($A$3:$D$3;$F$4:$G$4);$A$3:$D$3;0)}
G3	{=VERGLEICH(KKLEINSTE($A$3:$D$3;$F$4:$G$4);$A$3:$D$3;0)}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlasse in diesem Fall den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Wow das sieht so aus als würde das mein problem lösen
ich danke dir schon einmal ungemein für deine hilfe!
aber wenn da schon die matrix ranmusste, war das ja wirklich gar nicht sooo einfach und ich bin doch nicht so unfähig wie ich gestern schon fast dachte ;)

ach eine frage noch.
das jetzt mit einem verweis wird nicht mehr funktionieren, oder?
a la ich gebe in einem anderen tabellenblatt "Artikel1" ein und der spuckt mir dann die werte aus. da macht mir die matrixformel einen strich durch... oder?

 

Hallo,

Wo stehen welche Werte, die Excel "ausspucken" soll?

 

Hallo!

Hilft Dir das weiter?

Die billigsten und die teuersten Preise werden mit
der Bedingtenformation mit Farbe hinterlegt.
Leider wird das hier nicht angezeigt.
Sind sie gleich, dann beide mit Farbe aber nur der erste
Lieferant.

Arbeitsblatt mit dem Namen 'Tipp2'
	A	B	C	D	E	F	G	H	I	J
267	Preisvergleich
268
269
270		Merkur	Billa	Hofer	ABC	Weghofer	Aldi		Günstigster	Teuerster
271
272	Äpfel	18,00	45,00	78,23	17,95	42,00	15,00		Aldi	Hofer
273	Birnen	45,00	27,69	30,00	28,00	46,00	30,00		Billa	Weghofer

Zelle	Formel
I272	=INDEX($B$270:$G$270;VERGLEICH(MIN(B272:G272);B272:G272;))
J272	=INDEX($B$270:$G$270;VERGLEICH(MAX(B272:G272);B272:G272;))

Zelle	bedingte Formatierung...	Format
B272	1: =B272=MIN($B$272:$G$273)	abc
B272	2: =B272=MAX($B$272:$G$273)	abc
B273	1: =B273=MIN($B$273:$G$273)	abc
B273	2: =B273=MAX($B$273:$G$273)	abc

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

Gruß
Wilfried

 

hallo exl

selbe xls datei, nur halt in einem anderen blatt.

im prinzip muss ich eine lieferantenauswahldatei erstellen, die mir aus einer separaten preisliste die erste, zweite und dritte wahl des lieferanten ausspuckt.

ich hatte gehofft das wäre vielleicht einfach mit kkleinste und nem sverweis und den spaß dann ein wenig verschachteln zu machen gewesen. gestaltet sich aber dann doch recht schwierig. wie es scheint...

wobei ich gerade sehe dass ich das ja machen kann wie wilfried. zelle dahinter und dann einfach auf diese verweisen. der verweis funktioniert also im kopf schonmal

und an dich, wilfried:
ja, das sieht im prinzip genauso aus wie ich das benötige nur halt statt dem teuersten brauche ich den zweit- bzw drittgünstigsten. aber die anzeige hinter der preisliste hat mich schonmal auf eine gute idee gebracht. danke dafür!!