Office: (Office 2007) Probleme mit der RGP-Funktion

Hallo @ all,
dass man sich mit der RGP-Funktion aus einer gegebenen Menge von Zahlenpaaren z.B. die Werte für eine Trendlinie ausgeben lassen kann, ist ja ganz schön. Was aber mache ich, wenn in meiner Tabelle Zellen mit dem Wert "0" auftauchen und diese dann nicht mit in die Berechnung einfließen sollen? Hat jemand dazu eine nette Idee? Hat Zeit bis nächste Woche, denn am Sonntag arbeite ich denn dann doch nicht mehr. *wink.gif*
Gruß
Robert

:)

 

Moin, Robert,

direkt in der Datenmenge kann ich mir zur Zeit keine Lösung vorstellen, am Ende der Liste kann die Verwendung von dynamisch sich an die Menge der vorhandenen Daten anpassenden Namen helfen.

 

Hi jinx,
das Problem liegt auch darin, dass ich zum Teil aus einer Anzahl von Wertepaaren den größten Ausreißer herauslösche und somit dann irgendwo mittendrin eine Leerzeile habe. Grad überlege ich, ob man nicht einfach im Nachhinein die Leerzeilen automatisch löschen läßt, aber dann müßte man jedesmal die RGP-Zellenangaben neu eingeben. Ist auch nicht so schön. Ließe sich variabler Bereich definieren? Ich glaube nicht.
Oder weißt Du, ob es eine Möglichkeit gibt, aus einem eingelesenen Array mit Wertepaaren in VBA sich eine Trendlinie erstellen zu lassen?
Danke schon mal und viele Grüße
Robert

 

Hi,
nochmal eine Erläuterung bzw. ergänzende Frage zu oben aufgeführten Gedanken.
In der RGP-Formel gebe ich ja die Anfangs- und Endzelle an. Kann man da auch angeben, dass er den Inhalt einer Zelle, in die ich die Anfangszelle bzw. Endzelle schreibe, beachten soll?
Wenn z.B. mein Bereich für die RGP-Funktion von A5 bis A23 geht. Kann ich dann z.B. in die Zelle B1 den Anfang (A5) und in B2 das Ende (A23) schreiben und in der RGP-Formel den Inhalt der Zellen B1 und B2 als Bereich angeben?
Ich hoffe, ich hab mich so ausgedrückt, dass man verstehen kann, was ich meine.
Gruß
Robert

 

Hallo Leute,
nach einigem suchen habe ich irgendwo, wo, weiß ich nicht mehr, einen Beitrag gefunden, in dem erklärt wird, wie man die Funktionen der Trendlinien mittels VBA als String ausliest.
Geschrieben wurde es von Norbert Koehler und ich hoffe jetzt, dass ich damit keine Rechte verletze. Aber ich glaube, dieser Code ist auch aus irgendeinem Forum.
Das Bearbeiten der Strings sollte ja dann kaum noch Probleme machen.
Gruß
Robert

HTML:

Sub Get_TrendLabel()
Rem by Norbert Koehler 2000-04-02
' Procedure to copy the formulas of diagram-trendlines into a worksheet,
' considering all trendlines of all series in all diagrams of the current worksheet.
' For each diagram the user will be asked (via an inputbox) for the goal-cell,
' the results should be copied into.

'Title for Input- and Messageboxes
Const ConStrTitle As String = "Trend Label"
'Variables:
Dim intI As Integer
Dim intChart As Integer
Dim strChartName As String
Dim intK As Integer
Dim intSerie As Integer
Dim strSerieName As String
Dim intL As Integer
Dim intTrend As Integer
Dim strTrendName As String
Dim strTrendType As String
Dim varResult As Variant
Dim objResult As Object
Dim strTrend As String
Dim intPos As Integer
Dim strFunction As String
Dim strR2 As String

'Enumerate the amount of diagrams within the current worksheet.
intChart = ActiveSheet.ChartObjects.Count
If intChart = 0 Then 'Diagram does'nt exist.
MsgBox "Kein Diagramm vorhanden", vbOKOnly + vbInformation, ConStrTitle
Exit Sub
Else
For intI = 1 To intChart Step 1 'all diagrams
ActiveSheet.ChartObjects(intI).Activate
strChartName = ActiveChart.Name
'Enumerate the amount of series per diagram.
intSerie = ActiveChart.SeriesCollection.Count
'The following Inputbox-method of Type 8,
'needs a Range as return value.
'In case "Cancel" was selected a "type mismatch error, No.13" is returned,
'so we need to catch this with the Error-routine.
On Error GoTo Errorhandle
Set varResult = Application.InputBox("Bitte die Zielzelle auswählen." & vbCrLf & _
"Die daneben liegenden 3 Spalten werden genutzt." & vbCrLf & _
"Die Zeile(n) darunter ebenso.", ConStrTitle & " von: " & strChartName, Type:=8)
ActiveSheet.Cells(varResult.Row, varResult.Column).Select
Set objResult = Selection 'Define goal-cell.
On Error GoTo 0 'Turn off error trapping.
Application.ScreenUpdating = False
For intK = 1 To intSerie Step 1 'All series.
ActiveSheet.ChartObjects(intI).Activate
ActiveChart.SeriesCollection(intK).Select
strSerieName = Selection.Name
'Enumerate the amount of trendlines per serie.
intTrend = Selection.Trendlines.Count
For intL = 1 To intTrend Step 1 'All trendlines.
ActiveSheet.ChartObjects(intI).Activate
ActiveChart.SeriesCollection(intK).Trendlines(intL).Select
strTrendName = Selection.Name
strTrendType = Selection.Type
'Convert type-values to there corresponding Excel-constants.
Select Case strTrendType
Case "5"
strTrendType = "xlExponential"
Case "-4132"
strTrendType = "xlLinear"
Case "-4133"
strTrendType = "xlLogarithmic"
Case "6"
strTrendType = "xlMovingAvg"
Case "3"
strTrendType = "xlPolynomial"
Case "4"
strTrendType = "xlPower"
Case Else
strTrendType = "No XLTrendlineType"
End Select
With Selection
'"Moving Average" has no trend-formula by default.
'In case we are trying to get this value,
'an error No. 1004 is generated
'("Unable to get the Text property of the DataLabel class."),
'so we need to catch this with the Error-routine.
On Error GoTo Errorhandle
.DisplayEquation = True
.DisplayRSquared = True
strTrend = .DataLabel.Text
On Error GoTo 0 'Turn off error trapping.
'Find the linefeed character within the label.
intPos = InStr(1, strTrend, Chr(10))
'The function is in front of the linefeed character.
strFunction = Mid(strTrend, 1, intPos - 1)
'R2 is behind the linefeed character.
strR2 = Mid(strTrend, intPos + 1)
'Place results into the goal-cells.
objResult.Activate
ActiveCell.Value = strTrendType
ActiveCell.Offset(0, 1).Value = strFunction
ActiveCell.Offset(0, 2).Value = strR2
ActiveCell.Offset(0, 3).Value = strChartName & " " & _
strSerieName & " " & _
strTrendName
'Set same Column, next Row as goal-cell.
Set objResult = objResult.Offset(1, 0)
End With
Next intL
Next intK
Application.ScreenUpdating = True
'Release the Object.
Set objResult = Nothing
Next intI
End If
'Terminate before the Error-routine.
Exit Sub

Errorhandle:
'If "Cancel" was choosen a "Type Mismatch Error, No.13" occured.
If Err.Number = 13 Then
MsgBox "Abbruch gewählt.", vbOKOnly + vbInformation, ConStrTitle
Exit Sub 'Terminate routine.
'Unable to get the Text property of the DataLabel class.
ElseIf Err.Number = 1004 Then
strTrend = "NO FUNCTION" & Chr(10) & "R2 = 0"
Resume Next 'Continue with the code after the line caused this error.
Else 'for other errors switch on screen-updating.
Application.ScreenUpdating = True
Resume Next 'Continue with the code after the line caused this error.
End If
End Sub