Office: Rechnungskopie ohne Makros und Buttons in eine andere Datei

Guten Morgen,
habe ein Problem das ich nicht gelöst bekomme.
Habe ein Makro das eine Kopie des Blattes in einen anderen Ordner speichert, nur leider fragt mich Excel bei jedem speichern ob ich ohne Makros speichern will. Das bestätige ich mit "ja". Doch wenn ich die gespeicherte Datei dann öffne, sind auch noch die Buttons für die Module in der Kopie vorhanden, aber die Makros sind weg, was auch so sein soll.
Es soll lediglich nicht immer die Frage kommen!
Ich füge mal den Code ein.

Code:

  
    '########################################################
    'Speichern einer Kopie der aktuell bearbeiteten Rechnung.
    'Gespeichert wird nach Rechnungsnummer
    '########################################################
    
    Dim Datei As String
Const Pfad As String = "C:\rechnungen\"
Datei = Range("C23") & ".xlsx"
ThisWorkbook.Worksheets("Rechnung").Copy
ActiveWorkbook.SaveCopyAs Pfad & Datei
ActiveWorkbook.Close

Kann mir jemand bei meinem Problem helfen ?
Danke

 

Hallo hasegoe,

mit "DisplayAlerts" kann man die Systhemmeldungen Ein- und Ausschalten.
Aber nie vergessen sie auch wieder an zu schalten!

Bei Deinen Buttons handelt es sich um AktiveX-Steuerelemente?
Dann kann man sie über die OLEObjects "erwischen" und löschen.

Der Code müsste in etwa so aussehen (denke ich ich).

Bei dieser Zeile:

Code:

For Each ObjOLE In Datei.Worksheets("Rechnung").OLEObjects

bin ich mir nicht ganz sicher ob das Ansprechen der datei so funktioniert oder etwas anders lauten muss (ungetestet).

Code:

Dim Datei As String
dim ObjOLE As OLEObject

Application.DisplayAlerts = False
Const Pfad As String = "C:\rechnungen\"
Datei = Range("C23") & ".xlsx"
ThisWorkbook.Worksheets("Rechnung").Copy
ActiveWorkbook.SaveCopyAs Pfad & Datei
	 For Each ObjOLE In Datei.Worksheets("Rechnung").OLEObjects
		ObjOLE.Delete
	Next ObjOLE
Application.DisplayAlerts = True
ActiveWorkbook.Close

Ich hoffe ich ein wenig geholfen zu haben.

 

Hallo hasegoe,

heute morgen der Code war "aus dem Bauch heraus" und ungetestet.
Diesen hier habe ich jetzt getestet und bei mir funktioniert er:

Code:

Option Explicit

Dim Pfad As String
Dim Datei As String
Dim ObjOLE As OLEObject

Private Sub CommandButton1_Click()
    
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    
    Pfad = "C:\rechnungen\"
    Datei = Range("C23") & ".xlsx"

    ThisWorkbook.Worksheets("Rechnung").Copy
    ActiveWorkbook.SaveCopyAs Filename:=Pfad & Datei
    
    Workbooks.Open Pfad & Datei
    
    For Each ObjOLE In Workbooks(Datei).Worksheets("Rechnung").OLEObjects
        ObjOLE.Delete
    Next ObjOLE
    
    Workbooks(Datei).Save
    Workbooks(Datei).Close
    
    ActiveWorkbook.Close
    Application.DisplayAlerts = True
    
    Application.ScreenUpdating = True

End Sub

Ich hoffe ich ein wenig geholfen zu haben.

 

Hallo Fette Elfe.... was für´n Name

Vielen Dank für deinen Code....
soweit funktioniert er auch, habe aber 2 Probleme.
1. ich habe einen Blattschutz (ohne Passwort) auf der Datei. Daran stösst sich Deine Formel. Wenn ich den Blattschutz deaktivierte funktioniert diese soweit. Gern würde ich aber auch ein Blattschutz mit PW verwenden, wobei ich hier an meine Grenzen stoße.

und
2. Ich habe nicht nur ActiveX sondern auch FormularSteuerelemente enthalten und die sollten auch verschwinden.

Vielleicht hast Du da noch eine lösung für mich.
Vielen Dank

 

Hallo hasegoe,

zu 1).

Das wäre dann:

Code:

ws.Protect Password:="Kennwort"
ws.Unprotect Password:="Kennwort"

zu 2).

Das wäre dann:

Code:

For i = 1 To ws.Shapes.Count
        ws.Shapes(ws.Shapes.Count).Delete
Next i

Komplett siehts dann so aus (getestet):

Code:

Option Explicit

Dim Pfad As String
Dim Datei As String
Dim ws As Worksheet
Dim ObjOLE As OLEObject
Dim i As Integer

Private Sub CommandButton1_Click()
    
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    
    Pfad = "C:\rechnungen\"
    Datei = Range("C23") & ".xlsx"
    
    ThisWorkbook.Worksheets("Rechnung").Copy
    ActiveWorkbook.SaveCopyAs Filename:=Pfad & Datei
    
    Workbooks.Open Pfad & Datei
    Set ws = Workbooks(Datei).Worksheets("Rechnung")
    
    ws.Unprotect Password:="Kennwort"
    
    For Each ObjOLE In ws.OLEObjects
        ObjOLE.Delete
    Next ObjOLE
    
    For i = 1 To ws.Shapes.Count
        ws.Shapes(ws.Shapes.Count).Delete
    Next i
    
    ws.Protect Password:="Kennwort"
    Workbooks(Datei).Save
    Workbooks(Datei).Close
    
    ActiveWorkbook.Close
    Application.DisplayAlerts = True
    
    Application.ScreenUpdating = True
    
End Sub

Warum benutzt Du ActiveX- und Formularsteuerelemente gleichzeitig?
Beide sind so unterschiedlich dass mir persönlich das viel zu aufwendig wäre...


"Kennwort" musst Du natürlich in zwei Zeilen gegen Dein Kennwort austauschen. (die Anführungszeichen müssen aber bleiben)

Falls noch etwas unklar sein sollte: nachfragen.


Ich hoffe geholfen zu haben.