Office: Range mittels Maus auswählen

JeanCantos · 3. Februar 2007

Hallo zusammen,

ich übe mich gerade in VBA-Programmierung unter Excel und scheitere momentan an
folgendem Problem:

Der User wählt über die GetFilename-Methode Dateien aus, deren Dateinamen
in bestimmte Zellen geschrieben werden sollen.

Code:

Option Explicit

Sub FileDialog()
Dim strErrProzedure As String
Dim varDateinamen As Variant
Dim i As Integer

On Error GoTo Err_FileDialog
'Auswählen der Dateien
varDateinamen = Application.GetOpenFilename("Alle Dateien (*.*), *.*", MultiSelect:=True)

'Dateinamen extrahieren
For i = 1 To UBound(varDateinamen)
varDateinamen(i) = Dir(varDateinamen(i))
Next i

'...
'...

Exit_FileDialog:
On Error GoTo 0
Exit Sub

Err_FileDialog:
strErrProzedure = "FileDialog()"
Call Fehlermeldung(strErrProzedure)
Resume Exit_FileDialog
End Sub

Private Sub Fehlermeldung(strErrProzedure As String)
Dim strMeldung As String
Dim strButtons As String

strMeldung = "In der Prozedure" & vbCr & vbCr & strErrProzedure & vbCr & vbCr & _
"ist folgender Fehler aufgetreten: " & vbCr & vbCr & Err.Number & " " & Err.Description
strButtons = vbCritical

MsgBox strMeldung, strButtons
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Nun möchte ich, dass der User eine Zelle auswählt, wo die Dateinamen dann untereinander eingetragen werden.
D.h. der User wählt mit der Maus die Zelle "B5" aus, und der erste Dateiname wird in B5 geschrieben, der nächste in B6 usw.

Statt dem User eine InputBox zur Verfügung zu stellen, in der die Zelle manuell eintragen werden kann, möchte ich, dass die Zelle mit der Maus auswählt wird. Wie geht das?

Gruß,

Jean

:)

User · 4. Februar 2007

Hallo Jean,

probier mal so:

Code:

Option Explicit

Sub test()
Dim rngZelle As Range
Set rngZelle = Application.InputBox("Wähle bitte die Startzelle.", "Zelle wählen", ActiveCell.Address, Type:=8)
MsgBox rngZelle(1).Address
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

JeanCantos · 4. Februar 2007

Hallo fridgenep,

vielen Dank für den Code. Ist genau das, was ich suchte.
Gruß,

Jean

jinx · 11. Februar 2007

Moin, fridgenep,

drück bitte mal Abbrechen in der Application.Inputbox - Excel97 zumindest quittiert dies mit einem durchaus vermeidbaren Laufzeitfehler 424...

User · 11. Februar 2007

Hallo,

und wen interessiert das hier? Das war ein Beispiel und ein Denkanstoß!

Du scheinst echt Langeweile zu haben. *stupid

jinx · 11. Februar 2007

Moin, fridgenep,

unvollständige und mögiche Fehler verursachende Beispiele sollten jeden Leser interessieren...

struschie · 11. Februar 2007

Servus,

mich interessiert diese Input-Box sehr - wie ist denn der LFZ-Fehler zu vermeiden? Welche Alternative habe ich den Fehler abzufangen?

Grüße
struschie

jinx · 12. Februar 2007

Moin, struschie,

z.B. so:
Code:

Option Explicit

Sub MarkierungAppInpBox()
Dim rngZelle As Range
On Error Resume Next
Set rngZelle = _
Application.InputBox(prompt:="Wähle bitte die Startzelle:", _
Title:="Zelle wählen", _
Default:=ActiveCell.Address, _
Type:=8)
If rngZelle Is Nothing Then
MsgBox "keine Auswahl oder Abbruch", vbInformation
Exit Sub
Else
MsgBox rngZelle(1).Address
End If
On Error GoTo 0
' weitere Anweisungen
Set rngZelle = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

struschie · 12. Februar 2007

Danke jinx,

macht doch einen guten Eindruck =)

Grüße
struschie

Office: Range mittels Maus auswählen

Range mittels Maus auswählen

Range mittels Maus auswählen

Range mittels Maus auswählen

Range mittels Maus auswählen

Range mittels Maus auswählen - Similar Threads - Range mittels Maus

Excel Range als Bild in Word einfügen

SVERWEIS mit Range von bis funktioniert nicht?

Macro Fehler Subscript out of Range

Laufzeitfehler 1004 "Die Methode 'Range' für das Objekt '_Global' ist fehlgeschlagen".

2x Worksheet_Change(ByVal Target As Range)

Turnierdatenbank Punkteausweisung anhand Rang

Rang.gleich aber mit untersten Rang bei gleichen Werten