Office: Spalten anhand ihres Namens löschen/anzeigen

Hallo zusammen,

ich bekomme auf der Arbeit immer wieder Ausleitungen in Form von Excel-Tabellen mit Spalten von A bis CT. Die Spaltenüberschriften sind immer die selben.
Diese Tabellen muss ich kurz zusammenstellen, damit in der Präsentation nur noch die wichtigsten Spalten übrig bleiben + eine Spalte mit einem Link.
Bisher habe ich mir ein Macro gebastelt, dass z.B. alle Spalten von D-F, J-L, N, Q, AB-CB, usw. löscht. Das dann formatiert und alles hat gepasst.

Jetzt musste ich nach 3 Monaten feststellen, dass mein Macro nicht mehr das richtige Ergebnis bringt. In den aktuellen Ausleitungen haben sich die Spalten getauscht. CB wurde jetzt zu CD, usw.
Leider kann das immer wieder mal vorkommen, heißt mein Macro alle halbe Jahr anpassen reicht nicht. Kann auch alle paar Wochen vorkommen.

Darum stellt sich mir die Frage, wie ich es sonst lösen könnte. Kann ich Spalten gemäß ihrer Überschrift (Textinhalt) ausblenden/anzeigen?

Als Beispiel:
Spalten: A=Name | B=Datum | C=Herkunft | ... | CO= Menge | CP=Link zum Dokument

Und diese Spalten + Inhalte muss ich präsentieren und auf den Link zum jeweiligen Dokument klicken können.
Um von den über 90 Spalten nicht alles händisch löschen zu müssen, hätte ich gerne wieder ein Makro.

Habt ihr eine Idee wie ich das umsetzen könnte?
Entweder bestimmte Spalten gemäß ihrer jew. Überschrift ausblenden/löschen oder in einem neuen Sheet nur bestimmte Spalten anzeigen basierend auf den Daten vom ersten Sheet z.B.?

Danke schon mal im Voraus

 

Hallo Arbok,

das ist kein Problem, nur müsste man deine Datei kennen, bzw. wissen, welche Überschrift(en) die Spalten haben, die da gelöscht werden sollen.

 

Hallo Klaus-Dieter,
Ich habe mal eine kleine fiktive Datei erstellt.
Anzeigen möchte ich folgende Spalten:
ID, Name, Herkunft, Endzeitpunkt, Menge, Inhalt, Kommentar, Link zum Dokument

 

Hallo Arbok,

so würde das gehen, einige der Überschriften haben noch ein Leerzeichen am Ende, habe das erst einmal im Makro abgefangen, ist aber nicht so schön. Das ist ohnehin der Schwachpunkt dieser Arbeitsweise, es spiel zwar keine Rolle, wo die Spalten sind, die nicht gelöscht werden sollen, nur die Namen müssen eben passen.

Code:

Option Explicit

Sub löschen()
    Dim intSp As Integer
    Dim intAnz As Integer
    Dim varTitArr As Variant
    Dim strTempTiT As String
    Dim intMerk As Integer
    varTitArr = Array("ID", "Name ", "Herkunft ", "Endzeitpunkt ", "Menge ", "Inhalt", "Kommentar", "link zum Dokument")
    For intSp = Cells(1, Columns.Count).End(xlToLeft).Column To 1 Step -1
        intMerk = 0
        strTempTiT = Cells(1, intSp)
        For intAnz = 0 To 7
            If strTempTiT = varTitArr(intAnz) Then
                intMerk = 1
            End If
        Next intAnz
        If intMerk = 0 Then Columns(intSp).Delete Shift:=xlToLeft
    Next intSp
End Sub

 

Hi,

z.B. mit folgendem Makro:

Code:

Sub Ausblenden()
    Dim rngSpalten As Range
    Dim rngZelle As Range
    Dim arrSpalten()
    Dim intZaehler As Integer
    arrSpalten = Array("Name", "Datum", "Herkunft", "Menge") '<== hier alle Spaltenüberschriften auflisten die ausgeblendet werden sollen
    ActiveSheet.Columns.Hidden = False
    For intZaehler = 0 To UBound(arrSpalten)
        Set rngZelle = Rows(1).Find(arrSpalten(intZaehler), lookat:=xlWhole)
        If Not rngZelle Is Nothing Then
            If rngSpalten Is Nothing Then
                Set rngSpalten = rngZelle
            Else
                Set rngSpalten = Union(rngSpalten, rngZelle)
            End If
        End If
    Next intZaehler
    If Not rngSpalten Is Nothing Then rngSpalten.EntireColumn.Hidden = True
End Sub

---

 

Hallo, jeder schreibt sein eigenes Rezept, und davon hängt später alles ab. Die Jungs haben dir einige sehr gute Optionen genannt, ziehe sie in Betracht.

 

Guten Morgen,

Vielen Dank euch, das funktioniert super.