Office: (Office 365) PDF erstellen über Auswahl Steuerelement

Hallo,

ich möchte nur bestimmte Excelsheets in ein PDF drucken und in eine definierte Ablage ablegen.

Leider ist mein Excel Wissen sehr "beschränkt". Würde mich sehr über Hilfe freuen.

Danke

 

Hi Jeanette,

das kannst du mit folgendem Makro realisieren:

Code:

Sub PDF_Export()
    Dim strPfad As String
    Dim strMappe As String
    strPfad = "E:\Z_Zest\"  '<== Pfad anpassen
    strMappe = "Hallo.pdf" '<== Dateiname anpassen
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=strPfad & strMappe _
        , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
        :=False, OpenAfterPublish:=False
End Sub

---

 

Danke Beverly.

Ähm .... okay ich versuche es mal ....

Funktionieren tut es schon einmal, jedoch nimmt er die ausgewählten Sheets nicht. Speichert lediglich Seite 1.

 

Hi Jeanette,

dazu musst du schon mal deine Mappe hochladen.

---

 

Gerne doch ....

 

So sollte es funktionieren:

Code:

Private Sub CommandButton1_Click()
    Dim strPfad As String
    Dim strMappe As String
    Dim chkBox As Shape
    Dim arrTab()
    ReDim arrTab(1 To 1)
    Dim intZaehler As Integer
    strPfad = Range("A31")
    If Right(strPfad, 1) <> "\" Then strPfad = strPfad & "\"
    strMappe = "Dokumentation Rückverfolgung.pdf" '<== Dateiname anpassen
    For Each chkBox In ActiveSheet.Shapes
        If chkBox.TopLeftCell.Row >= 25 And chkBox.BottomRightCell.Row <= 28 Then
            If chkBox.DrawingObject.Value = 1 Then
                intZaehler = intZaehler + 1
                ReDim Preserve arrTab(1 To intZaehler)
                arrTab(intZaehler) = Worksheets(chkBox.AlternativeText).Index
            End If
        End If
    Next chkBox
    If arrTab(1) <> "" Then
        Worksheets(arrTab).Select
        Selection.ExportAsFixedFormat Type:=xlTypePDF, Filename:=strPfad & strMappe _
            , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
            :=False, OpenAfterPublish:=False
        Worksheets("Deckblatt").Select
    End If
End Sub

---

 

Hallo,

vielen lieben Dank, doch leider ist die Seite (n) die er drucken soll ohne Inhalt. Es wird eine weiße Seite erzeugt.

 

Hi,

dann ändere diesen Teil:

Code:

    If arrTab(1) <> "" Then
        Worksheets(arrTab).Copy
        With ActiveWorkbook
            .ExportAsFixedFormat Type:=xlTypePDF, Filename:=strPfad & strMappe _
            , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
            :=False, OpenAfterPublish:=False
            .Close False
        End With
    End If

---

 

Guten Morgen.

Jetzt klappt dies einwandfrei. Vielen lieben Dank. Kurze Frage noch, wie wird die Reihenfolge bestimmt? Also Seite 1, 2 etc.
Danke

 

Hi,

der Code läuft in einer Schleife über alle Shapes im Tabellenblatt und prüft ob sie innerhalb der Zeilen 25 und 28 liegen. Falls ja, wird die Aufschrift des Kontrollkästchens genommen, der Index (entspricht der Reihenfolge in der Mappe) des betreffenden Tabellenblattes ausgelesen und ins Array geschrieben. Die Reihenfolge, in der die Indizes in das Array eingelesen werden, hängt davon ab, in welcher Reihenfolge du die Kontrollkästchen erstellt hast. Die eingelesenen Tabellenblätter werden dann anhand ihres Indexes gemeinsam in eine neue Mappe kopiert und daraus dann das PDF-Dokument erstellt. Mir ist aber nicht bekannt, dass die Reihenfolge, in der die Tabellenblatt-Indizes im Array stehen, Einfluss auf die Reihenfolge der Blätter nach dem Kopieren in die neue Mappe hat - also ist davon auszugehen, dass die Reihenfolge der exportierten Tabellenblätter davon abhängt, wie die Reihenfolge in deiner Mappe vorliegt. Gibt es damit ein Problem?

---

 

Guten Morgen.

Es gibt damit keine Probleme. Aber vielleicht kann man es "sortieren".
Sprich Deckblatt, Rückverfolgung, Auswertung.

Dankeschön.

 

Hi,

ganz einfach: verschiebe die Tabellenblätter in deiner Mappe so, dass sie in der von dir gewünschten Reihenfolge vorliegen - in dieser Reihenfolge werden sie auch exportiert.

---

 

Perfekt .... funktioniert ... Dankeschön
Kurze Frage noch ... wenn ich weitere Themen zu dieser Datei hätte, schreibt man hier weiter oder eröffnet man einen neuen Thread?
Dankeschön.

 

Wenn es ein völlig anderes Problem ist - dann eröffne ein neues Thema. Wenn es mit dem bisherigen Problem zu tun hat dann kannst du hier ruhig weitermachen.

---