Office: Such-Formular mit Ausgabe als Bericht

Hallo,

ich verzweifele gerade an der Erstellung eines Such-Formulars. Ich finde viel über die SuFu, aber leider nicht genau das, was ich suche

Ich beschreib mein Problem mal ganz detailiert:

Eine Tabelle mit 2 Spalten –Eine mit dem Namen, die Andere ein Memofeld mit Text.
Ich möchte ein Formular erstellen, wo man in einer Textbox das Wort eingeben kann, nach dem Spalte 2 durchsucht werden soll (mit Sternchen und Leerzeichen).
Die Ausgabe soll ein tabellarischer Bericht sein, in dem alle Namen und die jeweils dazugehörigen Texte aus Spalte 2 aufgelistet sind.
Kann mir jemand bitte Hilfestellung geben, wie ich das machen soll (über eine Abfrage?) und einen entsprechenden Code programmieren?
Bin leider noch ziemlich unbeholfen mit Access..

Vielen Dank im Voraus!

Gruß
Mad

 

Ich hab mir das mal angeguckt... Neue Datenbank, Tabelle erstellt:

Code:

tbl_Eintrag:
EintragID   Auto/Zufall (primary)
EintragName   Text (50)
EintragBemerkung   Memo

Darauf eine Abfrage, jedes Feld einzeln aufgeführt, nach "EintragName" aufsteigend sortiert.

Dann hab ich mal 8 Beispiel-Datensätze eingetippert. Bei 4en kommt das Wort "test", bei den anderen 4 das Wort "versuch", innerhalb des Memo-Felds vor - Am Anfang, am Ende, in der Mitte und als zusammengesetztes Wort (z.B. "testweise").

Die Query gibt mir die 8 Datensätze aus, also hab ich dann eine Kopie der Query erstellt und bei "Kriterien" im Feld "EintragBemerkung" mal eingegeben:

Code:

wie "*test*"

Siehe da, es werden nur noch die 4 passenden Datensätze der Query ausgegeben. Und im SQL-Code der Query steht:

Code:

SELECT tbl_Eintrag.EintragId, tbl_Eintrag.EintragName, tbl_Eintrag.EintragBemerkung
FROM tbl_Eintrag
WHERE (((tbl_Eintrag.EintragBemerkung) Like "*test*"))
ORDER BY tbl_Eintrag.EintragName;

Das sieht Access-üblich etwas unübersichtlich aus und läßt sich noch prima zusammenstauchen:

Code:

SELECT
  EintragId, EintragName, EintragBemerkung
FROM
  tbl_Eintrag
WHERE
  EintragBemerkung LIKE "*test*"
ORDER BY
  EintragName
;

Deine Suchmaske muß also z.B. auf Button-Klick nichts weiter machen, als obigen SQL-Code zusammenzubauen und als Datenquelle für den Bericht einzusetzen. Oder noch einfacher:

Wenn Du nur die Zeile

Code:

  EintragBemerkung LIKE "*test*"

per Parameter an den Bericht übergibst, filtert der Bericht das ganz von alleine für Dich.

Wenn Du per Wizard einen Button erstellst, mit dem ein Bericht in der Seitenvorschau geöffnet werden soll, dann erzeugt das ca. folgenden Code:

Code:

Private Sub btn_Berichtsvorschau_Eintrag_Click()
On Error GoTo Err_btn_Berichtsvorschau_Eintrag_Click

    Dim stDocName As String

    stDocName = "rpt_Eintrag"
    DoCmd.OpenReport stDocName, acPreview

Exit_btn_Berichtsvorschau_Eintrag_Click:
    Exit Sub

Err_btn_Berichtsvorschau_Eintrag_Click:
    MsgBox Err.Description
    Resume Exit_btn_Berichtsvorschau_Eintrag_Click
    
End Sub

Und die "OpenReport"-Zeile ist der springende Punkt. Dort kann man auch noch den Filter unterbringen:

Code:

    DoCmd.OpenReport stDocName, acPreview, , stWhereCondition

Noch schnell die Deklaration oben dazupacken:

Code:

    Dim stWhereCondition As String

Und sich dann Gedanken machen, wie man das Ding sinnvollerweise gefült bekommt. Das grobe Gerüst steht:

Code:

    stWhereCondition = "EintragBemerkung LIKE ""*[suchtext]*"""

Jetzt muß nur noch "[suchtext]" mit dem tatsächlich gesuchten Text ersetzt werden. Und das holen wir uns aus dem Feld "edt_Filter_Eintrag", was ein Textfeld auf dem Formular mit dem Button ist.

Code:

    stWhereCondition = Replace(stWhereCondition, "[suchtext]", Trim$(Me!edt_Filter_Eintrag.Value & " "), 1, -1, vbTextCompare)

Und das ganze sieht dann so aus:

Code:

Private Sub btn_Berichtsvorschau_Eintrag_Click()
On Error GoTo Err_btn_Berichtsvorschau_Eintrag_Click

    Dim stDocName As String
    Dim stWhereCondition As String

    stDocName = "rpt_Eintrag"
    stWhereCondition = "EintragBemerkung LIKE ""*[suchtext]*"""
    stWhereCondition = Replace(stWhereCondition, "[suchtext]", Trim$(Me!edt_Filter_Eintrag.Value & " "), 1, -1, vbTextCompare)
    DoCmd.OpenReport stDocName, acPreview, , stWhereCondition

Exit_btn_Berichtsvorschau_Eintrag_Click:
    Exit Sub

Err_btn_Berichtsvorschau_Eintrag_Click:
    MsgBox Err.Description
    Resume Exit_btn_Berichtsvorschau_Eintrag_Click
    
End Sub

Gruß, Michael

 

Hallo Miriki,

Vielen, vielen Dank für deine Antwort -Das ist ja mal echt der Hammer!!!
Nicht nur, dass du das Ding schon komplett fertig gemacht hast und als Download zur Verfügung stellst -Du gibst hier gleich noch mal ne Lehrstunde...
Ich hab es mir schon einige Male durchgelesen, aber werd es noch ein paar mal machen, bis ich wirklich alles verstanden habe.
So macht das natürlich richtig spaß hier :mrgreen: :mrgreen: :mrgreen:

Beste Grüße
Mad

 

Das ist bei Fragen zu Access fast unvermeidlich. Während man für Excel Fragen nach Formeln oft noch "aus'm Kopp" beantworten kann, führt es bei Access fast unweigerlich zum Nachbauen des Problems, um die Lösung zu finden.

Code:

 -Du gibst hier gleich noch mal ne Lehrstunde...

Das ist mir meist eigentlich wichtiger, als nur die Antwort selbst zu geben. Es geht so in Richtung "Hilfe zur Selbsthilfe". Ich find's schon wichtig, daß man auch versteht, warum und wie man das macht, um in einer ähnlichen Situation nicht wieder "vor der Wand" zu stehen.

Freut mich auf alle Fälle, wenn ich helfen konnte und Du weiter kommst.

Gruß, Michael