Office: positionsbestimmung in excel tabellenblatt

einen schönen guten abend an euch,...

mal ein etwas aussergewöhnliches anliegen, zumindest mit excel...


gibt es irgendwie eine möglichkeit, über ein tabellenblatt soetwas wie ein koordinatensystem zu legen, um damit eine position von einem bild, oder einer autoform auf diesem tabellenblatt wiederzugeben?

kann soetwas funktionieren mit excel, oder ist das eher nicht möglich?

ganz liebe grüße
sascha

 

Hi Sascha,

willst du da etwas mit VBA machen? Als "Koordinatensystem" kannst du z.b. die Zellen (Position Links und Position Oben) verwenden.

Bis später,
Karin

 

hallo karin,


ja auch gern mit vba, wenn das funktioniert :)

könntest du mir das vielleicht noch etwas näher bringen, wie du das meinst,...

ich hab mir das irgendwie so vorgestellt, dann wenn sich ein Objekt (z.b. eine Autoform) sich Bereich der Zelle B12 befindet, mir als Koordinaten die B12 ausgegeben wird?


liebe grüße
sascha

 

Hi Sascha,

der folgende Code gibt die Adresse der Zelle wieder, auf der das Rechteck 1 liegt:

Code:

Sub ZelleErmitteln()
    MsgBox Cells(ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Row, ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Column).Address
End Sub

Bis später,
Karin

 

boahh cool, des is ja der wohnsinn,...

geile sache, das funktioniert ja supi....

vielen vielen dank karin,....damit werd ich was anfangen können,


liebe grüße
sascha

 

hey karin,...

hab heut morgen etwas "rumgespielt" mit dem code von dir, und es funktioniert soweit alles richtig gut, ich lass mir die position in einer zelle ausgeben.

jetzt hätt ich eine weiterführende frage an dich :)...


lässt sich das auch umgekehrt vollziehen, also sprich wenn ich koordinaten in eine zelle eingebe, und sich somit das "rechteck1" auf die entsprechende position bewegt?

liebe grüße
sascha

 

Hi Sascha,

natürlich ist das ebenfalls möglich - nach folgendem Prinzip:

Code:

Sub ShapesPositionieren()
    ActiveSheet.Shapes("Rechteck 1").Left = Range("B12").Left
    ActiveSheet.Shapes("Rechteck 1").Top = Range("B12").Top
End Sub

Bis später,
Karin

 

hallo karin,
dankeschön für deine hilfe...

wie müsste ich den code ändern, dass er sich die zellposition "B12" aus einer zelle holt...also wenn ich in A3 "B12" eingebe?

grüüüße

 

Hi Sascha,

Code:

    ActiveSheet.Shapes("Rechteck 1").Left = Range(Range("A3")).Left
    ActiveSheet.Shapes("Rechteck 1").Top = Range(Range("A3")).Top

Hierbei bedeutet Range("A3") eigentlich Range("A3").Value - also Wert aus Zelle A3, aber da Value die Standardeigenschaft der Zelle ist, kann man es weglassen.

Bis später,
Karin

 

hallo,...

also du hast mir jetzt schon mega weitergeholfen, hätt ja nicht gedacht das das mit vba möglich wär :)))


jeze noch ne kleine frage von mir zur "verschönerung" ;)

wenn ich einer zelle einene Name gebe, zB "Rot", kann ich dann sagen "rechteck1" soll auf die zelle "rot" gesetzt werden?

liebe grüße
sascha


Edit:

hui habs hinbekommen :))) freu ****

also die zelle muss einfach mit einem namen benannt werden,...und den namen kann man dann anstelle der koordinaten in eine zelle schreiben...


nun noch eine frage an dich:
wenn sich mein rechteck 1, in zelle B2 befindet, und B2 hab ich einen Namen gegeben ("Rot"),...kann ich mir dann die position rot ausgeben lassen mit dem ersten code von dir???

liebe grüüüße
sascha

 

Hi Sascha,

der erste gepostete Code gibt die Position des Rechteckes, nicht der Zelle wieder - aber wenn das Rechteck auf der Zelle "Rot" liegt, ergibt dieser Code die Position der Zelle "Rot" wieder. Wenn es dir darum geht zu überprüfen, ob das Rechteck auf der Zelle "Rot" liegt, dann kannst du das mit folgendem Code prüfen:

Code:

Sub UebereinstimmungPruefen()
    If Cells(ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Row, ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Column).Address = Range("Rot").Address _
        Then MsgBox "Liegt auf Zelle Rot"
End Sub

Bis später,
Karin

 

hi karin,...

...also dein erster geposteter code, hab ich so geändert das mir die position nicht in einer msg box wiedergegeben wird sondern in zelle A1

code:

Code:

Sub ZelleErmitteln()
    Sheets("Tabelle1").Range("A1") = Cells(ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Row, ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Column).Address
End Sub

jetzt würd ich gern, wenn sich rechteck auf zelle B12="rot" befindet, dass mir in A1 anstelle der B12 als Positionsbeschreibung "rot" ausgibt...

so ungefähr denk ich mir irgendwie :))

liebe grüße
sascha

 

Hi Sascha,

da fällt mir im Augenblick nur die Möglichkeit ein, über den Zellnamen direkt zu gehen:

Möglichkeit 1

Code:

Sub ZellnameErmitteln1()
    Dim naName As Name
    For Each naName In ActiveWorkbook.Names
        If naName.RefersTo = "=Tabelle1!" & Cells(ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Row, ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Column).Address Then
            Sheets("Tabelle1").Range("A1") = naName.Name
            Exit For
        End If
    Next naName
End Sub

Möglichkeit 2

Code:

Sub ZellnameErmitteln2()
    Dim naName As Name
    For Each naName In ActiveWorkbook.Names
        If naName.RefersToRange.Row = ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Row And _
            naName.RefersToRange.Column = ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Column Then
            Sheets("Tabelle1").Range("A1") = naName.Name
            Exit For
        End If
    Next naName
End Sub

Möglichkeit 3

Code:

Sub ZellnameErmitteln3()
    Dim naName As Name
    For Each naName In ActiveWorkbook.Names
        If Cells(naName.RefersToRange.Row, naName.RefersToRange.Column).Address = Cells(ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Row, _
            ActiveSheet.Shapes("Rechteck 1").TopLeftCell.Column).Address Then
            Sheets("Tabelle1").Range("A1") = naName.Name
            Exit For
        End If
    Next naName
End Sub

Bis später,
Karin

 

servus karin,

einfach klasse, das haut genauso hin wie ich mir das vorgestellt hab....

richtig super, vielen dank hierfür...

grüüüüße