Office: (Office 365) Per vba Zeile einfügen

Hallo zusammen,

ich möchte gerne in einer Tabelle per vba eine neue Zeile einfügen wenn in Spalte A ein Eintrag getätigt wird. Die Zeile soll über der Zeile mit dem Eintrag in Spalte A eingefügt werden.
Die Formeln und Formate aus der darüberliegende Zeile sollen auch in der neuen Zeile
auch sein.

Leider verfüge ich nicht über die notwendigen vba Kenntnisse um das alleine zu bewerkstelligen und benötige eure Hilfe.

würde mich über Unterstützung freuen.

Danke
Lars

 

Moin Lars

STRG-T
Neue Zeilen werden immer unterhalb der Tabelle eingefügt- Formeln und Formate werden übernommen.

 

Danke DL
Das ist mir bewusst, aber nicht das was ich benötige.
Wenn ich in z.b.A120 eine Eingabe mache möchte ich drüber eine Zeile eingefügt bekommen mit den Formeln und Formaten die sich darin befinden.

 

ist die Tabelle als Tabelle formatiert?

 

Hallo,

in der beiliegenden Datei habe ich dir in einem allgem.Codemodul das folgende Makro

Code:

Option Explicit

Sub MakroZeile_Einfügen()
    Dim KopfZeile As Long, AktZeile As Long
    If ActiveCell.ListObject Is Nothing Then
       MsgBox "Die Zelle " & ActiveCell.Address & " ist nicht in einer strukt.Tabelle."
    Else
       With ActiveCell
          AktZeile = .Row
          With .ListObject
             KopfZeile = .HeaderRowRange.Row
             .ListRows.Add Position:=AktZeile - KopfZeile, AlwaysInsert:=True
          End With
       End With
    End If
End Sub

eingefügt, ferner im Arbeitsblatt "Tabelle1" eine strukturierte Tabelle und einen Button, der mit dem Makro verknüpft ist.
Stellt man die aktive Zelle in eine Zelle der struktur.Tabelle und klickt den Button, wird in dieser Zeile eine Leerzeile in die Tabelle eingefügt. Gibt man Werte ein (in Sp1 und Sp2), wird in Sp3 die Summe errechnet.

 

Hallo Hajo,
meinst Du eine dynamische Tabelle?

 

@Exl121150

Das ist leider nicht die Funktion die ich benötige. Danke aber für deine Hilfe.

 

falls ich das richtig verstanden habe,

vba
Sub NeueZeileEinfügen()
Dim ZeileMitEintrag As Long
Dim LetzteZeile As Long

ZeileMitEintrag = Range("A:A").Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
LetzteZeile = Cells(Rows.Count, 1).End(xlUp).Row

Rows(ZeileMitEintrag).Copy
Rows(ZeileMitEintrag).Insert Shift:=xlUp
Application.CutCopyMode = False

Rows(LetzteZeile + 1).ClearContents
Rows(LetzteZeile + 1).ClearFormats
End Sub

 

oder einfacher noch du erstellst dir einen Button auf der Seite (mit dem code
Sub nachunten()

Range("A2").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove

End Sub

hast deinen Eintrag erledigt drückst du auf den Button.

 

@GÄRTNER23
Danke schön. Werde ich testen.
Was macht: LetzteZeile = Cells(Rows.Count, 1).End(xlUp).Row ?

Ich glaube ich habe vergessen zu erwähnen das ich eine Zeile mitten in der Tabelle einfügen möchte wenn in Spalte A ein Eintrag erfolgt.
Sucht LetzteZeile nach der letzten gefüllten Zeile in der Tabelle?

 

hallo ich hoffe es so richtig erklärt zu haben,
"Cells(Rows.Count,1)" bezieht sich auf die nächste leere Zeile in Spalte 1 (A1:A?) eines Tabellenblattes.
"End(xlUp)" bewegt sich von der untersten Zelle in der Spalte nach oben, bis sie die nächste nicht leere Zelle findet.
".Row" gibt Zeilennummer der Zelle zurück.

 

Hallo Gringo,

pack das mal in die betreffende Tabelle

Code:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim sz As Long, ls As Long, nZelle
sz = Target.Row
ls = ActiveSheet.Cells(sz, Columns.Count).End(xlToLeft).Column
   If Target.Column = 1 And Target.Count = 1 Then
   Application.EnableEvents = False
      Rows(sz).Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
      Rows(sz - 1).Copy
         Rows(sz).PasteSpecial Paste:=xlPasteFormulas, Operation:=xlNone, _
         SkipBlanks:=False, Transpose:=False
         Rows(sz).PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, _
         SkipBlanks:=False, Transpose:=False
         Application.CutCopyMode = False
      For Each nZelle In ActiveSheet.Range(Cells(sz, 1), Cells(sz, ls))
         If Not nZelle.HasFormula Then
            nZelle.ClearContents
         End If
      Next nZelle
   Application.EnableEvents = True
   End If
End Sub

 

@DIZA
Danke schön, werde ich testen.