Office: Portfolio-Diagramm (Blasendiagramm)

Hallo liebe Office-Gemeinde!

Ich bin bei meiner verzweifelten Suche bereits auf einige Links zum Thema gestoßen, keines konnte mir jedoch wirklich bei der Lösung meines Problems richtig helfen.

Nach vielen fehlgeschlagenen Versuchen, dieses Diagramm auf eine einfach schnelle Weise zu erstellen, habe ich es nun auf mühseelige Einzelarbeit (Definition jeder Blase extra) erstellt.

Wäre vielleicht jemand so nett und könnte mir erklären wie dies einfach zu Erstellen geht?

Das Diagramm zum jetzigen Zeitpunkt (so wie es aussehen sollte) ist beigefügt.

Anforderungen:
Beschriftung der Blasen mit den Ideennamen! (alle gleichzeitig)
Blasengröße angepasst zur Diagrammgröße (keine Riesenblasen, dass man nix mehr erkennen kann)
X-Achse = Innovationspotential
Y-Achse = Realisierungsaufwand
Blasengröße = Unternehmensrisiko

Vielen Dank im Voraus.

LG

 

Hi,

mit folgendem Makro kannst du das fertig erstellte Diagramm formatieren:

Code:

Sub DiaFormatieren()
   Dim intReihe As Integer
   With ActiveSheet.ChartObjects(1).Chart
      .ChartGroups(1).BubbleScale = 45
      For intReihe = 1 To .SeriesCollection.Count
         With .SeriesCollection(intReihe)
            .Format.ThreeD.BevelTopInset = 5
            .Format.ThreeD.BevelTopDepth = 2
            .DataLabels.ShowValue = False
            .DataLabels.ShowSeriesName = True
         End With
      Next intReihe
   End With
End Sub

Bis später,
Karin

 

Hallo Karin,

vielen Dank für das Makro.

Hat jedoch nicht das gewünschte Ergebnis gebracht.
Folgender Ablauf:
Erstellen des Markos DiaFormatieren und Speichern des Excel-Files als xlsm Datei
Erstellung eines Blasen-Diagramms auf neuem Tabellenblatt
Datenquelle auswählen: =Bewertung!$Q$5:$T$19
Makro ausführen

Fehlermeldung: Laufzeitfehler '-2147467259 (80004005)':
Die Count-Eigenschaft der DataLabels-Klasse kann nicht zugeordnet werden

Klick auf Debuggen: Öffnen Makro-Entwurfsansicht: Markierung der Zeile .DataLabels.ShowValue = False gelb
Diagramm sieht bis auf die Blasengröße gleich aus...

Habe ich was falsch gemacht?

LG

 

Hi,

du hast die Beschriftungslabel auch eingeblendet?

Bis später,
Karin

 

Hallo,

bin mir nicht sicher was du mit Beschriftungslabels meinst.

Habe mal einen Screenshot des Ergebnisses mit nachträglich aktivierten Datenbeschriftungen angehängt...

LG

 

Hi,

Beschriftungslabel = DataLabels (oder auch Datenbeschriftung) - genau diese meinte ich. Wenn diese nicht aktiviert (eingeblendet) sind, läuft der Code an genau der besagten Stelle auf einen Fehler.

Bis später,
Karin

 

Ahhhh, verstehe.
Die Beschriftung hat jetzt funktioniert, jedoch hat es das Problem, dass ich jeder Datenreihe manuell die richtigen Werte zuweisen muss noch nicht behoben.

Vielen Dank aber für das Beschriftungs-und Blasengrößen-Makro. Kann ich auf jeden Fall auch in Zukunft gut gebrauchen.

LG

 

Hi,

hier ein Code wie du das Blasendiagramm per VBA erstellen und (so wie bereits gepostet) formatieren kannst:

Code:

Sub DiaErstellenFormatieren()
   Dim intReihe As Integer
   With ActiveSheet.ChartObjects.Add(100, 100, 690, 476).Chart
      .ChartType = xlBubble
      For intReihe = 1 To 14
         With .SeriesCollection.NewSeries
            .Name = Worksheets("Bewertung").Range("$Q$" & intReihe + 5)
            .XValues = Worksheets("Bewertung").Range("$R$" & intReihe + 5)
            .Values = Worksheets("Bewertung").Range("$S$" & intReihe + 5)
            .BubbleSizes = Worksheets("Bewertung").Range("$T$" & intReihe + 5)
            .Format.ThreeD.BevelTopInset = 5
            .Format.ThreeD.BevelTopDepth = 2
            .ApplyDataLabels
            .DataLabels.Position = xlLabelPositionCenter
            .DataLabels.ShowValue = False
            .DataLabels.ShowSeriesName = True
         End With
      Next intReihe
      With .ChartGroups(1)
         .BubbleScale = 45
         .SizeRepresents = xlSizeIsWidth
      End With
      With .Axes(xlCategory)
         .MinimumScale = 0
         .MaximumScale = 3
         .ReversePlotOrder = True
         .MajorUnit = 0.5
         .MajorUnit = 1.5
         .HasMajorGridlines = True
      End With
      With .Axes(xlValue)
         .MinimumScale = 0
         .MaximumScale = 3
         .MajorUnit = 0.5
         .MajorUnit = 1.5
         .HasMajorGridlines = True
      End With
   End With
End Sub

Bis später,
Karin

 

HOLLA!
WOW!
DANKESCHÖN!!!!!!!! (nein Caps ist nicht unabsichtlich aktiviert^^)

LG