Office: Problem mit Verknüpfung von Zeilen

Hallo,

ich bin nun schon fast den ganzen Nachmittag am herum probieren, wie ich Zeilen miteinander verknüpfen kann und komme auf kein 100%iges Ergebnis. Jetzt hab ich durch Zufall euer Forum hier entdeckt und dachte mir vielleicht kann mir hier wer helfen.

Und das ist die Problemstellung:

Ich möchte in einem Tabellenblat 3 Spalten anlegen die pro Zeile mit einem unterschiedlichen Wort gefüllt werden. Danach soll in einer neuen Tabelle in Zeile 1 das erste Wort aus der ersten Spalte angezeigt werden, darunter dann das erste und zweite Wort usw., also eine Auflistung aller Möglicher Wortkombinationen einer Zeile.

Als Beispiel wäre das Tabelle 1:

A B C
1 Ich will Kekse
2 Du willst Kekse
3 Er will Kekse

Und das sollte in Tabelle 2 ausgegeben werden:

A
1 Ich
2 Ich will
3 Ich will Kekse
4 Du
5 Du willst
6 Du willst Kekse
7 Er
8 Er will
9 Er will Kekse
usw.

Ich habe das bisher nur so lösen können, dass ich die verschiedenen Phrasen nebeneinander und untereinander im Raster mit dieser Formel in Tabelle2 =Tabelle1!A$2&Tabelle1!$B2 darstellen konnte, aber so wie ich es gerne hätte schaff ich es einfach nicht. Hätte hier jemand einen Lösungsansatz für mich?

mfg bullet

 

Hallo bullet,

hier mein Vorschlag:

A1

A2

A3

Leider kann man das so nicht einfach runterziehen.
Aber vielleicht hilft dir das ja schonmal, oder jemand anderes weiß da noch Rat.

 

Hi Elfe,

vielen Dank für die Antwort, das klappt eigentlich schon ganz gut. Wäre es auch irgendwie möglich zu sagen, dass wenn die Verknüpfung von A1 mit B1 bis Bx erledigt ist, dass dann mit A2 mit B1 bis Bx weiter gemacht wird?

Ist etwas komplizierter als anfangs eigentlich dachte. :)

 

Ähm...
Hä?

*lach*
Was meinst Du?

 

Hallo!

	A	B	C	D	E
1	ich	will	Kekse		ich
2	du	willst	Bonbons		ich will
3	er	will	Limo		ich will Kekse
4					du
5					du willst
6					du willst Bonbons
7					er
8					er will
9					er will Limo

Zelle	Formel
E1	=INDEX(A:A;ZEILE(A3)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A3)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A3)/3))
E2	=INDEX(A:A;ZEILE(A4)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A4)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A4)/3))
E3	=INDEX(A:A;ZEILE(A5)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A5)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A5)/3))
E4	=INDEX(A:A;ZEILE(A6)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A6)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A6)/3))
E5	=INDEX(A:A;ZEILE(A7)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A7)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A7)/3))
E6	=INDEX(A:A;ZEILE(A8)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A8)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A8)/3))
E7	=INDEX(A:A;ZEILE(A9)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A9)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A9)/3))
E8	=INDEX(A:A;ZEILE(A10)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A10)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A10)/3))
E9	=INDEX(A:A;ZEILE(A11)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A11)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A11)/3))

 

Wow, das scheint soweit zu funktionieren! Vielen Dank schatzi!

Da ich nicht genau durchblicke welcher Teil der Formel was macht, wärst du so nett und würdest mir das noch ein wenig erklären, damit ich den Background dazu auch besser verstehen kann?

gruß, bu11e7

 

Hallo!

Die Formel besteht logischerweise aus drei großen Teilen:

=INDEX(A:A;ZEILE(A3)/3)&WENN(REST(ZEILE();3)=1;"";" "&INDEX(B:B;ZEILE(A3)/3))&WENN(REST(ZEILE();3);"";" "&INDEX(C:C;ZEILE(A3)/3))

roter Teil:
Die INDEX-Funktion ist recht einfach, z.B.: =INDEX(M:M;23) liefert den Wert aus M23.
Ich benutze hier noch die Funktion ZEILE, damit man die Formel nach unten ziehen kann. Was passiert also mit dem Term ZEILE(A3)/3 beim Runterziehen?

	A	B
1
2		1
3		1,33333333
4		1,66666667
5		2
6		2,33333333
7		2,66666667
8		3
9		3,33333333

Zelle	Formel
B2	=ZEILE(A3)/3
B3	=ZEILE(A4)/3
B4	=ZEILE(A5)/3
B5	=ZEILE(A6)/3
B6	=ZEILE(A7)/3
B7	=ZEILE(A8)/3
B8	=ZEILE(A9)/3
B9	=ZEILE(A10)/3

Aha, er zählt also in Drittel-Schritten hoch. Die INDEX-Funktion wiederum hat die (hier praktische) Eigenschaft, die Nachkommastellen einfach abzuschneiden. Es bleibt also die Folge {1;1;1;2;2;2;3;3;...}, daher liefert der rote Teil die Werte A1;A1;A1;A2;A2;A2;A3;A3;... zurück.

grüner Teil:
Die WENN-Funktion prüft, ob beim Teilen der aktuellen Zeilennummer durch 3 ein Rest von 1 bleibt. Das ist der Fall in den Zeilen 1;4;7;10;...
In diesen Fällen/Zeilen wird nur ein Leerstring gesetzt, in allen allen Fällen/Zeilen liefert INDEX den passenden Wert aus Spalte B.

violetter Teil:
Die WENN-Funktion prüft, ob beim Teilen der aktuellen Zeilennummer durch 3 überhaupt ein Rest bleibt. Das ist der Fall in den Zeilen 1;2;4;5;7;8;...
In diesen Fällen/Zeilen wird nur ein Leerstring gesetzt, in allen allen Fällen/Zeilen liefert INDEX den passenden Wert aus Spalte C.