Office: Stunden & Minuten zusammenrechnen

Moin zusammen,

ich bin neu hier und wende mich mit folgender Frage an euch:

Ich möchte bei Excel (2021) gerne Zeiten zusammenrechnen. Prinzipiell einfach, aber das Problem ist, dass die Stunden und Minuten in anderen Spalten stehen.

Wie schaff ich es, dass ich die Zahlen addieren kann, die Minuten nicht über 59 gehen und wenn diese durch 60 teilbar sind eine Stunde mehr in der Stundenspalte addiert wird.

Ich habe an eine Form der WENN-Formel gedacht, weiß aber nicht wie ich die Befehle/Bedingungen richtig eingebe, oder ist gibt eine noch einfacherer Möglichkeit.

Ich freue mich über eure Rückmeldungen

Grüße Max

 

=(J4&K4/60)/24 als Zeit formatieren

 

Hallo,

unter Excel2021 gibt es mehrere Möglichkeiten:

1) Man kann mit einer Formel eine Zwischensumme in einer Hilfszelle speichern, zB. Zelle I16:
=LET(h;$J$8:$J$14; m;$K$8:$K$14; SUMME(h+m/60)/24)
und dann dieses Zwischenresultat in die Zellen daneben umrechnen:
Zelle J16: =STUNDE(I16)
Zelle K16: =MINUTE(I16)

2) Man kann aber auch statt eines Zwischenresultates in I16 gleich mit einer Array-Formel in Zelle J16 arbeiten:
=LET(h;$J$8:$J$14; m;$K$8:$K$14;
d; SUMME(h+m/60)/24;
MTRANS(XMLFILTERN("<y><x>"&WECHSELN(TEXT(d;"hh:mm");":";"</x><x>")&"</x></y>";"//x")))

Aber so richtig bequem ist das nicht. Das geht erst mit Excel365 bzw. WEB-Excel:
3a) mit Funktion HSTAPELN():
=LET(h;$J$8:$J$14; m;$K$8:$K$14;
d; SUMME(h+m/60);
HSTAPELN(GANZZAHL(d);REST(d;1)*60))

3b) bzw. in Anlehnung an Punkt 1) oder 2):
=LET(h;$J$8:$J$14; m;$K$8:$K$14;
d; SUMME(h+m/60)/24;
HSTAPELN(STUNDE(d);MINUTE(d)))

 

Vielen Dank für die schnellen Antworten.

Leider hatte ich noch nicht die Zeit die Formeln auszuprobieren, werde aber eine Rückmeldung geben wenn ich dies getan habe.

 

Oder die Minuten zusammenzählen und per Ganzzahldivision die Stunden und Minuten daraus errechnen.
Summe Stunden =QUOTIENT(SUMME($J$4:$J$10)*60+SUMME($K$4:$K$10);60)
Summe Minuten =REST(SUMME($J$4:$J$10)*60+SUMME($K$4:$K$10);60)

 

Moin Max,

man könnte natürlich auch noch den direkten Excel-Weg gehen: Indem man Stunden und Minuten nicht mehr getrennt eingibt, sondern einfach im XL-Format. Dann kann man mit den Werten beliebig rechnen.

Als kleiner Tipp: die aktuelle Zeit man mit Strg + : (Doppelpunkt) Minuten-genau in die Tabelle zaubern.

Grüße