Office: Problem mit dem Auslesen von Werten aus einer anderen Excel

Hallo, ich habe ein kleines Problem mit dem Auslesen von Werten aus einer anderen Excel Datei. Ich habe schon Gegoogelt aber für dieses Problem noch nichts gefunden und habe eigendlich auch von VBA nicht viel Ahnung.

Hier mein Problem:

Ich habe 2 Excel Tabellen.
Die eine heißt helpline und die Zweite Monatsbericht (haben immer den selben Namen).

Nun möchte ich von der Datei Monatsbericht ausgehend Werte aus der Datei helpline auslesen und in der Datei Monatsberichte weiterverarbeiten.

Die Werte dich ich auslesen will sind in der Datei helpline unter Sheet1 immer in der Spalte E.
Dort stehen 4 verschiedene Texte: Offen, Geschlossen, Gelöst und Warte auf.
Nun möchte ich die jeweils für jeden Text die Anzahl auslesen und den Wert in der Datei Monatsberichte unter Helpline jeweils in den Zellen B5, C5, D5 und E5 ausgeben, bedeutet

wenn in der Datei helpline in der Spalte E 17x Offen steht soll er in der Datei Monatsbericht unter Helpline in der Zelle B5 den Wert 17 eintragen,
wenn dort 30x Warte auf steht soll er in der Zelle C5 den Wert 30 eintragen usw.

Hoffe ihr könnt mir hier helfen.

Im vorraus vielen Dank.

 

Hallo!

Ist die Excel-Datei "Helpline.xls" geöffnet, dann ergeben sich in der Monatsberichts-Excel-Datei folgende 4 Formeln:

	A	B	C	D	E
1
2
3
4		Offen	Warte auf	Geschlossen	Gelöst
5		4	3	3	2
6

Zelle	Formel
B5	=ZÄHLENWENN([Helpline.xls]Sheet1!$E$1:$E$65000;B4)
C5	=ZÄHLENWENN([Helpline.xls]Sheet1!$E$1:$E$65000;C4)
D5	=ZÄHLENWENN([Helpline.xls]Sheet1!$E$1:$E$65000;D4)
E5	=ZÄHLENWENN([Helpline.xls]Sheet1!$E$1:$E$65000;E4)

Sobald Du jedoch die "Helpline.xls"-Datei schließst, stehen in der Monatsberichts-Excel-Datei plötzlich ohne weiteres Zutun folgende Formeln:

	A	B	C	D	E
1
2
3
4		Offen	Warte auf	Geschlossen	Gelöst
5		4	3	3	2
6

Zelle	Formel
B5	=ZÄHLENWENN('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000;B4)
C5	=ZÄHLENWENN('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000;C4)
D5	=ZÄHLENWENN('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000;D4)
E5	=ZÄHLENWENN('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000;E4)

Dabei steht natürlich jeweils der Abschnitt '\\Srv-w2003-2\Server_I\EXCEL\Forum\' für den Pfad der Helpline.xls-Datei, der bei Dir entsprechend anders lauten wird. Falls Du diesen Pfad händisch eingeben möchtest, solltest Du auch noch auf die Stellung der beiden Hochkommas '...' achten.
Ferner ist in beiden Fällen auf die Verwendung der beiden eckigen Klammern zu achten!
Ferner ist bei Dir der Bereich $E$1:$E$65000 auf den Bereich zu reduzieren, der bei Dir tatsächlich verwendet wird.

 

Hey Danke für diese Formeln, funktionieren Super.

Was ich aber Vergessen hatte ist das ich nach Möglichkeit nicht die Datei helpline vorher öffnen will (ist ne Datei für meinen Chef und der kommt schnell durcheinander wenn er mehrere Dateien öffnen soll - ist halt ein Chef)

Gäbe es den dafür eine Möglichkeit?

 

Hallo!

Ich habe Dir ja 2 Varianten gepostet, wobei die 2. Variante funktioniert, ohne vorher die Datei Helpline.xls öffnen zu müssen.
Nur beim Erstellen der Formeln ist es bequemer (aber nicht notwendig), zuerst die Datei Helpline.xls zu öffnen, denn dann erspart man sich die korrekte Eingabe des Pfades dieser Datei.

 

Hallo,
die 2.Variante funktioniert so nicht.
Wenn ich die Masterdatei öffne aktualisiere ich die Verknüpfung doch leider kommt keinerlei Ergebnis.

Ist die Datei helpline hingegen schon vorher geöffnet so bekomme ich das korrekte ergebnis

 

Hallo!

Damit hast Du recht. Ich habe nämlich Excel2007 und da funktioniert der Zugriff auf eine geschlossene Arbeitsmappe aus der ZÄHLENWENN-Funktion heraus einwandfrei - leider aber sonderbarerweise nicht bei Excel2003, obwohl auch dort die Abholung eines einzelnen Wertes in eine Zelle bei geschlossener Quellarbeitsmappe einwandfrei funktioniert.

Als Workaround habe ich jetzt unter Excel2003 Folgendes als funktionierend getestet:

	A	B	C	D	E
1
2
3
4		Offen	Warte auf	Geschlossen	Gelöst
5		4	12	3	2
6

Zelle	Formel
B5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=B$4)*1)
C5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=C$4)*1)
D5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=D$4)*1)
E5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=E$4)*1)

In der SUMMENPRODUKT-Funktion funktioniert auch unter Excel2003 der Zugriff auf eine geschlossene Arbeitsmappe einwandfrei.

 

Vielen Dank, das ist genau das was ich gesucht hatte.
Und ich dachte das Funktioniert nur per VBA.

Super!

Danke nochmals

 

So, leider muss ich euch nochmal bemühen,

jetzt will mein Chef noch zusätzlich zu den Oben genannten Kriterien noch das z.B. alle Zellen die in der Spalte E Offen stehen haben UND in der Spalte K Haus stehen haben zusammengezählt werden.

Wie kann ich diese bedienung noch einbauen?

 

Hallo!

Folgende Formeln:

	A	B	C	D	E	F
1
2
3	Spalte K:					Haus
4	Spalte E:	Offen	Warte auf	Geschlossen	Gelöst	Offen
5		4	12	3	2	2
6

Zelle	Formel
B5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=B4)*1)
C5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=C4)*1)
D5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=D4)*1)
E5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=E4)*1)
F5	=SUMMENPRODUKT(('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$E$1:$E$65000=F4)*('\\Srv-w2003-2\Server_I\EXCEL\Forum\[Helpline.xls]Sheet1'!$K$1:$K$65000=F3))

 

Super, das ist es.

Vielen Dank, klappt Wunderbar und sogar noch besser.