Office: Probleme mit jetzt()

Hallo!

Habe ein Prob mit den Uhrzeiten.
Und zwar schreibe ich eine Zutrittsliste und mein Vorgesetzter möchte, das so bald ein Name eingetragen wird, die momentane Uhrzeit automatisch in einer Spalte erscheint. Mit der Funktion jetzt() bekomme ich zwar die Uhrzeit, aber so bald in einer weiteren Zeile man das Gleiche versucht, kommt die neue Uhrzeit auch in der Zeile davor.

Mit der Tastenkombination <STRG> + <:> bekommt man zwar das gewünschte Ergebnis, aber ich brauch es halt automatisch. Kennt da wer die Funktion zu?!

 

Hallo!

Das ist wohl am einfachsten mit VBA zu lösen.

Z.B so.

Dieser Code fügt in Spalte B ein Jetzt() ein sobald in A etwas eingetragen wird. Den Code in ein Tabellenblatt einfügen. Tabellenreiter rechtklick->Code anzeigen und da einfügen.

Code:

PPrivate Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Range
Dim bereich As Range
Set bereich = Range("a1:a100")
For Each i In bereich
If i <> "" And i.Offset(0, 1).Value = "" Then
i.Offset(0, 1).Value = Now
End If
Next i
End Sub

GRuß

 

Ich möchte kein jetzt() eingefügt haben, da sich die Zeit bei jeder Zeile dann wieder aktualisiert. Das ein jetzt() in der Spalte B erzeugt wird, schaff ich auch mit einer WENN - Funktion.

Ich möchte das die Zeit angezeigt wird, ohne das sie aktualisiert wird.

 

Hallo!

Der Code, den Gook Dir anbietet, tut genau das, was Du wolltest.
In Spalte B erscheint das aktuelle Datum mit Uhrzeit, sobald Du in Spalte A etwas einträgst. Diese Uhrzeit bleibt ein für allemal fest; es ist so, als ob Du sie mit Hand eingetippt hättest.

 

Leider funktioniert es nicht.

Habe Windows Vista mit Excel 2002

Muss ich da erst noch was aktivieren?

 

Nimm den Code in die Zwischenablage (außer dem ersten P, das ist natürlich ein Tippfehler).

Gehe zu Deiner Excel-Tabelle, wo die Uhrzeiten erscheinen sollen. Mache einen Rechtsklick auf den Tabellenreiter unten am Bildschirm. Wähle "Code anzeigen". Es erscheint eine weiße Fläche. Mache einen Rechtsklick auf diese weiße Fläche und wähle "Einfügen". Schließe das Fenster, damit Du wieder die Tabelle siehst.

Das Makro bewirkt folgendes:

Trage in eine Zelle der Spalte A irgend etwas ein; die Zelle rechts daneben muß leer sein. Dann erscheint in Spalte B das aktuelle Datum mit Uhrzeit und bleibt unverändert.

 

Hallo!

Vielleicht ist auch die Makro-Sicherheitsstufe auf "hoch". Dann werden Makros ohne Nachfrage deaktiviert.
Schau mal unter Menü Extras > Makros > Sicherheit und stelle dort die Sicherheit auf "mittel".

 

Es funktioniert jetzt, aber leider übergeht er die Formation.

Möchte gerne folgende Benutzerdeffienierte Formation: hh:mm

@gook:

Danke für den Code!

@ all other:

Thanx für die Hilfe

 

Hallo,

dann so.

Code:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Range
Dim bereich As Range
Set bereich = Range("a1:a100")
For Each i In bereich
If i <> "" And i.Offset(0, 1).Value = "" Then
i.Offset(0, 1).Value = Now
i.Offset(0, 1).NumberFormat = "hh:mm"
End If
Next i
End Sub

Gruß

 

Moin!

Auch auf die Gefahr hin, das ich nerve... Ich konkretisier das Ganze jetzt mal etwas ;)

Die Eingabe passiert von B4 - B56 und die Uhrzeit soll dann in E4 - E56 erscheinen.

Einen Teil kann ich mir selber zusammenreimen - die Eingabe, aber net wie ich es schaffe, das er es in E einträgt.

Code:

Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
Dim i As Range 
Dim bereich As Range 
Set bereich = Range("b4:b56") 
For Each i In bereich 
If i <> "" And i.Offset(0, 1).Value = "" Then 
i.Offset(0, 1).Value = Now 
i.Offset(0, 1).NumberFormat = "hh:mm" 
End If 
Next i 
End Sub

 

Hallo!

Probier's mal so:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("b4:b56")) Is Nothing Then
  With Target
    If .Count = 1 And .Offset(0, 3) = "" Then
      .Offset(0, 3) = Now
      .Offset(0, 3).NumberFormat = "hh:mm"
    End If
  End With
End If
End Sub

 

Vielen Dank!

Es funktioniert. Nun wird es so an meinen Vorgesetzten gegeben und dann werd ich es mit SQL umschreiben müssen, um es bedienerfreundlicher zu machen.

 

Darf ich mir diesen Satz groß ausgedruckt an die Wand hängen? ;-)

a) Excel-Tabelle nach SQL ?
c) SQL bedienerfreundlicher als Excel ???

Wenn ich das in meinem Club erzähle... ;-)

Gruß, Michael

 

Wenn man via SQL die Eingabe-Masken erstellt, ist es in so fern Bedienerfreundlicher. Ich hab`s an meinem Vater gesehen, der mit den Kapiteln usw in Excel nicht klar kam.

Allerdings habe ich jetzt wieder ein Prob mit dem Programm.

In dem Code, der hier erstellt wurde. wird das Format der Zeiteingabe ja geändert... Das gibt allerdings ein Problem mit dem Schutz, der auf dieser Spalte liegt. Kann man das irgendwie umgehen?!

 

Hallo!

Den Schutz musst du dann temporär aufheben:

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("b4:b56")) Is Nothing Then
Me.Unprotect Password:="Hallo"
With Target
If .Count = 1 And .Offset(0, 3) = "" Then
.Offset(0, 3) = Now
.Offset(0, 3).NumberFormat = "hh:mm"
End If
End With
Me.Protect Password:="Hallo"
End If
End Sub