Office: Raumplanung in Excel VBA

komakurt · 26. November 2010

Ok, danke!

komakurt · 28. November 2010

Guten morgen,

kann man noch einstellen, dass die Kommentare automatisch ausgeblendet werden?
Wenn ich einen Kommentar eingebe, bleib der immer offen und ich muss erst mit rechter Maustaste usw. einstellen, dass der ausgeblendet werden soll.

Danke schonmal *Smilie

jinx · 28. November 2010

Moin, komakurt,

es gibt da ein zeitweises sehr nützliches Werkzeug in Excel: den Makro-Rekorder. Dieser kann einem manchmal die Antwort auf eine Frage durch das Aufzeichnen der gewünschten Aktion bringen... *wink.gif*

Am Ende des Schreibvorganges die folgende Codezeile einfügen:

Code:

Application.DisplayCommentIndicator = xlNoIndicator
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

komakurt · 28. November 2010

Hallo, danke für die schnelle Antwort.

Ich weiß nicht, ob ich das richtig eingefügt habe, aber jetzt ist der Kommentar irgendwie ganz verschwunden und ich möchte ja, dass der eingeblendet wird, wenn man mit der Maus über die Zelle geht.

ich habe das mal mit dem Aufzeichnen versucht und habe jetzt folgenden Code:

Code:

Sub Makro1()

Range("B4:U26").Select
ActiveCell.Comment.Visible = False
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Aber ich habe keine Ahnung, wo ich das jetzt einfügen soll

jinx · 28. November 2010

Moin, komakurt,

in meiem letzten Posting stand am Ende die Anweisung, die nur die Anzeige des roten Dreiecks als Kennzeichnung für den Kommentar hinterlässt (und diesen Kommentar anzeigt, wenn man mit der Maus über die Zelle wandert):

Code:

Private Sub cmdOkay_Click()

With Range(Cells(4 + cmbStart.ListIndex, (2 + cmbDatum.ListIndex * 4) + cmbRaum.ListIndex), _
Cells(4 + cmbEnde.ListIndex, (2 + cmbDatum.ListIndex * 4) + cmbRaum.ListIndex))
.Merge
.Value = txtName.Text
If Len(txtKommentar) > 0 Then
With .Cells(1)
.AddComment
.Comment.Visible = True
.Comment.Text Text:=txtKommentar.Text
End With
End If
.BorderAround xlContinuous, xlThick, xlColorIndexAutomatic, vbBlack
End With
Application.DisplayCommentIndicator = xlNoIndicator
cmbDatum.ListIndex = -1
cmbRaum.ListIndex = -1
cmbStart.ListIndex = -1
cmbEnde.ListIndex = -1
txtName.Value = vbNullString
txtKommentar.Value = vbNullString

cmdOkay.Enabled = False

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

komakurt · 28. November 2010

Hallo,

ich habe das jetzt so eingefügt, nur leieder funktioniert das nicht.
Wenn ich jetzt unter "Extras"-"Optionen" auf den Reiter "Ansicht" gehe, steht da unter "Kommentare", dass Kommentare ausgestellt sind.
Stelle ich das jetzt wieder auf "Nur Indikatoren" um, funktioniert es mit dem Ein- und Ausblenden.
Nach der nächsten Eingabe über die UserForm sind die Kommentare allerdings wieder ausgestellt.

Ich habe aber noch ein viel größeres Problem.
War grade in einer Besprechung und mir wurde mitgeteilt, dass noch ein weiterer Raum (Raum 111) dazukommt.
Ich wäre beinahe durchgedreht...

jinx · 28. November 2010

Moin, komakurt,

wegen der Kommentare: ich kann scheinbar kein englisch mehr, denn xlNoIndicator heißt ja keine Anzeige. Ändere bitte diese Konstante um in xlCommentIndicatorOnly, dann sollte die Anzeige der Kommentare klappen.

Ich wäre beinahe durchgedreht...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wo Du doch bisher alles so toll programmiert hast, dürfte es sich bei dieser kleinen Anpassung doch um kein Problem für Dich handeln... *holy *wink.gif*

Da muss dann aber noch ein weiterer Freiheitsgrad eingebaut werden, denn es ist ja auch möglich, dass eine unterschiedliche Anzahl an Räumen an einzelnen Tagen zur Verfügung steht. Daraus resultiert dann auch eine Veränderung in der Aktivierung bzw, Auswertung der Aktivierung der einzelnen Steuerlemente. Und das werde ich frühestens heute Abend in Angriff nehmen.

komakurt · 28. November 2010

So funktioniert es, danke! *Smilie

Diese fünf Räume stehen uns dann immer zur Verfügung und es wird in absehbarer Zeit auch kein weiterer Raum hinzugefügt oder wieder abgegeben.
Also muss dieses Problem immerhin nicht beachtet werden. *wink.gif*
Es muss jetzt "einfach" nur ein weiterer Raum nach bisherigem Prinzip hinzugefügt werden.

jinx · 29. November 2010

Moin, komakurt,

merkwürdig, dass Du bis jetzt noch nicht ein einziges Mal nachgefragt hat, was denn wo im Code angesprochen wird bzw. was bestimmte Befehle machen...

Festlegung der Räume in einer modulweiten Konstanten oben im Prozedurkopf:
Code:

Option Explicit
Const mclngRÄUME As Long = 5

Private Sub cmbDatum_Change()

If cmbDatum.ListIndex = -1 Then
cmbRaum.Enabled = False
cmbStart.Enabled = False
cmbEnde.Enabled = False
Else
cmbRaum.Enabled = True
cmbStart.Enabled = False
cmbEnde.Enabled = False
End If

End Sub

Private Sub cmbEnde_Change()

Dim rngTime As Range

If cmbEnde.ListIndex > -1 Then
If cmbEnde.ListIndex < cmbStart.ListIndex Then
MsgBox "Sie haben eine Endzeit eingegeben, die kleiner oder gleich der Startzeit ist." & vbCrLf & _
"Bitte korrigieren Sie diese Eingabe.", vbOKOnly, "Negative oder keine Besprechungszeit gewählt"
cmbEnde.ListIndex = -1
Exit Sub
End If
Set rngTime = Range(Cells(4 + cmbStart.ListIndex, (2 + cmbDatum.ListIndex * mclngRÄUME) + cmbRaum.ListIndex), _
Cells(4 + cmbEnde.ListIndex, (2 + cmbDatum.ListIndex * mclngRÄUME) + cmbRaum.ListIndex))
If WorksheetFunction.CountBlank(rngTime) < rngTime.Cells.Count And cmbStart.ListIndex > -1 Then
MsgBox "Es gibt bereits einen Eintrag in dem von Ihnen gewünschten Zeitfenster." & vbCrLf & _
"Wählen Sie das Zeitfenster erneut aus."
With cmbStart
.ListIndex = -1
.SetFocus
End With
With cmbEnde
.ListIndex = -1
.Enabled = False
End With
End If
Set rngTime = Nothing
End If

End Sub

Private Sub cmbRaum_Change()

If cmbRaum.ListIndex = -1 Then
cmbStart.Enabled = False
cmbEnde.Enabled = False
Else
cmbStart.Enabled = True
cmbEnde.Enabled = False
End If

End Sub

Private Sub cmbStart_Change()

Dim rngTime As Range

If cmbStart.ListIndex = -1 Then
With cmbEnde
.ListIndex = -1
.Enabled = False
End With
Exit Sub
Else
cmbEnde.Enabled = True
End If

If cmbEnde.ListIndex > -1 Then
Set rngTime = Range(Cells(4 + cmbStart.ListIndex, (2 + cmbDatum.ListIndex * mclngRÄUME) + cmbRaum.ListIndex), _
Cells(4 + cmbEnde.ListIndex, (2 + cmbDatum.ListIndex * mclngRÄUME) + cmbRaum.ListIndex))
If WorksheetFunction.CountBlank(rngTime) < rngTime.Cells.Count And cmbStart.ListIndex > -1 Then
MsgBox "Es gibt bereits einen Eintrag in dem von Ihnen gewünschten Zeitfenster." & vbCrLf & _
"Wählen Sie das Zeitfenster erneut aus."
With cmbStart
.ListIndex = -1
.SetFocus
End With
With cmbEnde
.ListIndex = -1
.Enabled = False
End With
End If
Set rngTime = Nothing
End If

End Sub

Private Sub cmdAbbrechen_Click()

Unload Me

End Sub

Private Sub cmdOkay_Click()

With Range(Cells(4 + cmbStart.ListIndex, (2 + cmbDatum.ListIndex * mclngRÄUME) + cmbRaum.ListIndex), _
Cells(4 + cmbEnde.ListIndex, (2 + cmbDatum.ListIndex * mclngRÄUME) + cmbRaum.ListIndex))
.Merge
.Value = txtName.Text
If Len(txtKommentar) > 0 Then
With .Cells(1)
.AddComment
.Comment.Visible = True
.Comment.Text Text:=txtKommentar.Text
End With
End If
.BorderAround xlContinuous, xlThick, xlColorIndexAutomatic, vbBlack
End With
Application.DisplayCommentIndicator = xlCommentIndicatorOnly
cmbDatum.ListIndex = -1
cmbRaum.ListIndex = -1
cmbStart.ListIndex = -1
cmbEnde.ListIndex = -1
txtName.Value = vbNullString
txtKommentar.Value = vbNullString

cmdOkay.Enabled = False

End Sub

Private Sub txtName_Exit(ByVal Cancel As MSForms.ReturnBoolean)

If cmbStart.ListIndex = -1 Then Exit Sub

If Len(txtName.Text) = 0 Then
MsgBox "Es ist zwingend notwendig, dass Sie einen Namen für die Buchung eintragen.", vbExclamation, "Kein Name für die Buchung"
cmdOkay.Enabled = False
txtName.SetFocus
Exit Sub
End If

cmdOkay.Enabled = True

End Sub

Private Sub UserForm_Activate()

Dim lngCounter As Long

Me.Caption = ActiveSheet.Name

With cmbDatum
.Clear
For lngCounter = 2 To (2 + 4 * mclngRÄUME) Step mclngRÄUME
.AddItem CStr(Format(Cells(2, lngCounter).Value, "DDDD, DD.MM.YYYY"))
Next lngCounter
End With

With cmbRaum
For lngCounter = 2 To mclngRÄUME + 1
.AddItem Cells(3, lngCounter).Value
Next lngCounter
.Enabled = False
End With

With cmbStart
.Clear
For lngCounter = 14 To 35
.AddItem Format(TimeSerial(0, lngCounter * 30, 0), "hh:mm")
Next lngCounter
.Enabled = False
End With

With cmbEnde
.Clear
For lngCounter = 15 To 36
.AddItem Format(TimeSerial(0, lngCounter * 30, 0), "hh:mm")
Next lngCounter
.Enabled = False
End With

cmdOkay.Enabled = False

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

komakurt · 30. November 2010

Guten morgen,

vielen Dank für deine Mühe! So ist es perfekt.
Ich habe versucht selbst zu verstehen, was wo passiert.
Die einzelnen Prozeduren helfen einem da ja schon bei.

Ich versuche mich jetzt selbst ein bisschen an VBA, möchte das auch endlich mal lernen, dann brauche ich hier nicht mehr andere Leute zu nerven. *wink.gif*

Vielen Dank nochmal!

Office: Raumplanung in Excel VBA

Raumplanung in Excel VBA

Raumplanung in Excel VBA

Raumplanung in Excel VBA

Raumplanung in Excel VBA

Raumplanung in Excel VBA - Similar Threads - Raumplanung Excel VBA

Raumplanung mit Blockunterricht

Pivotdatenzuordnen #BEZUG!

Raumplan mit Excel programmieren

Besprechung löschen im Raumkalender

Termin löschen aus Raumkalender

Raumplanung

Belegungsplan für Veranstaltungen