Office: Sendkeys an Windows Bild- und Faxanzeige

Hallo zusammen,

ich möchte gern per VBA SendKeys("PGDN") an die Windows Bild- und Faxanzeige senden um die Seiten eines MultiTifs zu durchblättern.

Die Tif-Datei rufe ich bisher so auf:
Shell "rundll32.exe shimgvw.dll,ImageView_Fullscreen C:\Dokumente und Einstellungen\Sven\Desktop\testtif.tif"

Hat jemand eine Idee und kann mir helfen?


Das System das ich zur Verfügung habe: Win XP mit Office 2003

Vielen Dank und Viele Grüße
Sven

 

Hallo Sven,

Du wendest die shimgvw.dll auf einen Dateipfad an, der Leerzeichen enthält: C:\Dokumente und Einstell...".
Ein solcher Dateipfad muss jedoch in solche "..." Anführungszeichen gesetzt werden, damit die einzelnen Pfadbestandteile nicht als mehrere Parameter aufgefasst werden. Aber genau mit diesen Anführungszeichen beim Dateipfad kann jedoch die shimgvw.dll nichts anfangen.
Diese verquere Eigenschaft konnte ich durch Tests herausfinden (ich habe allerdings Windows8):
1) Entweder Du verwendest einen Dateipfad, der keine Leerzeichen enthält. Dann brauchst Du den Dateipfad nicht in Anführungszeichen setzen. Dann kannst Du die shimgvw.dll verwenden. Dann funktioniert sie auch unter Windows8.
2) Oder aber Du kannst nicht auf einen solchen Dateipfad verzichten: Dann musst Du einen anderen Grafikviewer verwenden, zB. Irfanview. Dieser ist noch dazu gratis. Dieser versteht natürlich auch die Page-Down- und Page-Up-Tasten.

Nachfolgend der Code, den ich verwendet habe, mit reichlich Kommentar:

Code:

Option Explicit
'
'Die Variable varProgID ist hier auf Modulebene zu deklarieren, damit sie
'sowohl in der SUB cmdNxtSeite_Click als auch in der SUB AnwendungÖffnen verfügbar ist.
Dim varProgID As Variant
'
'Click-Ereignis für den ActiveX-Button "cmdNxtSeite":
'
Private Sub cmdNxtSeite_Click()
'
  'varProgID = Range("A3").Value
  If varProgID Then
    'Sendkeys sendet die Tastaturbefehle an die Anwendung, die gerade den Fokus hat.
    'In der Shell-Funktion wurde zwar die Anwendung in einem Fenster mit NormalFocus geöffnet;
    'damit sie aber vor dem Senden des Tastenbefehls tatsächlich noch/wieder den Fokus hat/bekommt,
    'wird auf die erfolgreiche Ausführung des AppActivate-Befehls gewartet:
    VBA.AppActivate Title:=varProgID, Wait:=True
    'Der Tastenbefehl "Page-Down" wird an die Anwendung, die momentan den Fokus hat, gesendet.
    'Damit eine Wirkung feststellbar ist, muss diese Anwendung diesen Tastenbefehl tatsächlich auch "verstehen".
    SendKeys String:="{PGDN}", Wait:=True
  Else
    MsgBox "Die ProgID = 0 ! --> Abbruch."
  End If
  '
End Sub
'
'Click-Ereignis für den ActiveX-Button "cmdÖffnen":
'
Private Sub cmdÖffnen_Click()
  Call AnwendungÖffnen
End Sub
'
Private Sub AnwendungÖffnen()
  '
  Dim Anwendung As String, PfadDatei As String
  '
  Anwendung = "Rundll32.exe shimgvw.dll,ImageView_Fullscreen "
              'Anwendung = "C:\Windows\System32\notepad.exe" '<--- Damit habe ich getestet.
  PfadDatei = "C:\Dokumente und Einstellungen\Sven\Desktop\testtif.tif"
              'PfadDatei = "I:\VecWaWi\Export\Stamm12.txt"   '<--- Damit habe ich getestet.
  'Enthält der Pfad/Dateiname Leerzeichen, muss das Ganze in ".." gesetzt werden:
  'PfadDatei = Chr(34) & PfadDatei & Chr(34)
  'shimgvw.dll erkennt aber leider nicht einen solchen in ".."-gesetzten Dateipfad !!!
  'Hier ist es besser einen anderen Viewer zu verwenden, zB. Irfanview  (dieser ist noch dazu gratis)
  '
  'Damit die Anwendung auf Sendkeys reagiert, muss ihr Anwendungsfenster den Fokus haben.
  'Außerdem wird der Rückgabewert der Shell-Funktion benötigt, um ermitteln zu können, ob die Anwendung gestartet ist.
  varProgID = VBA.Shell(PathName:=Anwendung & " " & PfadDatei, WindowStyle:=vbNormalFocus)
  '
  'Da die Shell-Funktion die Anwendung asynchron startet, ist es notwendig,
  'zu überprüfen, ob die Variable varProgID bereits einen Wert ungleich Null (= Anwendung ist gestartet) enthält.
  'Damit die Abarbeitung anderer Ereignisse unter Windows nicht behindert wird,
  'ist zwischenzeitlich der Aufruf der DoEvents-Prozedur notwendig.
  Do While varProgID = 0
    DoEvents
  Loop
  'Range("A3").Value = varProgID
End Sub

Diesen Code habe ich im Codemodul eines Arbeitsblattes verwendet. Im Arbeitsblatt selber habe ich 2 ActiveX-Buttons platziert namens "cmdÖffnen" und "cmdNxtSeite". Durch Anklicken dieser beiden Buttons werden die Klick-Prozeduren "cmdÖffnen_Click()" und "cmdNxtSeite_Click()" ausgeführt.

 

Hallo Anton,
vielen Dank das Du dir so viel Arbeit gemacht hast.
Ich werde das morgen gleich ausprobieren.
Was einen anderen Viewer wie z.B. Irfanview angeht... ich darf (kann) keine Software auf meinen Firmen PC installieren.
Daher muss ich alles was Tools und Automatisierung betrifft mit vba/vbs und mit den Anwendung die MS bereitstellt erledigen :-(

Viele Grüße
Sven

 

Funktioniert wunderbar!!!
Vielen Dank nochmals.