Office: Problem mit meinem VBA bzw Makro

Guten Morgen Ihr lieben Helfer.

Ich habe hier ein kleines problem.

Code:

Sub drucken()
Sheets(Array("Label")).PrintOut Copies:=1, Collate:=True,
End Sub

Ich habe diesen Code bei mir drin und soweit klappt das aj auch nur haben ich diese Tabelle ausgeblendet und darum druck er mit das nicht. Wasmuß ich in diesem Code ergänzen das er mir das druckt. Mit der Aufzeichnung bin ich nicht weiter gekommen da er mir immer nur ein anderes Blatt druckt.


Ich wäre euch sehr danbar wenn ihr mir da helfen könntent.


Gruß Michael

 

Hallo

habe eine Lösung gefunden nur möchte ich nun das immer nur bis zur Letzten Zeille gedruckt wird, wobei in jeder Zeile eine Formel steht. Nur immer wieder 20 Seiten zu drucken wobei davon mehr als die hälfte noch leer ist. Wie kann ich das machen? Mir würde auch reichen wenn ich die Anzahl der Seiten sagen könnte da die Tabelle die Daten einer anderen Tablle übernimt aber nicht alle Daten. Wer kann mir da helfen. Hier auch mal den Code den ich gerade verwende.

Code:

Option Explicit

Sub Labeldruck()
    Application.ScreenUpdating = False
    With Worksheets("Label")
        .Visible = True
        .PrintOut
        .Visible = False
    End With
End Sub

Ich danke euch für die Hilfe.

 

Hallo Michael,

die erste leere Zelle zu ermitteln ist eigentlich nicht schwer.
Etwas komplizierter wirds, wenn die Zellen nur leer aussehen, es aber nicht sind, weil sie Formeln enthalten.
In dem Fall kann man zum Beispiel eine Schleife benutzen:

Code:

Option Explicit

Sub Labeldruck()

Dim loLastRow As Long
Dim loCounter As Long

    Application.ScreenUpdating = False
    With Worksheets("Label")
        .Visible = True
    ' letzte benutzte Zelle in Spalte 1 ermitteln = Startwert für die folgende Schleife
        loLastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    ' Schleife um die letzte Zelle in Spalte 1 mit einem Wert zu finden
        For loCounter = loLastRow To 1 Step -1
            If .Cells(loCounter, 1) <> "" Then
                loLastRow = loCounter
                Exit For
            End If
        Next loCounter
    ' Druckbereich festlegen
        .PageSetup.PrintArea = "$A$1:$B$" & loLastRow
        .PrintOut
        .Visible = False
    End With
    Application.ScreenUpdating = True
    
End Sub

Wenn Du die Bildschirmaktualisierung ausschaltest, vergesse nie sie auch wieder anzuschalten.
;O)


Ich hoffe geholfen zu haben.

 

Danke Dir erstmal für die Hilfe nur leider klappt das nicht so richtig. Es wir zwar gedruckt aber immer nur alles und nicht nur bis zur letzten Zeille die Seite.

Die Tabelle besteht aus 7 Spalten von A - G und 490 Zeilen in jeder Zelle steht ein Formael die sich die Daten aus einer anderen Tabelle holt. Nun soll aber nur bis zur letzten Zeille die Seite gedruckt werden. wenn jetzt zum Besipiel in Zeille 184 die Letzen Daten stehen soll Seite 5 noch komplett gedruckt werden. Ich hoffe es hatt noch jemand einen Vorschlag für mich.

 

Achim's Code überprüft von unten her angefangen, in welcher Zeile in Spalte A nichts ( = "" ) mehr steht.

Code:

If .Cells(loCounter, 1) <> "" Then

Um sicher zu gehen, versuch mal:

Code:

If Trim$(.Cells(loCounter, 1).Value) <> "" Then

Solte auch das nicht funktionieren, wird Achim wohl etwas mehr Input brauchen, was eigentlich "leer" heißt. Dafür wird er u.a. wohl mindest die Formel(n) kennen müssen, die die Daten aus dem anderen Blatt ziehen.

[GLASKUGEL]
In Tabelle1 steht z.B. in A53:
=Tabelle2!A53
Und ist die dortige Zelle leer, wird als Ergebnis "0" zurückgeliefert. Und dann hat jemand in der bedingten Formatierung
"Zellwert ist gleich 0" --> Textfarbe weiß
gesetzt.
[/GLASKUGEL]

*breitgrins*

Gruß, Michael

 

Hallo und auch danke aber das hatt leider auch nicht geklappt.

=Tabelle2!A53 das ist meine Formel und ich habe Eingestellt bei Nullwerten ein 0 anzeigen = Hacken raus

 

Hallo Michael & Michael ...
;O)

Erstmal danke an miriki für die Schützenhilfe.


@Blacky1980
Probiers mal so:

Code:

Option Explicit

Sub Labeldruck()

Dim loLastRow As Long
Dim loCounter As Long

    Application.ScreenUpdating = False
    With Worksheets("Label")
        .Visible = True
    ' letzte benutzte Zelle in Spalte 1 ermitteln = Startwert für die folgende Schleife
        loLastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    ' Schleife um die letzte Zelle in Spalte 1 mit einem Wert zu finden
        For loCounter = loLastRow To 1 Step -1
            If .Cells(loCounter, 1)[COLOR=#ff0000].Text[/COLOR] <> "" Then
                loLastRow = loCounter
                Exit For
            End If
        Next loCounter
    ' Druckbereich festlegen
        .PageSetup.PrintArea = "$A$1:$B$" & loLastRow
        .PrintOut
        .Visible = False
    End With
    Application.ScreenUpdating = True
    
End Sub

Sollte eigentlich klappen...
Andererseits ist Dein Text ein klein wenig unverständlich.
Was genau soll eigentlich ausgedruckt werden?
Alle Zeilen bis zur letzten mit einem Wert?
Oder soll geschaut werden, in welcher Druckseite sich die letzte Zeile mit Wert befindet, und diese Seite soll dann komplett (also auch die noch dahinein passenden Leerzeilen) gedruckt werden?


Ich hoffe geholfen zu haben.

 

Super! Danke Achim so ist es wie das wollte die letzten lerr Zeilen sind nicht so wichtig. Sieht zwar besser aus vor allem wenn nur zwei Zeilen auf der letzten Seite sind. Wäre schön wenn es noch gehen würde. Aber ein riesen Dank an Achim und Michael einfach nur kalsse.
Zu Deiner Frage Achim.
Alle Zeilen bis zur letzten mit einem Wert und auch die noch dahinein passenden Leerzeilen.

 

Hallo Michael,

dass sollte dann eigentlich so funktionieren:

Code:

Option Explicit

Sub Labeldruck()

Dim loLastRow As Long
Dim loCounter As Long

    Application.ScreenUpdating = False
    With Worksheets("Label")
        .Visible = True
    ' letzte benutzte Zelle in Spalte 1 ermitteln = Startwert für die folgende Schleife
        loLastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    ' Schleife um die letzte Zelle in Spalte 1 mit einem Wert zu finden
        For loCounter = loLastRow To 1 Step -1
            If .Cells(loCounter, 1).Text <> "" Then
                loLastRow = loCounter
                Exit For
            End If
        Next loCounter
[COLOR=#ff0000]    ' Druckbereich auf die Spalten A-G festlegen
        .PageSetup.PrintArea = "$A:$G"
    ' Schleife um letzten Seitenumbruch vor loLastRow zu finden
        loCounter = 1
        Do
            If (.HPageBreaks(loCounter).Location.Row - 1) > (loLastRow - .HPageBreaks(1).Location.Row) Then
            ' letzte Zeile manuell festlegen
                loLastRow = .HPageBreaks(loCounter).Location.Row + .HPageBreaks(1).Location.Row - 2
                Exit Do
            Else
                loCounter = loCounter + 1
            End If
        Loop[/COLOR]
    ' Druckbereich festlegen
        .PageSetup.PrintArea = "$A$1:$G$" & loLastRow
        .PrintOut
        .Visible = False
    End With
    Application.ScreenUpdating = True
    
End Sub

Allerdings gehe ich dabei auch davon aus, dass die Zeilen alle gleich hoch sind, denn ich beziehe mich ja auf die Anzahl Zeilen der ersten Seite. Also dass immer gleichviele Zeile auf die Seiten passen.
Wenn dem nicht so sein sollte, müssen wir uns etwas anderes überlegen.


Ich hoffe geholfen zu haben.

 

Super!!!!! Danke Dir Achim. Nur ein kleines Problem in mom habe ich nur auf 1,5 Seiten Daten stehen aber er druckt mir 3 Seiten wobei auf Seite 3 nur eine einzige Zeile ist die aber auch leer ist. Habe aber etwas versucht und es hat geklappt. so war es von Dir

So habe ich es gemacht

Hier nochmal den Code wie ich jetzt habe und wie er perfekt ist.

Code:

Option Explicit

Sub Labeldruck()

Dim loLastRow As Long
Dim loCounter As Long

    Application.ScreenUpdating = False
    With Worksheets("Label")
        .Visible = True
    ' letzte benutzte Zelle in Spalte 1 ermitteln = Startwert für die folgende Schleife
        loLastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    ' Schleife um die letzte Zelle in Spalte 1 mit einem Wert zu finden
        For loCounter = loLastRow To 1 Step -1
            If .Cells(loCounter, 1).Text <> "" Then
                loLastRow = loCounter
                Exit For
            End If
        Next loCounter
    ' Druckbereich auf die Spalten A-G festlegen
        .PageSetup.PrintArea = "$A:$G"
    ' Schleife um letzten Seitenumbruch vor loLastRow zu finden
        loCounter = 1
        Do
            If .HPageBreaks(loCounter).Location.Row > (loLastRow - .HPageBreaks(1).Location.Row) Then
            ' letzte Zeile manuell festlegen
                loLastRow = .HPageBreaks(loCounter).Location.Row + .HPageBreaks(1).Location.Row - 2
                Exit Do
            Else
                loCounter = loCounter + 1   [U][B] (habe da eine 0 rein gemacht)[/B][/U]
            End If
        Loop
    ' Druckbereich festlegen
        .PageSetup.PrintArea = "$A$1:$G$" & loLastRow
        .PrintOut
        .Visible = False
    End With
    Application.ScreenUpdating = True
    
End Sub

Super die Leute und das Forum. War noch in einem anderen Forum aber da habe ich immer erst mal Dummesprüche zu lesen bekommen bis ich mal ne vernüftige Antwort bekommen habe. Ich Danke Dir Achim einfach klasse!!!!

 

Hallo Michael,

so leid es mir tut, aber dass:

ist leider Schwachfug.
Die Variable loCounter muss in der Schleife um eins hochgezählt werden, denn nur so werden alle horizontalen Seitenumbrüche nacheinander geprüft.
Ändere die Null also bitte wieder in eine Eins.
Der Fehler ist woanders zu suchen.

Übrigens, ich hatte meinen Code noch ganz leicht abgeändert, offensichtlich erst nachdem Du ihn Dir rauskopiert hattest.
Und zwar die folgende Zeile:

Code:

If .HPageBreaks(loCounter).Location.Row > (loLastRow - .HPageBreaks(1).Location.Row) Then

in

Code:

If (.HPageBreaks(loCounter).Location.Row - 1) > (loLastRow - .HPageBreaks(1).Location.Row) Then

Den Fehler den Du beschreibst, kann ich nicht nachvollziehen.
Kannst Du bitte mal eine Beispielmappe zum Testen hochladen, wo man den Fehler nachvollziehen kann?

 

Hallo Michael,

probiere bitte mal den folgenden Code, jetzt sollte es eigentlich klappen, egal wieviele Datenzeilen Du hast.

Code:

Option Explicit

Sub Labeldruck()

Dim loLastRow As Long
Dim loCounter As Long

    Application.ScreenUpdating = False
    With Worksheets("Label")
        .Visible = True
    ' letzte benutzte Zelle in Spalte 1 ermitteln = Startwert für die folgende Schleife
        loLastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    ' Schleife um die letzte Zelle in Spalte 1 mit einem Wert zu finden
        For loCounter = loLastRow To 1 Step -1
            If .Cells(loCounter, 1).Text <> "" Then
                loLastRow = loCounter
                Exit For
            End If
        Next loCounter
    ' Druckbereich auf die Spalten A-G festlegen
        .PageSetup.PrintArea = "$A:$G"
    ' Schleife um letzten Seitenumbruch vor loLastRow zu finden
       [COLOR=#ff0000] If .HPageBreaks.Count > 0 Then[/COLOR]
            loCounter = 1
            Do
                If [COLOR=#ff0000]([/COLOR].HPageBreaks(loCounter).Location.Row[COLOR=#ff0000] - 1)[/COLOR] > (loLastRow - .HPageBreaks(1).Location.Row) Then
                ' letzte Zeile manuell festlegen
                    loLastRow = .HPageBreaks(loCounter).Location.Row + .HPageBreaks(1).Location.Row - 2
                    Exit Do
                Else
                    loCounter = loCounter + 1
                End If
            Loop
        ' Druckbereich festlegen
            .PageSetup.PrintArea = "$A$1:$G$" & loLastRow
            .PrintOut
[COLOR=#ff0000]        Else
        ' eine Seite drucken
            .PrintOut From:=1, To:=1
        End If[/COLOR]
        .Visible = False
    End With
    Application.ScreenUpdating = True
    
End Sub

 

Naja aber es hatt geklapt.


So wie hier der Code ist habe ich ihn drin mit der 0

Code:

Sub Listendruck()

Dim loLastRow As Long
Dim loCounter As Long

    Application.ScreenUpdating = False
    With Worksheets("Maschinen Liste")
        .Visible = True
    ' letzte benutzte Zelle in Spalte 1 ermitteln = Startwert für die folgende Schleife
        loLastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    ' Schleife um die letzte Zelle in Spalte 1 mit einem Wert zu finden
        For loCounter = loLastRow To 1 Step -1
            If .Cells(loCounter, 1).Text <> "" Then
                loLastRow = loCounter
                Exit For
            End If
        Next loCounter
    ' Druckbereich auf die Spalten A-G festlegen
        .PageSetup.PrintArea = "$A:$G"
    ' Schleife um letzten Seitenumbruch vor loLastRow zu finden
        loCounter = 1
        Do
            If .HPageBreaks(loCounter).Location.Row > (loLastRow - .HPageBreaks(1).Location.Row) Then
            ' letzte Zeile manuell festlegen
                loLastRow = .HPageBreaks(loCounter).Location.Row + .HPageBreaks(1).Location.Row - 2
                Exit Do
            Else
                loCounter = loCounter + 0
            End If
        Loop
    ' Druckbereich festlegen
        .PageSetup.PrintArea = "$A$1:$G$" & loLastRow
        .PrintOut
        .Visible = False
    End With
    Application.ScreenUpdating = True
    
End Su

Ich kann Dir die Mappe per Mail schicken da die ganzen Daten vorhanden sind.

Es ist nur noch ein schönheitsfehler drin wäre schön wenn man den noch weg bekommen könnte. Beim Druck sind es auf der ersten und der letzten Seite werden unterschiedliche Zeilen Anzahlen gedruckt. Schön wäre es wenn es immer gleich viele Zeilen wären.

Seite1 = 42 Zeilen Seite2+3 = 45 Zeilen Seite4 =43 Zeilen.

Könnte man das auf 45Zeilen pro Seite festlegen?

Aber vielen Dank an Achim echt ein super hilfe biste mir mit dem ganzen Mist da.


Gruß Michael

 

Hallo Michael,
glaub es mir doch einfach: es ist Schwachfug
Geklappt hat es vermutlich nur, weil eh nur der erste Seitenumbruch geprüft werden musste.
Denn die Variable loCounter wird als Zähler für die Seitenumbrüche benutzt.
Die Zeile loCounter = loCounter + 0 bewirkt also nichts anderes, als das sich der zugewiesene Wert dieser Variable nicht verändert, somit ist die Zeile völlig überflüssig.
Dadurch dass sich der Wert aber nicht verändert, bleibt die Variable beim Wert 1, und somit wird immer nur der erste Seitenumbruch geprüft.
Wenn Du mehrere Hundert Datenzeilen hast, und dementsprechend mehrere Druckseiten, würde die Schleife immer nur den ersten Umbruch prüfen und die Bedingung für den Abbruch der Schleife wäre niemals erfüllt.
Du hättest also eine super funktionierende ENDLOSSCHLEIFE.

Also vergiss bitte endlich diese 0!



Abgesehen davon hatte ich ja bereits ein Update des Codes gepostet.
Bevor ich jetzt weiter daran rumdocktere, probiere bitte erstmal diesen aus, und gib Rückmeldung ob alles klappt, oder was nicht klappt.



Die Beispieldatei bitte nicht per Mail, für solche Fälle kann man hier im Forum Anhänge hochladen.
Schließlich sollen alle Mitlesenden, und auch zukünftig alle Lösungssuchenden den Lösungsweg verstehen und nachvollziehen können.


Zum Schluss noch eine Bitte:
Wenn Du Code veränderst (die 0), dann versuche vorher zu verstehen was der Code macht.
Verstehst Du ihn nicht, dann verändere ihn auch nicht, denn Du kannst ja nicht wissen was er danach macht.
Falls Du etwas von meinem Code nicht verstehst, dann frage danach.
Ich werde ihn Dir dann erklären.

 

Hallo Achim


Danke Dir nochmal für die Antwort!

Code:

Option Explicit


Sub Listendruck()

Dim loLastRow As Long
Dim loCounter As Long

    Application.ScreenUpdating = False
    With Worksheets("Maschinen Liste")
        .Visible = True
    ' letzte benutzte Zelle in Spalte 1 ermitteln = Startwert für die folgende Schleife
        loLastRow = .Cells(Rows.Count, 1).End(xlUp).Row
    ' Schleife um die letzte Zelle in Spalte 1 mit einem Wert zu finden
        For loCounter = loLastRow To 1 Step -1
            If .Cells(loCounter, 1).Text <> "" Then
                loLastRow = loCounter
                Exit For
            End If
        Next loCounter
    ' Druckbereich auf die Spalten A-G festlegen
        .PageSetup.PrintArea = "$A:$G"
    ' Schleife um letzten Seitenumbruch vor loLastRow zu finden
        If .HPageBreaks.Count > 0 Then
            loCounter = 1
            Do
                If (.HPageBreaks(loCounter).Location.Row - 1) > (loLastRow - .HPageBreaks(1).Location.Row) Then
                ' letzte Zeile manuell festlegen
                    loLastRow = .HPageBreaks(loCounter).Location.Row + .HPageBreaks(1).Location.Row - 2
                    Exit Do
                Else
                    loCounter = loCounter + 1
                End If
            Loop
        ' Druckbereich festlegen
            .PageSetup.PrintArea = "$A$1:$G$" & loLastRow
            .PrintOut
        Else
        ' eine Seite drucken
            .PrintOut From:=1, To:=1
        End If
        .Visible = False
    End With
    Application.ScreenUpdating = True
    
End Sub

Habe nun diesen Code drin und es geht auch genau so wie ich das möchte nr ebend der eine Schönheitsfhler mit den verschiedenen anzahlen an Zeillen pro Seite. Hier wie es gedruckt wird:
Seite1 = 42 Zeilen
Seite2 = 45 zeilen
Seite3 = 45 Zeilen
Seite4 = 43 Zeilen

Habe auch die 1 gelassen wie Du gesagt hast habe nach dem ich die Vorhanden Daten kopiert hatte und unterhalb eigfügt hatte habe ich gemerkt wass passiert. Excel Reagiert nicht mehr und bricht zusammen mit der 1 passiert das nicht.

Wie kann man das nun machen das es immer 45 Zeilen pro Seite sind selbst wenn nur 3 Zeilenn einen Wert auf der letzen Seite haben sollen dann ebend der rest leer gedruckt werden? Aber nur bis zum ende der Seite.


Ich hoffe Du verstehst wass im damit sagen will.

Griuß Michael