Office: Serienbrief aus mehreren Datensätze

Hallo
ich benötige Hilfe bei der Erstellung eines Serienbriefes aus eine Excel Tabelle. Hintergrund ist, ich habe ein Excel Tabelle aus Teams Schichten exportiert.
Hier wird aus jedem Eintrag ein Datensatz erstellt. Ich müsste die Tabelle jetzt so filtern Abfragen etc.. das ich einen Datensatz für eine Person bekomme mit StartDatum EndDatum am besten noch KW. Diesen könnte ich dann benutzen um einen Serienbrief zu erstellen.

 

Hola,
kannst du mal anhand der Tabelle zeigen wie das Wunschergebnis aussehen soll?
Gruß,
steve1da

 

Anbei die Datei, in Tab Endergebnis sind die Daten welche ich für den Serienbrief benötige.
Danke für dein Interesse.
Gruß
icjc99

 

In A2:
=EINDEUTIG(Schichten!A2:A16)
In B2:
=INDEX(Schichten!$C$2:$I$16;AGGREGAT(15;6;ZEILE(Schichten!$C$2:$I$16)-1/(Schichten!$A$2:$A$16=$A2);ZEILE(A1));VERGLEICH(B$1;Schichten!$C$1:$I$1;0))
Die Formel nach rechts und nach unten ziehen. Die Kalenderwochen musst du mit Isokalenderwoche() ermitteln, woher die Anschrift kommt, weiß ich nicht.

 

die Formel funktionieren leider nicht ganz , aber ich denke der Fehler liegt bei mir ich habe A2 befüllt gibt in Office 2016 #Name zurück und in Office 365 #Überlauf.
In B2 scheint es gut zu funktionieren. Jedoch bei ziehen bleibt er wohl bei den gleichen ausgangs Feldern.
Was mach ich falsch???
Gruß icjc99

 

Anbei nochmal die Datei

 

2016 kennt noch kein Eindeutig(). Soll das denn auch in 2016 genutzt werden oder nur in 365?
#ÜBERLAUF kommt wenn nicht genug freie Zellen für die Formel da ist. Lösch mal A3 und A4 dann kommt auch in 365 ein Ergebnis.
Beim Enddatum fehlt noch was, also in C2:
=MAXWENNS(Schichten!$F$2:$F$16;Schichten!$A$2:$A$16;A2)
Aber: Maxwenns() gibt es in 2016 auch nicht.

 

Ok leider steht mir nur 2016 zur Verfügung 365 war nur ein Versuch ob ich bei der Eingabe Fehler gemacht habe man verliert ja leicht den Focus.
Eine ähnliche Formel für 2016 gibt es nicht?

 

Ich habe jetzt alles in 365 ausprobiert und es funktioniert einwandfrei.
Top echt Klasse Lösung.

Viel viel Dank
Gruß icjc99
für 2016 gibt es keine Lösung ? - ich weiß ist echt frech gefragt.

 

Gibt's auch :)
In A2: =Schichten!A2
In A3: =WENNFEHLER(INDEX(Schichten!$A$2:$A$16;VERGLEICH(1;(ZÄHLENWENN(A$2:A2;Schichten!$A$2:$A$16)=0)*(Schichten!$A$2:$A$16<>"");0));"") diese Formel mit Strg-Shift-Enter abschließen.
In C2:
=INDEX(Schichten!$F$2:$F$16;AGGREGAT(14;6;ZEILE(Schichten!$A$2:$A$16)-1/(Schichten!$A$2:$A$16=A2);1))

 

Vielen Vielen Dank,
es hat alles hervorragend geklappt.
Gruß
Icjc99

 

Hallo,
ich brächte doch nochmal Hilfe.
Bei C2: gibt er das höchste Datum für die Person aus pass also für das Enddatum.
Jedoch findet er mit dieser Formel nicht das niedrigstem Anfangsdatum für die Person?
Ich denke es liegt an den Zelle auf die verwiesen wird aber ich weiß nicht weiter.
Gruß
icjc99

 

Hallo,

ich würde folgende Formel statt dessen probieren:
=INDEX(Schichten!$D$2:$D$16;AGGREGAT(15;6;ZEILE(Schichten!$A$2:$A$16)-1/(Schichten!$A$2:$A$16=A2);1))

 

Hallo,

allerdings müsste für eine Formel in Zelle Endergebnis!B2 Folgendes sogar besser funktionieren:
=AGGREGAT(15; 6; Schichten!$D$2:$D$16 / (Schichten!$A$2:$A$16 = A2); 1)
Diese Formel ermittelt das kleinste Startdatum in Schichten!D2:D16, das für das Mitglied aus Zelle Endergebnis!A2 zutrifft.
Sie funktioniert auch dann, wenn die Zeilen nicht nach Schichten!D2:D16 aufsteigend sortiert sind.

 

Klasse funktioniert, macht jetzt richtig Spass damit zu experimentieren. Mit Aggregat Kleinst und Gröster wert Top Danke.
Vieleicht habt ihr ja noch eine Idee, ich versuche gerade die Zelle A3 so umzubauen das er den Index und Zählenwenn auf die Kalenderwochen unterteilt.
Wenn das nicht möglich ist schade aber ihr habt mit alle sehr geholfen .
Danke
Gruß Icjc99