Office: SQL Server Tabelle via ODBC und VBA verknüpfen

phil_discount · 18. November 2008

Hallo Leute,

ich habe schon gegoogelt, allerdings noch nichts 100% passendes gefunden.
Ich will via VBA eine Tabelle verknüpfen, abhängig von dem was der User in einem Dropdownmenü auswählt, soll eine Tabelle verknüpft werden.

Code:

Function CreateODBCLinkedTables() As Boolean
On Error GoTo CreateODBCLinkedTables_Err
Dim strTblName As String, strConn As String
Dim db As Database, rs As Recordset, tbl As TableDef
' ---------------------------------------------
' Register ODBC database(s)
' ---------------------------------------------
Set db = CurrentDb
DBEngine.RegisterDatabase "Stratadial", _
"SQL Server", _
True, _
"Description=Production Data" & _
Chr(13) & "Server=192.168.203.20" & _
Chr(13) & "Database=Stratadial"
' ---------------------------------------------
' Link table
' ---------------------------------------------
strTblName = "dbo.results_K20"
strConn = "ODBC;"
strConn = strConn & "DSN=sympatel_dialer;"
strConn = strConn & "APP=Microsoft Access;"
strConn = strConn & "DATABASE=Stratadial;"
strConn = strConn & "UID=xxxx;"
strConn = strConn & "PWD=xxxx;"
strConn = strConn & "TABLE=dbo.results_K20"

Set tbl = db.CreateTableDef(strTblName, _
dbAttachSavePWD, ("dbo.results_K20"), _
strConn)
db.TableDefs.Append tbl

CreateODBCLinkedTables = True
MsgBox "Refreshed ODBC Data Sources", vbInformation
CreateODBCLinkedTables_End:
Exit Function
CreateODBCLinkedTables_Err:
MsgBox Err.Description, vbCritical, "MyApp"
Resume CreateODBCLinkedTables_End
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Allerdings wenn ich die FUnktion ausführe, dann bekomme ich immer eine Fehlermeldung:

Code:

Das Datenbankmodul kann dbo.results_K20 nicht finden. Stellen Sie sicher, dass es sich um einen gültigen Parameter oder Alias-Namen handelt, der kein ungültigen Zeichn oder falsche Zeichensetzung enthält und dessen Name nicht zu lang ist.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Findet jemand von euch den Fehler?

Danke und Grüsse
Philip

:)

Anne Berg · 20. November 2008

Hallo Phil,
wie hast du dir das denn gedacht mit der Benutzerauswahl?

Meinst du nicht, du müsstest ein paar Parameter an die Funktion übergeben (nach Erweiterung derProzedur-Deklaration versteht sich!) wie z.B. den Tabellennamen, User-ID und Passwort?

So wie du uns das gezeigt hast, sind die Verbindungsparameter ja fest eingestellt. Das ist aber doch nicht das was du vorhast...

phil_discount · 20. November 2008

Hey Anne,

das wollte ich eigentlich danach machen, erstmal mit einer statischen Tabelle "dbo.results_K20" versuchen, danach ausbauen :-)

Aber wieso kann er nicht einmal die statische Tabelle verknüpfen?

Grüsse
Philip

Anne Berg · 20. November 2008

Hallo, wenn du dich erstmal herantasten willst, hättest du das mit dem Listenfeld auch weglassen können.

Aufgrund des Sonderzeichens in dem Tabellennamen würde ich es mal mit den allheilbringenden eckigen Klammern versuchen.

phil_discount · 20. November 2008

leider ohne Erfolg :-(
Grüsse
Philip

Anne Berg · 20. November 2008

Sei mal so nett und zeig uns, wie du das umgesetzt hast.

Dann erkläre doch bitte auch mal den Tabellennamen ("dbo.xxx")...
(ich fürchte das klingt nach ADP, wovon ich keine Ahnung habe!)

phil_discount · 20. November 2008

Guten Morgen,

ich habe die FEhler jetzt gefunden:

- zum einem war "dbo" bloß der Besitzer der Datenbank und gar nicht der Datenbankname, auch wenn es mir im "GUI" so angezeigt wurde.
- habe die FUnktion jetzt mit Übergabeparameter und variabel gestaltet und funktioniert zuverlässig

Code:

Function CreateODBCLinkedTables(campaign_name As String)
On Error GoTo CreateODBCLinkedTables_Err
Dim strTblName As String, strConn As String, strSrcTable As String
Dim db As Database, rs As Recordset, tbl As TableDef

'Vorhandene Tabelle löschen
UnlinkTable ("dialer_results")

' ---------------------------------------------
' Register ODBC database(s)
' ---------------------------------------------
Set db = CurrentDb
DBEngine.RegisterDatabase "Stratadial", "SQL Server", True, "Description=Production Data" & _
Chr(13) & "Server=192.168.203.20" & Chr(13) & "Database=Stratadial"
' ---------------------------------------------
' Link table
' ---------------------------------------------

strTblName = "dialer_results"
strSrcTable = "results_" & campaign_name
strConn = "ODBC;"
strConn = strConn & "DSN=sympatel_dialer;"
strConn = strConn & "APP=Microsoft Access;"
strConn = strConn & "DATABASE=Stratadial;"
strConn = strConn & "UID=xx;"
strConn = strConn & "PWD=xx;"
strConn = strConn & "TABLE=" & strSrcTable

Set tbl = db.CreateTableDef(strTblName, dbAttachSavePWD, strSrcTable, strConn)
db.TableDefs.Append tbl

CreateODBCLinkedTables_End:
Exit Function
CreateODBCLinkedTables_Err:
MsgBox Err.Description, vbCritical, "MyApp"
Resume CreateODBCLinkedTables_End
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Noch mal danke für die Hilfe!

Grüsse
Philip

Office: SQL Server Tabelle via ODBC und VBA verknüpfen

SQL Server Tabelle via ODBC und VBA verknüpfen

SQL Server Tabelle via ODBC und VBA verknüpfen

SQL Server Tabelle via ODBC und VBA verknüpfen

SQL Server Tabelle via ODBC und VBA verknüpfen - Similar Threads - SQL Server Tabelle

Access to SQL Server

Acces FrontEnd und MS SQL-Server als BackEnd

per suchfeld adressdaten aud sql datenbank einfügen

Backup SQL Server Datenbank VBA

Zugriff auf verknüpfte SQL Server Tabelle

Access Runtime mit SQL Server

Access erkennt die Identitätsspalte in einer verknüpften SQL Server-Tabelle nicht