Office: Per VBA Aus einer Exceldatei mehrere Tabellenblätter in anderen Exceldateien schützen

Hallo,

seit langem habe ich mal wieder eine Frage. Man kann ja per VBA mehrere Tabellenblätter einer Exceldatei schützen, oder den Schutz aufheben.

Geht das ganze auch so, das ich eine seperate Datei habe, in der der VBA-Code ausgeführt wird, und dann in vorgegebenen Dateien/Tabellenblättern im selben Verzeichnis die Tabellebblätter gesperrt oder der Schutz aufgehoben wird?

Beispiel:

Ordner (hier befinden sich alle Dateien)
Steuerdatei.xls (hier befindet sich der Code zum entsperren)
Datei1.xls -> Tabellenblatt1 ; Tabellenblatt2 ; Tabellenblatt3
Datei2.xls -> Tabellenblatt1 ; Tabellenblatt2 ; Tabellenblatt3
Datei3.xls -> Tabellenblatt1 ; Tabellenblatt2 ; Tabellenblatt3
Datei4.xls -> Tabellenblatt1 ; Tabellenblatt2 ; Tabellenblatt3
Datei5.xls -> Tabellenblatt1 ; Tabellenblatt2 ; Tabellenblatt3

 

Hi Jan,

das ist möglich - dazu müsste(n) die andere(n) Arbeitsmappe(n) geöffnet und der Schutz der benannten Tabellenblätter aufgehoben oder gesetzt werden.
Deine Angabe Tabellenblatt1 - ist das der tatsächliche Name des Tabellenblattes oder sind es unterschiedliche Namen und du meinst die Nummerierung? Sollen alle genannten Arbeitsmappen auf einmal bearbeitet werden oder soll immer eine aus dem Verzeichnis ausgewäglt werden?

Bis später,
Karin

 

Hallo Beverly,

klingt ja schonmal gut :) Die Tabellenblätter in den Dateien heißen "Direkt", "Medizinlager", "Zentrallager", und "leer". Die Bezeichnungen oben hatte ich lediglich als Beispiel genommen.

Die Arbeitsmappen sollten im optimalsten Fall alle auf einmal bearbeitet werden. Ich stelle es mir so vor:

1. Öffnen der Exceldatei mit dem Makro
2. Ausführen des Makros -> Öffnen aller Dateien im selben Verzeichnis nacheinander -> Dann entsperren aller enthaltenen Tabellenblätter.

Nach dem Bearbeiten dann:
1. Starten eines Makros zum Sperren aller Arbeitsblätter und anschließendes schließen aller Exceldateien.

 

Hi Jan,

ungetestet:

Code:

Sub ArbeitsmappenBearbeiten()
    Dim strVerzeichnis As String
    Dim strDatei As String
    Dim strTyp As String
    Dim wksTab As Worksheet
    strTyp = "*.xls"
    Application.ScreenUpdating = False
    strVerzeichnis = ThisWorkbook.Path & "\"
    strDatei = Dir(strVerzeichnis & strTyp)
    Do While strDatei <> ""
        If strDatei <> ThisWorkbook.Name Then
            Workbooks.Open Filename:=strVerzeichnis & strDatei
            With Workbooks(strDatei)
                For Each wksTab In .Worksheets
                    wksTab.Unprotect
                Next wksTab
            End With
        End If
        strDatei = Dir
    Loop
    Application.ScreenUpdating = True
End Sub

Es werden alle Arbeitsmappen, die im selben Verzeichnis wie die Mappe mit dem Makro liegen, geöffnet und bei allen enthaltenen Tabellenblättern (unabhängig vom Namen) der Schutz aufgehoben.

Bis später,
Karin

 

Hallo Beverly,

sorry das ich noch keine Rückmeldung gegeben habe, ich kam noch nicht zum Testen. Ich danke dir aber schonmal vielmals und berichte, wie es funktioniert :)

 

Hey, grade getestet, funktioniert super, sogar mit Angabe des Passwortes ruckzuck :) Danke dir dafür.
Weitere Frage, ich bekomme das Skript bricht umgebauter, das ich nach der Änderung aller Dateien diese mit Passwortschutz auf die Arbeitsblätter und den vorgenommenen Änderungen wieder speichere. Wie muss ich da vorgehen? Workbook.Close mit der Angabe SaveChanges klappt nicht

 

Hi,

ich habe den Code jetzt nicht getestet, aber versuche es mal so:

Code:

Sub ArbeitsmappenSchliessen()
    Dim wkbMappe As Workbook
    Dim wksTab As Worksheet
    Application.ScreenUpdating = False
    For Each wkbMappe In Workbooks
        If wkbMappe.Name <> ThisWorkbook.Name And InStr(wkbMappe.Name, "PERSON") = 0 Then
            With wkbMappe
                For Each wksTab In .Worksheets
                    wksTab.Protect
                Next wksTab
                .Save
                .Close
            End With
        End If
    Next wkbMappe
    Application.ScreenUpdating = True
End Sub

Bis später,
Karin

 

Damit hast du direkt ins schwarze getroffen :) vielen vielen Dank :)