Office: Seriennummern in Spalte

Hallo Zusammen

Komme leider nicht weiter und zähle verzweifelt auf eure Hilfe!
Habe ein Excel, Spalte 1 = Artikelnummern, Spalte 2 bis n = Seriennummern. Möchte nun die Seriennummern in Spalte 2 untereinander haben:

Ausgangslage Variante 1:
http://dl.dropbox.com/u/10535061/Mappe1.xlsx

Ausgangslage Variante 2:
http://dl.dropbox.com/u/10535061/Mappe2.xlsx

==> Ziel ist es, pro Zeile EINE ArtikelNr. und EINE Seriennummer zu haben (wohl eine Mischung aus Transponieren, Zeile einfügen und Artikel-Nr. kopieren).


Beispiel
vorher:
1885690100159;c121212121;c124547845;c147845787

nachher:
1885690100159;c121212121
1885690100159;c124547845
1885690100159;c147845787


kann hier jemand helfen? Vorgabe ist, ein Makro dazu zu schreiben.

Herzlichen Dank im voraus!
Gruss
Raphi

 

Hallo Raphi,

den Schritt von Variante 1 zu Variante 2 > "Text in Spalten" hast Du schon gefunden, okay.

Dann könnte für Variante 2 dieser Code sein, was Du suchst:

Code:

Option Explicit

Dim loZeile As Long
Dim loLetzteZeile As Long

Dim intSpalte As Integer
Dim intLetzteSpalte As Integer
Dim intCounter As Integer

Dim varArtikelnummer As Variant
Dim varSeriennummer As Variant

Public Sub SeriennummernVerteilen()
    
    With Me
        ' letzte belegte Zelle in Spalte A
        loLetzteZeile = IIf(IsEmpty(.Cells(.Rows.Count, 1)), .Cells(.Rows.Count, 1).End(xlUp).Row, .Rows.Count)
        
        ' alle belegten Zeilen durchlaufen
        For loZeile = loLetzteZeile To 2 Step -1
            ' letzte belegte Spalte in aktueller Zeile
            intLetzteSpalte = IIf(IsEmpty(.Cells(loZeile, .Columns.Count)), .Cells(loZeile, .Columns.Count).End(xlToLeft).Column, .Columns.Count)
            
            ' wenn mehrere Seriennummern in einer Zeile stehen
            If intLetzteSpalte > 2 Then
                intCounter = 1
                
                ' alle Seriennummern ab der 2. in der aktuellen Zeile
                For intSpalte = 3 To intLetzteSpalte
                    
                    ' Wertübergabe an Variablen
                    varArtikelnummer = .Cells(loZeile, 1).Value
                    varSeriennummer = .Cells(loZeile, intSpalte).Value
                    
                    ' Zeile einfügen
                    .Rows(loZeile + intCounter).Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
                    
                    ' Werte in Zellen eintragen
                    .Cells(loZeile + intCounter, 1).Value = varArtikelnummer
                    .Cells(loZeile + intCounter, 2).Value = varSeriennummer
                    
                    ' Zähler erhöhen
                    intCounter = intCounter + 1
                    
                Next intSpalte
                
                ' nicht mehr benötigte Werte löschen
                .Range(.Cells(loZeile, 3), .Cells(loZeile, intLetzteSpalte)).ClearContents
                
            End If
            
        Next loZeile
        
    End With
    
End Sub

Kopiere diesen Code in das Modul des Tabellenblattes wo Du ihn nutzen möchtest und lass ihn laufen.
Vorher solltest Du aber auf jeden Fall eine Sicherheitskopie Deiner Daten machen.

Danach würde ich empfehlen Deine Tabelle mal zu sortieren und Doppelte zu löschen.
Aber das musst Du ja wissen. ;O)


Ich hoffe geholfen zu haben.

 

Hallo Achim

Wow, ich bin schlicht begeistert, besten Dank für deine ausführliche Antwort!

Leider generiert der Code bei mir folgenden Fehler:
"Fehler beim Kompilieren:
Unzulässige Verwendung des Schlüsselworts Me"

Was meinst du?

 

Hallo Raphi,

das "Me" ist die Referenz, damit Excel weiß auf welchen Bereich, welches Blatt, welche Mappe sich der Code bezieht.


Ich vermute, Du hast diesen Satz nicht befolgt:

In einem allgemeinen Code-Modul müsste die Referenz anders aussehen, zum Beispiel so:

Code:

With ThisWorkbook.Worksheets(1)

oder so:

Code:

With ThisWorkbook.Worksheets(Tabelle1)

Im angehängten Bild siehst Du genau welches Code-Modul ich meine.
Dort muss der Code rein.
Falls Du den Code NICHT für Blatt 1 nutzen möchtest, muss er natürlich in das entsprechende Modul.

Ich hoffe jetzt sind alle Klarheiten beseitigt.
;O)

 

Hallo Achim

Perfekt, hat einwandfrei funktioniert, tausend dank für deine Hilfe! Habe noch einige Ergänzungen vorgenommen (wie Zeilen ohne Seriennummern löschen etc.), nun kann sichs sehen lassen ;)

Gute Zeit,
Gruss
Raphael