Office: Schaltfläche mit Zellbezug / Makro mit abhängigkeitet der Position einer Schaltfläche

Ich habe eine Exceltabelle mit mehreren Blättern zur Inventarübersicht/Verwaltung.
Ab Zeile 4 steht pro Zeile ein Inventarobjekt. Zu jedem Objekt stehen in den Zellen der entsprechenden Zeile verschiedene Infos.
Anhand dieser Infos möchte ich die Tabelle sortieren. Hierzu habe ich in jeder Spalte in Zeile 3 eine Schaltfläche eingefügt, welche von Zellposition und Größe abhängig ist und mit denen ich die Tabelle nach den Infos der entsprechenden Spalte aufsteigend sortieren kann.
Zum sortieren nach den Werten von Spalte A sieht die Makro (die ich dann der Schaltfläche im Feld A3 zugewiesen habe) dann so aus:

Sub A()
'
' A Makro
'

'
ActiveSheet.Sort.SortFields.Clear
ActiveSheet.Sort.SortFields.Add Key:=Range("A4:A1000" _
), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
With ActiveSheet.Sort
.SetRange Range("A3:Z1000")
.Header = xlYes
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
End Sub

Prinzipiell funktioniert das ganz gut so. Allerdings würde ich gerne noch ein paar Dinge perfektionieren.
In erster Linie geht es mir darum dass das Makro den Spaltenbezug von der Schaltfläche bezieht. Somit bräuchte ich zum einen nur ein Makro, anstatt eines pro Spalte und zum anderen (was wichtiger ist) kann ich nach belieben Spalten vertauschen, kopieren, löschen ohne dass es Probleme gibt. Wenn ich derzeit z.b. Spalte C lösche, so rutscht ja der inhalt von Spalte D in spalte C. Die Schaltfläche hat jedoch immer noch das Makro welches nach den Werten aus der JETZTIGEN spalte D sortiert.
Wie kann ich das lösen?

 

Hi Bobby,

versuche es mal damit (dieses Makro allen Schaltflächen zuweisen):

Code:

Sub Sortieren()
   Dim intSpalte As Integer
   intSpalte = ActiveSheet.Shapes(ActiveSheet.Application.Caller).TopLeftCell.Column
   ActiveSheet.Sort.SortFields.Clear
   ActiveSheet.Sort.SortFields.Add Key:=Range(Cells(4, intSpalte), Cells(1000, intSpalte)), SortOn:=xlSortOnValues, _
      Order:=xlAscending, DataOption:=xlSortNormal
   With ActiveSheet.Sort
      .SetRange Range("A3:Z1000")
      .Header = xlYes
      .MatchCase = False
      .Orientation = xlTopToBottom
      .SortMethod = xlPinYin
      .Apply
   End With
End Sub

Beachte bitte, dass die linke obere Zelle der Schaltfläche sich tatsächlich in der Spalte befindet, in welcher sortiert werden soll.

Bis später,
Karin

 

Vielen Dank!
Funktioniert perfekt!