Office: (Office 2007) Probleme beim Runden in Verschachtelter Wenn Funktion mit Index/Vergleich

Hallo ihr Lieben,

Ich habe folgendes Problem: Ich habe eine recht lange Preisliste in der in Spalte A Die Auflage und in Spalte C der Gesamtpreis der Waren stehen. Ich bin gerade dabei mir eine Formel zu schreiben, mit der ich in einer Zelle die gewünschte Auflage eingebe und in einer anderen dann der entsprechende Preis angezeigt wird. Allerdings handelt es sich um eine Staffelpreisliste, welche von 100 - 200 die Auflage in 5er, von 200 - 2000 in 10er und vonn 2000 bis10000 in 100er Schritten angibt. Die Zwischenschritte werden aus dem Stückpreis der nächstniedrigeren Auflage errechnet. Bis jetzt habe ich mir folgendes zusammengegoogelt:

=WENN(ISTNV(VERGLEICH(O5;$A$4:$A$416;0));((INDEX(C4:C416;VERGLEICH(ABRUNDEN(O5/5;0)*5;$A$4:$A$416;0)))/(ABRUNDEN(O5/5;0)*5))*O5;WENN(UND(O5>200;O5<2000);((INDEX(C4:C416;VERGLEICH(ABRUNDEN(O5;-1);$A$4:$A$416;0)))/(ABRUNDEN(O5;-1)))*O5;WENN(UND(O5>2000;O5<10000);((INDEX(C4:C416;VERGLEICH(ABRUNDEN(O5;-2);$A$4:$A$416;0)))/(ABRUNDEN(O5;-2)))*O5;INDEX(C4:C416;VERGLEICH(O5;$A$4:$A$416;0)))))

Wenn ich jetzt jedoch eine Auflage ab 200 suche, bei der die letzte stelle >= 5 ist(206, 1607, 8898 usw.) bekomme ich die Fehlermeldung #NV

Der Fehler scheint ja irgendwo ab dem ersten "Sonst" zu liegen, denn bis 200 kann ich problemlos alle Auflagen eingeben.

Wäre total nett, wenn sich jemand die Zeit nehmen würde da einmal drüber zu gucken, denn ich bin mit meinem Latein am Ende und google hilft mir bei so einem speziellen Problem leider auch nicht mehr weiter.

Vielen Dank im Voraus!

Bruno

 

Hola,

eine Beispieldatei wäre hier sinnvoll.

Gruß,
steve1da

 

Hola Steve,

Ich habe meine Tabelle mal etwas verschlankt und hier angehangen. Dadurch haben sich natürlich die Spalten etwas verschoben. Die Formel befindet sich in E5. Bei weiterem rumprobieren ist mir jedoch aufgefallen, dass das Problem doch woanders liegt als gedacht. Und zwar kriege ich immer nur Ergebnisse für die ersten fünf Zahlen eines Rundungsbereiches (xxx0-xxx4) bei den 10er Intervallen also nur die hälfte, bei den hunderter und tausender Intervallen jedoch auch nur z. Bsp. 8000, 8001,8002, 8003 und 8004. Ab 8005 bekomme Ich bis 8100 nur Fehlermeldungen.

Ich komme einfach nicht dahinter, wodran es liegt

Muchas gracias y saludos,

Bruno

 

Hola,

suchst du sowas?

Code:

=SVERWEIS(E3;A2:C386;3)

Übrigens ginge das auch mit deiner Formel in E4, wenn der Vergleichstyp nicht auf 0 sondern auf 1 steht.

Gruß,
steve1da

 

Ja genau. Nur das mir damit dann ja zum Beispiel immer der Preis für eine Auflage von 220 angezeigt wird, auch wenn ich 226 in E2 eingebe. Ich bräuchte allerdings den Stückpreis von 220 mal 226 für den Gesamtpreis von 226... Ich bräuchte eine Formel, mit der ich mir eben diese Zwischenschritte ausrechnen kann.

 

Hallo Bruno,

ich bin nicht der Formelkünstler und Steve ist da viel besser als ich,
aber wenn Du mit der Formel die nächst kleinere Auflage (mit Preis) bereits identifizieren kannst, dann teile doch einfach den Preis durch die nächst kleinere Auflage, und mulipliziere dann mit deiner Wunschauflage

Code:

=INDEX(C2:C380;VERGLEICH(E3;$A$2:$A$380;1))/INDEX(A2:A380;VERGLEICH(E3;$A$2:$A$380;1))*E3

Noch einfacher sollte es aber gehen, wenn man die Indexformel direkt auf den entsprechenden Stückpreis setzt (also Spalte B) und dann mit der Wunschauflage multipliziert

Code:

=INDEX(B2:B380;VERGLEICH(E3;$A$2:$A$380;1))*E3

Analog dazu

Code:

=SVERWEIS(E3;A2:C386;2)*E3

Oder verstehe ich da etwas falsch?

 

Hallo Achim,

klasse, so funktioniert das! Ich hatte ursprünglich mit einer Liste ohne Stückpreise gearbeitet und hab mich da wohl dann etwas verrant :) Vielen lieben Dank!!!!!