Office: (Office 2019) Speichern einer Sicherheitsdatei als PDF

Hallo Liebe Excel Profis
da meine Kenntnisse für VBA echt gering sind, bitte ich etwas um Nachsicht.
Ich habe mir ein Makro gebastelt das nur speichert wenn ein USB Stick ermittelt wurde. funktioniert soweit. Das Speichern der Datei als .xlsm funktioniert auch wie es soll, nur beim Speichern der PDF wird ein komischer Name erzeugt. Der wie folgt aussieht

Monatslisten%20-%20Abschluß%20Mai%202025

%20 soll eigentlich ein Leerzeichen sein? Könnte mir jemand sagen warum dies geschieht? Der Code sieht wie folgt aus:

Code:

Sub Test()

Dim LWe As Object
Dim LW As Object
Dim Pfad As String
Dim Tabelle_save As String

Set LW = CreateObject("Scripting.filesystemobject").Drives
Pfad = ActiveWorkbook.Path
   
    For Each LWe In LW
        If LWe.IsReady = True And LWe.drivetype = 1 Then   '
       
    Tabelle_save = Pfad & "Monatslisten - " & "Abschluß " & Format(DateSerial(Year(Now), Month(Now), 0), "MMMM YYYY") & ".pdf"
 
    ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, _
        Filename:=Tabelle_save, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False
   
    Tabelle_save = Pfad & "Monatslisten - " & "Abschluß " & Format(DateSerial(Year(Now), Month(Now), 0), "MMMM YYYY") & ".xlsm"
   
    ActiveWorkbook.SaveCopyAs Filename:=Tabelle_save

    'Application.Quit
   
    End If
    Next
End Sub

Vielen Dank Schon mal von meiner Seite
schöne Grüße
Kruemi

 

benutze den Makrorecorder für das Speicher als PDF.

 

Hallo Hajo,
Danke für Deine Antwort.
Das habe ich gemacht und dann den aufgezeichneten Code eingefügt. Das Speichern der PDF funktioniert gut, nur der Name der abgelegten Datei ist nicht so wie es soll. Ich bekomme statt Leerzeichen %20 und ich weiß nicht woran es liegt.
aktueller Zustand - "Monatslisten%20-%20Abschluss%20Mai%202025"
soll Zustand - "Monatslisten - Abschluss Mai 2025"

schöne Grüße
Kruemi

 

Hi,

es wäre besser, Dateinamen ohne Leerzeichen und mit Unterstrich zu erzeugen!
"Monatslisten_ Abschluss_Mai_2025"
Die Leerzeichen erzeugen die %20!

 

Moin Kruemi,

beim Testen Deines Codes hat sich Dein Namenskonstrukt (per Debug.Print tabelle_save jeweils in den Zeilen unterhalb tabelle_save = brav) gezeigt, wie Du es erwartest. Nur erscheint die PDF-Datei nicht auf dem Stick, weil Dein Code beim Speichern des PDF mit Objektfehler abbricht (was sich aber als mein Fehler heraus gestellt hat, PDFs ohne Inhalt werden nun mal nicht gedruckt).

Hier mal eine VBAstelei, die Du in den Code eines Moduls kopierst:

Code:

Sub VBAstel_Test()
Dim wb As Workbook, oWMI As Object, cDrvs As Object, Drv As Object
Dim sPath As String, sPDF As String, sXLSM As String, sDrv As String

Set wb = ActiveWorkbook
Set oWMI = GetObject("winmgmts:\\.\root\CIMV2")
Set cDrvs = oWMI.ExecQuery("Select * from Win32_LogicalDisk")

sPath = wb.Path & "\"
sPDF = "Monatslisten-Abschluss " & Format(DateSerial(Year(Now), Month(Now), 0), "MMMM YYYY") & ".pdf"
sXLSM = "Monatslisten-Abschluss " & Format(DateSerial(Year(Now), Month(Now), 0), "MMMM YYYY") & ".xlsm"

For Each Drv In cDrvs
    If Drv.Drivetype = 2 Then
        sDrv = Drv.deviceid & "\"
        sPDF = sDrv & sPDF
        sXLSM = sDrv & sXLSM
        Debug.Print sPDF
        Debug.Print sXLSM
    End If
Next Drv

wb.Save
wb.SaveCopyAs sXLSM
DoEvents
wb.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sPDF, Quality:=xlQualityStandard

Set oWMI = Nothing

End Sub

Wenn es dann noch Probleme mit dem Dateinamen gibt, siehst Du das im Direktfenster und nimmst Boskos Tipp mit den Unterstrichen an. Dann lässt Dein System die Leerzeichen nicht zu, was bei all meinen Systemen Win10/11 und Mac kein Problem ist.
Anmerkung: Nach einer Office-Reparatur war unter den Extras die Microsoft Scripting Runtime noch nicht wieder am Start. Daher der Umweg über WMI.

Grüße

 

Hi,

vielleicht klappt es ja mit dem Vorschlaghammer:

Code:

Sub Test()
Dim LWe As Object
Dim LW As Object
Dim Pfad As String
Dim Tabelle_save As String

Set LW = CreateObject("Scripting.filesystemobject").Drives
Pfad = ActiveWorkbook.Path
   
    For Each LWe In LW
        If LWe.IsReady = True And LWe.drivetype = 1 Then   '
       
    Tabelle_save = Pfad & "Dummy.pdf"
   
    ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, _
        Filename:=Tabelle_save, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False
   
    Name Tabelle_save As Pfad & "Monatslisten - " & "Abschluß " & Format(DateSerial(Year(Now), Month(Now), 0), "MMMM YYYY") & ".pdf"
   
    Tabelle_save = Pfad & "Monatslisten - " & "Abschluß " & Format(DateSerial(Year(Now), Month(Now), 0), "MMMM YYYY") & ".xlsm"
   
    ActiveWorkbook.SaveCopyAs Filename:=Tabelle_save

    'Application.Quit
   
    End If
    Next
End Sub

Gruß
Jürgen

 

Moin Jürgen! Ungetestet, aber fehlt in Deinem Pfad nicht ein "\" ?

@Kruemi Falls Dir die FSO-Version mehr zusagt, hier eine etwas elegantere Fassung:

Code:

Sub VBAstel_Test_FSO()
Dim wb As Workbook, FSO As Object, oDrv As Object
Dim sPath As String, sDrv As String, sFile As String
Dim sPDF As String, sXLSM As String

Set wb = ActiveWorkbook
Set FSO = CreateObject("Scripting.filesystemobject").Drives

sPath = wb.Path & "\"
sFile = "Monatslisten-Abschluss " & Format(DateSerial(Year(Now), Month(Now), 0), "MMMM YYYY")
sPDF = sFile & ".pdf": sXLSM = sFile & ".xlsm"

For Each oDrv In FSO
     If oDrv.IsReady And oDrv.DriveType = 1 Then
        sDrv = oDrv.DriveLetter & ":\"
        sPDF = sDrv & sPDF
        sXLSM = sDrv & sXLSM
        Debug.Print sPDF
        Debug.Print sXLSM
    End If
Next oDrv

wb.Save
wb.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sPDF, Quality:=xlQualityStandard
wb.SaveCopyAs sXLSM

Set FSO = Nothing

End Sub

Viel Spaß damit!

 

Hi Bastler,

das ist der "Urcode" plus zwei Änderungen. Da müsste ich beim Kopieren versagt haben. Warten wir mal ab,
deine Lösung ist ja leicht eleganter.

Gruß
Jürgen

 

Hallo Zusammen,
vielen Dank für die ganzen Vorschläge. Sie laufen alle ohne Fehler sauber durch und das Ergebnis ist das was ich haben möchte. Ich werde den Vorschlaghammer Code von Jürgen benutzen, weil ich den Aufbau kenne und weiß was da passiert.
Nichts destotrotz werde ich auch Bastler seine Code´s saven um sie zu analysieren. (Vielleicht gibt es ja den einen oder anderen LernAHAeffekt).

vielen Dank nochmal an Bastler und Jürgen
schöne Grüße
Kruemi

 

Moin Kruemi,

solche Fragesteller lobe ich mir !! Nicht nur Fragen stellen, sondern auch die Chance wahrnehmen, etwas KnowHow zu stibitzen

Soll belohnt werden! Schau morgen mal auf VBAsteleien.de im Excel-Bereich vorbei. Dort stelle ich meine beiden Codes zu Deiner Frage mit ausführlichen Kommentaren ein. Da kannst Du dann sicher etwas abstauben

Schöne Grüße

 

'n Amd zusammen!

Die kommentierte FSO-Version ist online!

Viel Spaß damit!