Office: (Office 2010) Power Query

Helfe beim Thema Power Query in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo, ein Experiment bei uns im Labor spuckt 1-6 Dateien mit der Endung "*.cla" aus. Je nach Anzahl der genutzten Kanäle. Ich bin in der Lage die... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Lorenz_FAU, 18. November 2021.

  1. Lorenz_FAU Neuer User

    Power Query


    Hallo,

    ein Experiment bei uns im Labor spuckt 1-6 Dateien mit der Endung "*.cla" aus. Je nach Anzahl der genutzten Kanäle.
    Ich bin in der Lage die Messdaten per Datenimport oder auch mit PowerQuery in Excel zu importieren, jedoch nur mit einzelnen Dateien.

    Wenn ich den Ordner mit allen Dateien durch Powerquery auf einmal importiere, setzt Excel die verschiedenen Kanäle in einer Tabelle lückenlos untereinander. Da jedes Experiment unterschiedlich lange dauert und somit auch eine unterschiedliche Anzahl an Zeilen erzeugt, kann ich die verschiedenen Kanäle im Anschluss nicht mehr gut per Makro oder durch Formeln voneinander trennen.

    Am besten wäre es, wenn die verschiedenen Dateien/Kanäle nach der Abfrage auf mehrere Tabellenblätter oder einfach nur in Spalten nebeneinander verteilt würden.

    Ich habe mal einen Screenshot von dem jetzigen Ergebnis meiner laienhaften Excelnutzung angehängt. Dort sieht man den lückenlosen Übergang von einem Kanal/Datensatz zum nächsten (Zeile 2877).

    Vielleicht hat jemand eine Idee wie ich diese Problem lösen könnte. Muss auch nicht schön sein :)

    Power Query Unbenannt.JPG
     
    Lorenz_FAU, 18. November 2021
    #1
  2. ralf_b Neuer User
    so wie ich das verstehe ist in spalte 1 die Möglichkeit von kammer 1 und kammer 2 zu unterscheiden.
    das könnte man filtern, und die gefilterten Werte per erweiterten Filter auf andere Blätter kopieren. auch eine Schleifenlösung per vba ist denkbar.
     
    1 Person gefällt das.
  3. Lorenz_FAU Neuer User
    Schonmal danke für die Antwort.

    Ich probiere das mal aus, befürchte aber, dass ich das mit meinen Kenntnissen nicht durch ein Makro voneinander trennen kann.

    Die Möglichkeit bei einer Ordner-Abfrage die Dateien getrennt voneinander in Tabellenblätter zu exportieren gibt es scheinbar nicht?
     
    Lorenz_FAU, 19. November 2021
    #3
  4. Exl121150 Erfahrener User

    Power Query

    Hallo,

    ich habe dir das Makro "ArbBlaetter_Erzeugen" gebastelt, welches in ein allgemeines Codemodul zu kopieren ist.

    1) Es kopiert die Sätze einer im aktiven Arbeitsblatt enthaltenen strukturierten Tabelle in Zielarbeitsblätter, wobei die Namen dieser Zielarbeitsblätter aus der 1. Spalte der Tabelle entnommen werden.
    2) Existiert ein Zielarbeitsblatt nicht, wird es erzeugt und auch die darin enthaltene strukturierte Tabelle.
    3) Die einzelnen Sätze werden am Ende der jeweiligen Zieltabelle angefügt.
    4) Existieren einzelne Zielarbeitsblätter beim Aufrufen des Makros bereits, können damit Mehrfachübernahmen in den Zieltabellen erfolgen. Ist dies jedoch nicht gewünscht, müssen vor dem Makroaufruf die Zielblätter entfernt werden.
    Code:
    Option Explicit
    Public Sub ArbBlaetter_Erzeugen()
       Dim WsQ As Worksheet     'Quellblatt    (=Aktives Arbeitsblatt)
       Dim lstQ As ListObject   'QuellTabelle  (=strukt.Tabelle im aktiven Arbeitsblatt)
       Dim rngQK As Range       'Kopfzeilen-Bereich der QuellTabelle
       Dim rowQ As ListRow      'Satz der QuellTabelle
      
       Dim WsZ As Worksheet     'ZielBlatt
       Dim lstZ As ListObject   'ZielTabelle
      
       Set WsQ = ActiveSheet           'Quellblatt ist aktives Blatt
       Set lstQ = WsQ.ListObjects(1)   'QuellTabelle ist die 1.Tabelle im Quellblatt
       Set rngQK = lstQ.HeaderRowRange 'Kopfzeilenbereich in der QuellTabelle
      
       On Error GoTo Err_BlattTab_Erzeugen
      
      'Durchlaufe alle Sätze der QuellTabelle
       For Each rowQ In lstQ.ListRows
          With rowQ.Range
            'Die 1.Spalte enthält den Namen des Zielblattes und auch den Namen der ZielTabelle ("Tab....")
             Set WsZ = Worksheets(.Cells(1).Value)
             Set lstZ = WsZ.ListObjects("Tab" & WsZ.Name)
            
            'Kopiere den Satz von der QuellTabelle an das Ende der ZielTabelle:
             .Copy Destination:=lstZ.ListRows.Add.Range
        
             Application.StatusBar = "Satz " & rowQ.Index
          End With
       Next rowQ
      
      'Abschlussarbeiten:
       WsQ.Activate: WsQ.Range("A1").Select
       MsgBox Replace("Alle Sätze # kopiert.", "#", lstQ.ListRows.Count)
      
       Exit Sub
      
    Err_BlattTab_Erzeugen:
    
      'Falls Zielblatt nicht existiert, erzeuge Zielblatt und auch die enthaltene ZielTabelle:
       With Worksheets.Add(After:=Worksheets(Worksheets.Count))
         .Name = rowQ.Range.Cells(1)
      
         rngQK.Copy Destination:=.Range("A1")
         .ListObjects.Add(SourceType:=xlSrcRange, Source:=.UsedRange, Xllistobjecthasheaders:=xlYes).Name = "Tab" & .Name
       End With
      
       Resume 'Fahre an der Stelle fort, an der der Fehler verursacht wurde
    
    End Sub
    
    Aufgerufen wird das Makro über die Tastenkombination Alt+F8 und anschließendes Ausführen von "ArbBlätter_Erzeugen".
    In der beiliegenden Demodatei ist auch ein Button enthalten, der mit dem Makro verknüpft ist.
     
    Exl121150, 20. November 2021
    #4
    1 Person gefällt das.
  5. Lorenz_FAU Neuer User
    Wow !
    Tausend Dank für deine Hilfe, funktioniert wunderbar. Damit kann ich auf jeden Fall arbeiten.

    Jetzt hab ich außerdem einen guten Grund mir einen neuen PC zu wünschen, denn bei knapp 3000 Zeilen und bis zu 6 Datensätzen braucht das Makro dafür eine Weile (Intel core i5).

    Nochmal Danke schön für den tollen Support!
     
    Lorenz_FAU, 22. November 2021
    #5
Thema:

Power Query

Die Seite wird geladen...
  1. Power Query - Similar Threads - Power Query

  2. Power Query - Abfragen zusammenführen

    in Microsoft Excel Hilfe
    Power Query - Abfragen zusammenführen: Hallo! Ich habe eine Frage zum Power Query, wenn zwei Abfragen zusammengeführt werden sollen. Wie in der angehängten Datei gezeigt ist, habe ich eine Daten Tabelle und eine Mapping Tabelle, aus...
  3. Hilfe dringend benötigt :)

    in Microsoft Excel Hilfe
    Hilfe dringend benötigt :): Hallo zusammen, ich brauche dringend eure Hilfe. Ich bin leider absolut keine Excel-Expertin und brauche für meine Arbeit dringend eine VBA Programmierung und eine Tabelle, die automatisiert...
  4. Power Query Excel import

    in Microsoft Excel Hilfe
    Power Query Excel import: Hallo zusammen, leider bin ich auf eine kleine Herausforderung gestoßen, wo ich mit Google vorerst nicht weiter komme. Ich möchte eine Excel in Power BI hochladen, jedoch wird im Power Query eine...
  5. Datenabruf Coinmarketcap

    in Microsoft Excel Hilfe
    Datenabruf Coinmarketcap: Hallo in die Runde. Ich hoffe, es kann mir hier jemand einen Tipp geben. Ich versuche, die aktuellen Kryptowährungskurse von der Webseite Coinmarketcap in Excel 2019 zu importieren. Hierfür...
  6. Mit Power Query Beitragsübersicht des Forums in Excel importieren und aufbereiten

    in Microsoft Excel Hilfe
    Mit Power Query Beitragsübersicht des Forums in Excel importieren und aufbereiten: Ich suche immer wieder mal einen älteren Beitrag und mühe mich dann jedes Mal ab, bis ich diesen gefunden habe. Damit dies zukünftig einfach wird, habe ich nun für das Excel-Forum einen Import...
  7. Power Query -> sortieren / aktualisieren

    in Microsoft Excel Hilfe
    Power Query -> sortieren / aktualisieren: Hallo zusammen Kann man, oder wie kann man das Problem lösen das ich im Anhang beschrieben habe? Für eine Antwort bedanke ich mich. Es grüsst Fösi 365962
  8. Abfrage von historischen Daten aus SharePoint-Liste mit Power Query

    in Microsoft Excel Hilfe
    Abfrage von historischen Daten aus SharePoint-Liste mit Power Query: Guten Tag, um den Status verschiedener Projekte zu verfolgen nutzen wir eine SharePoint-Liste. Um verschiedene statistische Auswertungen durchführen rufe ich die Liste in Excel mittels...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden