Office: (Office 2010) s-verweis/ index/ vergleich

Hallo zusammen,
ich möchte den zum Schadenszeitpunkt/ Reparaturtag aktuellen Vertrag für eine Maschine wiedergeben.
Eine Maschine kann mehrere Verträge haben die sich durch unterschiedliche Start und Ende Datum unterscheiden.
Kann mir vielleicht jemand helfen?
Viele Grüße Jochen

 

Hallo,

mit Gewalt geht es so:
=INDEX(Matrix!$C$3:$C$10;SUMMENPRODUKT((Matrix!$D$3:$D$10<=C3)*(Matrix!$E$3:$E$10>=C3)*(Matrix!$B$3:$B$10=B3)*(ZEILE(Matrix!$B$3:$B$10)))-2)

 

Krass!!!
Vielen vielen Dank! Darauf wäre ich nie gekommen!!!
Sie haben mir super geholfen!!!

 

hallo, ich würde so tun..:

Arbeitsblatt mit dem Namen 'Tabelle2'
	B	C	D	E	F	G
2	Auto	Reparaturtag	welcher Vertrag wäre gültig??
3	Bagger 1	01.02.2009	Vertrag 1	< hier sollte Vertrag 1 stehen
4	Bagger 1	02.02.2010	Vertrag 5
5	Bagger 1	03.02.2011	Vertrag 6
6	Bagger 2	04.02.2009	Vertrag 2
7	Bagger 3	05.01.2009	Vertrag 3
8	Bagger 4	06.01.2009	Vertrag 4	< hier sollte Vertrag 4 stehen
9	Bagger 4	07.01.2009	Vertrag 4	< hier sollte Vertrag 4 stehen
10	Bagger 4	08.01.2009	Vertrag 4	< hier sollte Vertrag 4 stehen
11

Zelle	Formel
D3	=WENN(SUMMENPRODUKT((Matrix!$D$3:$D$10<=C3)*(Matrix!$E$3:$E$10>=C3)*(Matrix!$B$3:$B$10=B3))>0;INDEX(Matrix!$C$3:$C$10;SUMMENPRODUKT((Matrix!$D$3:$D$10<=C3)*(Matrix!$E$3:$E$10>=C3)*(Matrix!$B$3:$B$10=B3)*ZEILE($A$1:$A$8)));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

 

hallo René, habe deine antwort zu spät gesehen... ... ich würde aber noch eine fehlermeldung umzu zaubern..:

Arbeitsblatt mit dem Namen 'Tabelle2'
	B	C	D	E	F
2	Auto	Reparaturtag	welcher Vertrag wäre gültig??
3	Bagger 1	01.02.2009	Vertrag 1	< hier sollte Vertrag 1 stehen	Vertrag 1
4	Bagger 1	18.05.2016			#WERT!

Zelle	Formel
D4	=WENN(SUMMENPRODUKT((Matrix!$D$3:$D$10<=C4)*(Matrix!$E$3:$E$10>=C4)*(Matrix!$B$3:$B$10=B4))>0;INDEX(Matrix!$C$3:$C$10;SUMMENPRODUKT((Matrix!$D$3:$D$10<=C4)*(Matrix!$E$3:$E$10>=C4)*(Matrix!$B$3:$B$10=B4)*ZEILE($A$1:$A$8)));"")
F4	=INDEX(Matrix!$C$3:$C$10;SUMMENPRODUKT((Matrix!$D$3:$D$10<=C4)*(Matrix!$E$3:$E$10>=C4)*(Matrix!$B$3:$B$10=B4)*(ZEILE(Matrix!$B$3:$B$10)))-2)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

 

Hallo Jörg,

stimmt! Dies hatte ich ignoriert, da es ja keine Fehlermeldung gab! ;-)