Office: Rechnung mit Datum

Hallo allerseits!

Ich stehe vor folgendem Problem in Excel 2003:

Ich habe ein Jahr (nicht unbedingt ein Kalenderjahr, allerdings immer vom ersten des Monats beginnend), dass ich in gleiche Teile aufteilen will / muss. Die Einteilung selber ist kein Problem.

Und jetzt die Problematik: Ich habe nun einen Stichtag (z.B. den 1.6.2009) und will mir ausrechnen, wann das nächste Fälligkeitsdatum ist, also wann wieder ein Teil des Jahres (Monat, viertel Jahr, halbes Jahr oder ganzes Jahr) um ist.

Als Beispiel:

Eine Zeitreihe startet mit 1.4.2007 (wobei das Jahr relativ egal ist), und zwar mit einer vierteljählrichen Betrachtung. Somit sind die "ausgezeichneten" Tage jeweils der 1.4., der 1.7., der 1.10. und der 1.1. jedes Jahr. Als Betrachtungsstichtag nehmen wir nun z.B. 1.5.2009. Von diesem Tag weg will ich mir ausrechnen, wann der nächste "ausgezeichnete" Tag ist. In diesem Fall wäre das also der 1.7.

Gleichzeitig muss diese Berechnung jedoch auch mit den anderen Aufteilungen eines Jahres (monatlich, halbjährlich, jährlich) stimmen. Es muss immer der zukünftige, nächste "ausgezeichnete" Tag herauskommen, wobei falls der Stichtag selbst ein "ausgezeichneter" Tag ist, natürlich dieser übernommen werden soll.

Kann mir da jemand helfen? Ist das überhaupt verständlich, was ich hier schreibe?

Wie viele Intervalle es pro Jahr gibt steht z.B. in Spalte A und zwar entweder als Eintrag 1 (jährlich), 2 (halbjährlich), 4 (vierteljährlich) od. 12 (monatlich). Der "Beginn" der Zeitreihe steht z.B. in Spalte B und der Stichtag von dem aus ich rechne in Spalte C.

Danke!

 

Hallo!

Falls Du immer den nächsten 1.1. (1.4. ... 1.7. ... 1.10.) anpeilen möchtest, wäre dieses vielleicht eine Möglichkeit:

	A	B
1	Stichtag	Nächster ausgezeichneter Tag
2	12.05.2009	01.07.2009
3	01.07.2009	01.07.2009

Zelle	Formel
B2	=DATUM(JAHR(A2);3*GANZZAHL((MONAT(A2)+2-(TAG(A2)=1))/3)+1;1)
B3	=DATUM(JAHR(A3);3*GANZZAHL((MONAT(A3)+2-(TAG(A3)=1))/3)+1;1)

Du brauchst nur eine Zelle mit dem Stichtag und eine weitere Zelle mit der Formel.

 

Danke für deine rasche Antwort. Leider ist das Problem etwas komplexer. Ich habe folgende Spalten:

A: Beginn der Zeitreihe (ist immer der erste eines Monats)
B: Intervalle pro Jahr (entweder 12 = Monatsintervall, 4 = vierteljährliches Intervall, 2 = halbjährliches Intervall, 1 = jährliches Intervall)
C: aktueller Stichtag (fixer Tag, z.B. der 1.6.2009; ist auch immer der erste eines Monats)

Jetzt habe ich halt das Problem, dass nicht immer der z.B. der 1.1. ein "ausgezeichneter" Tag ist, weil wenn die Zeitreihe am 1.2.2007 gestartet ist und ich ein halbjährliches Intervall (B=2) habe, dann sind nur der 1.2. und der 1.8. jedes Jahres "ausgezeichnete" Tage. Per Stichtag 1.6.2009 sollte mir demnach der 1.8.2009 als nächster Termin ausgegeben werden.

Vielen Dank auf jeden Fall für jede Hilfe!

LG,
der salzige hund

 

Hallo!

Tut mir leid, da weiß ich dann auch nicht mehr weiter.

 

Hallo!

Hier ein Versuch, der aber noch ausgiebig getestet werden sollte...

	A	B	C	D
1	Beginn	Intervalle	aktuell	nächster
2	01.02.2007	2	01.06.2009	01.08.2009

Zelle	Formel
D2	{=MIN(WENN(DATUM(JAHR(A2);MONAT(A2)+12/B2*ZEILE($1:$999);1)>=C2;DATUM(JAHR(A2);MONAT(A2)+12/B2*ZEILE($1:$999);1)))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]


edit: Vielleicht funktioniert diese (kürzere und schnellere) Variante auch:

=DATUM(JAHR(A2);MONAT(A2)+AUFRUNDEN(DATEDIF(A2;C2;"m")/12*B2;)*12/B2;1)

 

Super, die schnelle Variante funktioniert einwandfrei!

Vielen, vielen Dank! Bist ein Schatzi!

LG,
saltydog