Office: (Office 2019) Spalteninhalte vergleichen Werte durch Leerzeichen getrennt

Hallo,

ich stehe vor der Aufgabe zwei Spalteninhalte zu vergleichen in welchen mehrere Werte stehen welche wiederum durch Leerzeichen getrennt sind. Die Reihenfolge der Werte kann dabei jedoch variieren.

Bsp:
Spalte 1 : A1 B1 C1
Spalte 2: B1 A1 C1

In dem Fall möchte ich eine extra Spalte "gleich" schreiben.

Bsp:
Spalte 1 : A1 B1 C1
Spalte 2: B1 A1 D1

In dem Fall möchte ich eine extra Spalte "ungleich" schreiben.

Hat jemand eine Idee wie ich das lösen kann? Danke vorab.

 

Moin

C1

Code:

=MTRANS(XMLFILTERN("<y><z>"&WECHSELN(A1; " ";"</z><z>")&"</z></y>";"//z"))

D1

Code:

=MTRANS(XMLFILTERN("<y><z>"&WECHSELN(B1; " ";"</z><z>")&"</z></y>";"//z"))

K1

Code:

=SUMME(ZÄHLENWENNS(C1#;G1#))=3

 

Danke. Arber irgendwie funktioniert das nicht .. oder ich bin zu blöd für die Anwendung.
Ich habe mich aber im Ausgangsthread auch Falsch ausgedrückt. Die Werte stehen nicht in einer Spalte sondern in einer Zelle.

 

Ich habe zwar XMLFILTERN() genommen aber trotzdem dynamische Arrays verwendet. Das passt nicht für Excel 2021.

Ansonsten sind mir da jetzt zu viele Unwägbarkeiten drin. Ich passe.
Vielleicht findet sich ein anderer.

 

Du möchtest also ein ODER über die Vergleiche. Warum nimmst Du so schlimme Inhalte? Jetzt muss ich weit weglaufen.

D1: =ODER(A1:C1=A2:C2) oder =ODER(INDEX(A1:C1=A2:C2;))

WAHR ist dabei "Gleich" (=mindestens ein Paar gleich)

 

Das würde nur funktionieren wenn die Werte gleich bleiben oder? es stehen aber immer neue Wérte in den Zellen. mal ist es ein Wert, mal 2 , mal 3 und mal 4.

 

Och mönsch ... Excel-Version? Bei 6 Zellen, die auszuwerten sind, darfst Du Dir die Mühe machen und hier mal bestätigen:

1 2 3
3 1 2 = ungleich

1 2 3
2 1 3 = gleich
-----
Ah, so langsam ahne ich, was Du willst:

1 2 3
3 1 2 = gleich

1 2 3
3 1 4 = ungleich

Du willst also einfach die einfach nur unsortierten Inhalte beider Zeilen auf Vollständigkeit (inhaltliche Identität) prüfen. Dann im neuesten Excel:
=UND(SORTIEREN(A1:C1;;;1)=SORTIEREN(A2:C2;;;1))

 

Lt. Präfix 2019.
Außerdem steht z.b. "A1 B1 C1" in einer Zelle.
In einem aktuellen Excel also z.B. so (geht wahrscheinlich kürzer):

	A	B	C
1	A1 B1 C1	C1 A1 B1	WAHR
2	A1 D1 E1	E1 B1 D1	FALSCH

Zelle	Formel
C1	=IDENTISCH(TEXTVERKETTEN(" ";1;SORTIEREN(TEXTTEILEN(A1;;" ")));TEXTVERKETTEN(" ";1;SORTIEREN(TEXTTEILEN(B1;;" "))))
C2	=IDENTISCH(TEXTVERKETTEN(" ";1;SORTIEREN(TEXTTEILEN(A2;;" ")));TEXTVERKETTEN(" ";1;SORTIEREN(TEXTTEILEN(B2;;" "))))

@ginatrick:
Entweder Du nimmst Excel Online oder Du brauchst VBA

Gruß Ralf

 

Ich bin durch "Spalteninhalte" statt "Zellinhalte" vom "Leerzeichen" abgelenkt gewesen :)

 

Hallo,
mit etwas Bauchweh müsste es auch mit folgender Formel gehen in Zelle C1:
=UND(
LÄNGE(A1)-LÄNGE(WECHSELN(A1;" ";""))=LÄNGE(B1)-LÄNGE(WECHSELN(B1;" ";""));
WENNFEHLER(SUMME(FINDEN(" "&XMLFILTERN("<x><t>"&WECHSELN(A1;" ";"</t><t>")&"</t></x>";"//t")&" ";" "&B1&" "))>0;FALSCH))
Sie überprüft
1) im 1.UND-Argument, ob die gleiche Anzahl Blanks in A1 und B1 vorhanden sind
2) im 2.UND-Argument, ob zu jeder Teilzeichenkette in A1 (begrenzt mit Blanks) eine solche in B1 (begrenzt mit Blanks) gefunden werden kann.
Diese Formel müsste auch mit Excel2019 funktionieren.

 

Hallo Anton!
Ja müsste gut funktionieren.
Da wir beide 365 nutzen, vergessen wir gerne, für Versionen bis 2019 auf den Formelabschluss mittels CSE hinzuweisen.
Schließlich übergibt XMLFILTERN() ein Such-Array an FINDEN()
FINDEN({" A1 ";" B1 ";" C1 "};" C1 A1 B1 ")

Gruß Ralf

 

Hallo @RPP63_neu,

meine Frage rührt aus einer Wissenslücke meinerseits: Microsoft behauptet, wie man in folgenden Link lesen kann
Dynamische Arrayformeln und Verhalten bei übergelaufenem Array - Microsoft-Support
dass die dynamischen Arrays in Excel2019 funktionieren sollten.
Stimmt das also nicht?

 

Die Hilfeseite dürfte Falsches behaupten!
Excel 2019 wurde in 2018 programmiert.
Spill-Range (die Voraussetzung für diese dynamischen Arrays) wurde in 2019 eingeführt, zunächst nur in 365 ausgerollt und in 2021 implementiert.

Spill range

Ein Excel 2019 Nutzer sollte dies mal kurz verifizieren (oder auch widerlegen).

Gruß Ralf

 

Hallo Ralf,

danke für die Info.

Dass dynam.Arrays mit Excel2016 nicht funktionieren (obwohl auch in genannter Hilfeliste enthalten), wusste ich.

 

Hallo,

in der Zwischenzeit konnte ich die Formel so verbessern, dass mein Bauchweh vom letzten Mal verschwunden ist:
Zu vergleichende Zeichenketten in Zellen A1 und B1, Formel zB. in Zelle C1:
{=UND(
LÄNGE(WECHSELN($A1;" ";""))=LÄNGE(WECHSELN($B1;" ";""));
WENNFEHLER(SUMME(FINDEN(" " & XMLFILTERN("<x><t>" & WECHSELN( WECHSELN(WECHSELN(GLÄTTEN($A1);" ";" ");" ";" " ); " ";"</t><t>") & "</t></x>";"//t") & " ";" " & $B1 & " "))>0;FALSCH))}

Die Formel überprüft

1. im 1. UND-Argument, ob die beiden Zeichenketten die gleiche Länge hinsichtlich der zu vergleichenden Zeichen haben, wobei natürlich Leerzeichen (ZEICHEN(32)) nicht mitgezählt werden, jedoch harte Leerzeichen (ZEICHEN(160)) schon.
2. im 2. UND-Argument, ob zu jeder Teilzeichenkette in A1 (begrenzt mit Leerzeichen) eine solche in B1 (ebenfalls begrenzt mit Leerzeichen) gefunden werden kann. Dabei ist es egal, wie viele Leerzeichen zwischen den Teilzeichenketten enthalten sind, auch solche am Anfang und Ende der Zeichenketten sind egal.

• Die Formel sollte ab Excel2013 funktionieren (wegen Funktion XMLFILTERN()).
• Bis Excel2019 muss die Formel als Array-Formel mit den geschweiften Klammern (rot) am Anfang und Ende eingesetzt werden, wobei diese Klammern nicht (direkt) eingegeben werden dürfen: Die Formel ist in die Formeleditierzeile ohne geschweifte Klammern einzugeben und die Formeleingabe ist dort mit der Tastenkombination Strg+Umschalt+EINGABE zu beenden (nicht mit EINGABE alleine !!). Danach erscheint sie wie oben gezeigt.
• In Excel2021 und Excel365 gibt es dynamische Arrays, sodass dort die geschweiften Klammern nicht mehr nötig sind.