Office: Spalten mittels Dropdown-Auswahl ein- und ausblenden

Hallo,
ich bin neu hier im Forum. Mein Name ist Guido, ich bin um die 50 Jahre alt und benötige dringend eure Hilfe bei einem Excel-Problem. Ich erstelle gerade eine Checkliste, die über das Jahr monatlich geführt werden muss. Da ich das Ganze als geschütztes Arbeitsblatt auf einem Surface Go rumtrage möchte, wäre das echt super, wenn ich die Monatsspalten, die ich beim Rundgang nicht benötige einfach ausblenden könnte, ohne jedes mal den Blattschutz aufzuheben und wieder neu zu aktivieren. Hat jemand eine Idee, wie das gehen könnte?
So stelle ich mir das irgendwie vor:







Vielen Dank schon mal für eure Unterstützung.
Gruß Guido

 

Hi,

Deine Dropdown-Auswahl des jeweiligen Monats sei mal in J5. Folgenden Code in das Codemodul des Tabellenblattes:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim x As Long, y As Long
With Target
If .Address(0, 0) = "J5" Then
x = Application.Match(.Value, Range("K5:V5"), 0) + 10
Me.Unprotect "DeinPasswort"
For y = 11 To 22
Columns(y).Hidden = (y <> x)
Next y
Me.Protect "DeinPasswort"
End If
End With
End Sub

 

Hi Boris,
hui, das ist mal ne schnelle Antwort. Ok, dann muss ich mich wohl mal endlich mit Codes und Makros beschäftigen.
Da habe ich bislang keine Erfahrungen mit gemacht.
Wo finde ich denn dieses Codemodul?

 

Hi,

VBA-Editor mit Alt+F11 öffnen, links im Projektexplorer einen Doppelklick auf das Codemodul des entsprechenden Tabellenblattes, den Code dann in das rechte Fenster reinkopieren und den Editor wieder oben links mit x schließen.

 

Krass, geht. Nur die Möglichkeit, alle wieder anzuzeigen wäre noch super.

 

Hi,

dann mit dieser kleinen Änderung - alle Spalten werden eingeblendet, wenn die Zelle J5 leer ist (leere sie mit der Entf-Taste).

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim x As Long, y As Long
With Target
    If .Address(0, 0) = "J5" Then
        Me.Unprotect "DeinPasswort"
        If .Value = "" Then
            Columns("K:V").Hidden = False
        Else
            x = Application.Match(.Value, Range("K5:V5"), 0) + 10
            For y = 11 To 22
                Columns(y).Hidden = (y <> x)
            Next y
        End If
        Me.Protect "DeinPasswort"
    End If
End With
End Sub

 

Vielen Dank Boris. Das klappt hervorragend. Lediglich das Surface Go geht beim Ausführen des Makros ein bissl in die Knie. Aber muss ja nur einmal im Monat ausgeführt werden.!
Gruß Guido

 

Moin Guido,
".. geht in die Knie" Das liegt dann aber nicht an Boris' Code, sondern hat andere Gründe. Ich habe den Code eben getestet und keinen Unterschied zwischen einem satt ausgestatteten i7 und meinem Go Pro feststellen können.
Da dürften eher die Fotos, Pläne und bunten Formatierungen ein Rolle spielen (die ich natürlich nicht nachgebildet habe).
Grüße

 

Ja, klar. Sind ne Menge Bilder drin, die dann immer verschoben werden müssen. Funktioniert ja und muss ja nicht ständig auf und zugeklappt werden.
also, alles gut. Hast mir sehr geholfen.