Office: Schleife mit TextBoxen?? VBA

Hallo,
ich hab mal eine Frage:
Ich habe eine UserForm in der ich oben ein "Abfrage Datum" eingebe. Je nachdem ob ich dort 1,2 oder 3 Abfragedaten eingebe soll das Makro eine schleife durchlaufen, damit auch bei den Abfragedaten 2 und 3 Ergebnisse angezeigt werden.


Am besten ihr guckt euch mal die Datei an... dann versteht ihr schon was ich meine.
Als erstes würde ich sagen If in Textbox 3&4 etwas steht dann beginne mit der Schleife.... aber wie man dann der Schleife sagt das die Ergebnisse in die anderen Textboxen müssen ist mir ein rätsel...

Danke schon mal...

 

Hi Heinz,

im UserForm für den CommandButton diesen Code:

Code:

Private Sub CommandButton1_Click()
    If TextBox1 <> "" And TextBox2 <> "" Then Berechnung 1
    If TextBox3 <> "" And TextBox4 <> "" Then Berechnung 2
    If TextBox5 <> "" And TextBox6 <> "" Then Berechnung 3
End Sub

Und im allgemeinen Modul diesen Code:

Code:

Sub Berechnung(bytSpalte As Byte)
    Dim rngZelleStart As Range
    Dim rngZelleEnde As Range
    Dim strControl1 As String
    Dim strControl2 As String
    Dim strControl3 As String
    Dim strControl4 As String
    Dim strControl5 As String
    Dim strControl6 As String
    Select Case bytSpalte
        Case 1
             strControl1 = "TextBox1"
             strControl2 = "TextBox2"
             strControl3 = "TextBox7"
             strControl4 = "TextBox8"
             strControl5 = "TextBox9"
             strControl6 = "TextBox10"
        Case 2
             strControl1 = "TextBox3"
             strControl2 = "TextBox4"
             strControl3 = "TextBox11"
             strControl4 = "TextBox12"
             strControl5 = "TextBox13"
             strControl6 = "TextBox14"
        Case 3
             strControl1 = "TextBox5"
             strControl2 = "TextBox6"
             strControl3 = "TextBox15"
             strControl4 = "TextBox16"
             strControl5 = "TextBox17"
             strControl6 = "TextBox18"
    End Select
    With Sheets("Tabelle1")
        Set rngZelleStart = .Columns(1).Find(CDbl(UserForm1.Controls(strControl1)), lookat:=xlWhole)
        Set rngZelleEnde = .Columns(1).Find(CDbl(UserForm1.Controls(strControl2)), lookat:=xlWhole)
        If rngZelleStart Is Nothing Or rngZelleEnde Is Nothing Then
            MsgBox "Wert nicht gefunden"
        Else
            UserForm1.Controls(strControl3) = _
                Application.Sum(.Range(.Cells(rngZelleStart.Row, 2), .Cells(rngZelleEnde.Row, 2)))
            UserForm1.Controls(strControl4) = _
                Application.Sum(.Range(.Cells(rngZelleStart.Row, 2), .Cells(rngZelleEnde.Row, 2))) / 2
            UserForm1.Controls(strControl5) = _
                Application.Sum(.Range(.Cells(rngZelleStart.Row, 2), .Cells(rngZelleEnde.Row, 2))) / 3
            UserForm1.Controls(strControl6) = _
                Application.Sum(.Range(.Cells(rngZelleStart.Row, 2), .Cells(rngZelleEnde.Row, 2))) / 4
        End If
    End With
    Set rngZelleStart = Nothing
    Set rngZelleEnde = Nothing
End Sub

Für die Berechnung benötigst du kein Tabellenblatt, das kann man direkt im Code machen.

Bis später,
Karin

 

Vielen Dank!


Einfach perfekt!!!
Ich hab das wohl etwas umstädlich angefangen :)

 

Hey,

ich hab nochmal ne Frage:
Ich würde jetzt gern aus der Userform die Werte in ein Druckformular kopieren.
Leider überschreibe ich mir jedes mal die Zeilen, weil ich nicht weiß wie ich dem Makro erklären soll das es eine Spalte weiter springen muss..

Vielen Dank, Marius

 

Hi Marius,

schreibe den Code für das Eintragen nach diesem Prinzip:

Code:

Cells(7, 5 + bytSpalte) = CDbl(UserForm1.Controls(strControl1))

Da du die Spalte, in der sich die TexBoxen auf dem UserForm stehen, ja mit an die Prozedur übergibst, kannst du sie auch gleich zur Festlegung der Spalte für das Tabellenblatt verwenden.

Ich nehme an, dass du die Zahlen aus der TextBox auch als "richtige" Zahl ins Tabellenblatt schreiben möchtest? Derzeit trägst du sie ja als Text ein, denn Inhalte von TextBoxen sind immer Text. Folglich musst du die "Textzahlen" aus den TextBoxen noch in Zahlen umwandeln - da im gegebenen Fall auch Dezimalzahlen vorkommen können, verwendet man dafür CDbl (Bezeichnung für den Datentyp Double).

Bis später,
Karin

 

Vielen Dank!

Wieder etwas gelernt!!!!!

MfG, Marius