Office: Prozedur ist zu groß

Hallo ich habe ein Problem und zwar werden sehr viele Kombinationsfelder beim Öffnen eines Excel Workbook gefüllt.
Diese führt jetzt zu einer zu großen Prozedur.
Hätte da jemand eine Lösung?

Gruß Ingo

 

Moin Ingo

habe mir eben mal Deinen Code angeschaut und ca. 15 Fragezeichen im Gesicht.

Ich sehe nur Mengen von Sheets gleichen Namens und andere böhmische Dörfer. Vielleicht beschreibst mal in einfachen Sätzen: wo Deine Daten herkommen und was mit ihnen geschehen soll. Dein Blätterwald ist mit großer Wahrscheinlich für die Verarbeitung unnötig. Eine übersichtliche Ausgabe ist dann der zweite Schritt.

Schöne Grüße

 

Hallo Ingo,

für die Zuweisung der Spaltenzahl (.ColumnCount) und 2 spaltiges Füllen kann man dies in einer kleinen Schleife erschlagen.
beispielhaft so:

Code:

    Dim i&
    With Worksheets("01 Woche")
        For i = 1 To 40
            .OLEObjects("ComboBox" & i).Object.ColumnCount = 2  ' Spaltenzahl 2 setzen
            .OLEObjects("ComboBox" & i).Object.List = Sheets("Einstellungen").Range("A2:B" & .Cells(Rows.Count, 1).End(xlUp).Row)   ' Beide Spalten füllen
        Next i
    End With

Den Rest kannst du dir nach diesem Prinzip dann selbst bauen.
Solltest du damit nicht zurecht kommen, lade eine brauchbare Demodatei anonymisiert mit dem bisher vorhandenen Code hoch.

Gruß Uwe

 

Code:

.Cells(Rows.Count, 1).End(xlUp).Row

Diese Konstruktion bezieht sich so natürlich auf Worksheets("01 Woche“).

 

@HSV,

stimmt, hatte da nicht aufgepasst.
richtig ist die Zeile so:

Code:

.OLEObjects("ComboBox" & i).Object.List = Sheets("Einstellungen").Range("A2:B" & Sheets("Einstellungen").Cells(Rows.Count, 1).End(xlUp).Row)

Gruß Uwe

 

ich habs mal zu Ende gebaut:

Code:

Private Sub Workbook_Open()
    Dim wks As Worksheet, i&, j&, arr()
    For Each wks In ThisWorkbook.Worksheets
        If InStr(1, wks.Name, "Woche", vbTextCompare) Then i = i + 1: ReDim Preserve arr(1 To i): arr(i) = wks.Name
    Next
    Set wks = ThisWorkbook.Sheets("Einstellungen")
    For i = 1 To UBound(arr)
        With Worksheets(arr(i))
            For j = 1 To 40
                With .OLEObjects("ComboBox" & j).Object
                    .ColumnCount = 2  ' Spaltenzahl 2 setzen
                    .List = wks.Range("A2:B" & wks.Cells(Rows.Count, 1).End(xlUp).Row).Value   ' Beide Spalten füllen
                End With
            Next j
        End With
    Next i
End Sub

Dieser Code arbeitet unter der Annahme, dass alle Tabellenblätter, welche im Namen "Woche" enthalten ist jeweils 40 ComboBoxen eingebaut sind. Die relevanten Blätter werden in ein Array eingelesen und in Schleife i abgeklappert. In Schleife j werden die Comboboxen befüllt.

GHruß

 

Hallo an dieser Stelle einen großen Dank an alle die mir bei dem Problem geholfen haben.
Besonders an OilMax der Code läuft hervorragend, einfach genommen reinkopiert und funktioniert, top.
Nochmal eine Dank an alle.
Gruß Ingo