Office: (Office 365) Spalten Sortieren nach Zahlen mit Buchstaben (1a,1b usw)

Hallo,

ich habe hier eine Bauteileliste erstellt um diese leichter wiederzufinden.
Das Problem ist, dass die Baugruppen unterteilt sind (ist ein Kartonbaubogen mit mehreren Hundert Teilen, verteilt auf verschiedene Bögen).
Nun hat eine Baugruppe zum Beispiel die Teile 5, 5a, 5b, 5c, 5d usw. Also das erste Teil hat eben keinen Buchstaben. Wenn ich die Liste nun sortiere sortiert Excel erstmal die ganzen Zahlen und dann erst die Zahlen mit Buchstaben.
Ich kann es jetzt so lassen, weil es halt so ist, oder das ganze per Hand sortieren oder irgendwie eine zweite Spalte mit den Buchstaben und diese dann noch mal seperat sortieren oder per Hand.. Keine Ahnung, gibt viele Möglichkeiten, aber ich will erstmal fragen, ob man Excel das auch irgendwie anders sagen kann, dass die Reihenfolge erst Zahl, dann Zahl mit Buchstaben und dann erst die nächsthöhere Zahl?

Hat da jemand eine geschickte Lösung?

Ich hänge die Datei einfach mal mit an, ist aber noch der erste Rohentwurf, also quasi gerade erst aufgenommen :)

Vielen Dank

Andreas

 

Hi,

mit einer Hilfsspalte:

Vielleicht besser noch so:

Code:

=WENN(ISTZAHL([@Bogen]);[@Bogen]&"@";[@Bogen])

 

Hi,

ich würde ja zwei neue Spalten machen. Diese bekommen die Formeln

Code:

=[@[Teile Nummer]]&""
=[@Bogen]&""

Jetzt kannst du nach einer der beiden Spalten sortieren.

 

Danke für die Hilfe. Ich habe das wohl etwas schlecht erklärt. Es soll natürlich die Bauteilenummern sortiert werden, da ich diese ja nacheinander benötige. Ich schau dann nach, auf welchem Bogen das Teil ist und lege mir diese zurecht. Aber das ist nicht schlimm, ich habe die Formel entsprechend umgestellt.
Nach Bögen muß ich gar nicht sortieren.

Nun ist das schon ganz toll, allerdings habe ich jetzt eigentlich eine noch komplexere Sortierung, indem es mit 100 anfängt, dann bis 109 und dann kommt 11 und geht dann mit 110 weiter. Das ist vermutlich der "logischen Sortierung" geschuldet. Normalerweise kann man die Zellen so formatieren, dass die Zahlen immer Drei- oder Vierstellig sind. Aber mit Buchstaben geht das nicht..
Eventuell müsste ich sie dann doch noch mal umschreiben, indem ich eine Spalte für Zahlen und eine für Buchstaben nehme. Wird sicher das einfachste sein..

 

=TEXT(1;"000"&"A")

 

Hallo,

da du Excel365 hast, eine Hilfsspalte mit folgender Formel erzeugen:
=LET(nr;[@[Teile Nummer]]; WENN(ISTZAHL(nr);TEXT(nr;"000 ");nr))

Zu beachten ist, dass das Leerzeichen in "000 " wichtig ist. Diese Spalte alphabetisch sortieren.
Dann müsste die Spalte "Teile Nummer" richtig sortiert sein, wenn man vom offensichtlichen Falscheintrag "1^53c" absieht.

 

Hallo,

meine obige Formel bitte korrigieren:
=LET(nr;[@[Teile Nummer]]; WENN(ISTZAHL(nr);TEXT(nr;"000 ");RECHTS("000"&nr;4)))
So müsste es jetzt endlich stimmen.

 

Hi Anton,

nicht ganz, bei diesen Nummern versagt die Formel:

So gehts, außer bei D1 D2 u. D3:

Code:

=LET(nr;[@[Teile Nummer]]; WENN(ISTZAHL(nr);TEXT(nr;"000 ");RECHTS("000"&nr;5)))

 

Das wird mir jetzt regelrecht unangenehm, ihr gebt euch so viel Mühe.
Ich habe die aktualisierte Liste mit der (letzten) Formel mal hochgeladen. Die Fehlerhafte Zahl hatte ich nämlich auch schon entdeckt und korrigiert. Auch die Teile "D" habe ich herausgenommen, da sie eigentlich unwichtig sind.
Beide Formeln funktionieren aber leider trotzdem nicht, da die Ziffern nun zwar "einige Nullen" voranstellen, aber eben auch die großen und das macht das ganze dann überflüssig. Die "5" und "50" und Konsorten erscheinen nun irgendwo mittendrin, bzw. am Ende :)

 

Hi,

Code:

=LET(nr;[@[Teile Nummer]]; WENN(ISTZAHL(nr);TEXT(nr;"0000 ");RECHTS("000"&nr;5)))

 

Moin

Code:

=LET(
länge;LÄNGE([@[Teile Nummer]]);
zahlwert;AGGREGAT(14;6;--TEIL([@[Teile Nummer]];1;SEQUENZ(länge));1);
textwert;WECHSELN([@[Teile Nummer]];zahlwert;"");
TEXT(zahlwert;"000"&ZEICHEN(9))&textwert
)

 

Hi,

oder auch so:

Code:

=LET(ya;[@[Teile Nummer]];
xa;REGEXERSETZEN(ya;"[a-z]";"";0;1);
xaa;LÄNGE(xa);xb;WIEDERHOLEN(0;5-xaa)&xa;
xb&TEIL(ya;xaa+1;99))

 

Hi,

falls es REGEX-Funktionen nicht gibt:

Code:

=LET(
xa;AGGREGAT(15;6;SPALTE($A$1:$F$1)/(CODE(TEIL(A2&"z";SPALTE($A$1:$F$1);1))>65);1);
xb;WIEDERHOLEN(0;5-xa);
xb&A2)

 

Sieh mal an, ich wußte gar nicht dass ich die Regenechsen auch schon habe.

AnzStellen ist eine benannte Zelle ausserhalb der Tabelle und bezieht sich ausschließlich auf den Zahlwert.

Code:

=LET(
teilenr;[@[Teile Nummer]];
zahlwert;REGEXERSETZEN(teilenr;"[a-z]";"";;1);
format;WIEDERHOLEN(0;AnzStellen)&ZEICHEN(9);
textwert;WECHSELN(teilenr;zahlwert;"");
ergebnis;TEXT(zahlwert;format)&textwert;
ergebnis)

PS: Woher kommt eigentlich der Zusatz "PowerQuery Guru" unter meinem Avatar?

 

Hallo,

falls die Funktion REGEXEXTRAHIEREN bereits verfügbar ist: Folgende berechnete Hilfsspalte
=LET(tx;REGEXEXTRAHIEREN([@[Teile Nummer]];"(\d{0,4})(\D*)";2); TEXT(INDEX(tx;1);"0000")&INDEX(tx;2))

Falls jedoch bei der Formel von vorhin #NAME? angezeigt wird:
Im Namensmanager unter Name "SortKey" folgende benutzerdef. Formel eingeben unter Bezieht sich auf:
=LAMBDA(key; LET(lg; LÄNGE(key); nr;TEXTVERKETTEN("";1; LET(ch;TEIL(key;SEQUENZ(lg); 1); WENN(("0" <= ch) *(ch <= "9");ch;""))); TEXT(nr;"0000")&RECHTS(key; lg-LÄNGE(nr))))
Statt obiger LET-Formel folgende benutzerdefinierte Funktion als berechnete Hilfsspalte eingeben:
=SortKey(@[Teile Nummer])