Office: (Office 365) Pictures.Delete

Hallo Zusammen,

möchte gerne in der Tabelle1 alle Bilder in dem Bereich A2:M40 löschen.
Steigt aber hier immer aus:

ActiveSheet.Pictures.Delete ("A2:M40")

Wo liegt der Fehler?

Danke Merkur

 

Hi,

du musst in einer Schleife prüfen, ob das Bild im Bereich liegt:

Code:

Sub LoeschenImBereich()
    Dim picBild As Picture
    For Each picBild In ActiveSheet.Pictures
      If Not Intersect(picBild.TopLeftCell, Range("A2:M40")) Is Nothing Then
         If Not Intersect(picBild.BottomRightCell, Range("A2:M40")) Is Nothing Then
            picBild.Delete
         End If
      End If
    Next picBild
End Sub

---

 

Hallo Karin und danke für die Hilfe,

allerdings ist auf dem Blatt ein CommandButton.
Nun tritt ein Fehler auf. Siehe Bild.
Ohne den Button läuft es ohne Probleme.

Gruß Merkur

 

Hi,

was für ein CommandButton - Formular- oder AxtiveX-Steuerelement?

---

 

........ActiveX-Steuerelement ist es.

 

Hi,

dann muss man den Objekttyp Shape verwenden und prüfen ob es ein Bild ist:

Code:

Sub LoeschenImBereich()
    Dim shaBild As Shape
    For Each shaBild In ActiveSheet.Shapes
      If Not Intersect(shaBild.TopLeftCell, Range("A2:M40")) Is Nothing Then
         If Not Intersect(shaBild.BottomRightCell, Range("A2:M40")) Is Nothing Then
            If shaBild.Type = msoPicture Then shaBild.Delete
         End If
      End If
    Next shaBild
End Sub

---

 

Danke schön.

Funktioniert klasse