Office: Suchfilter über mehrere Tabellenbläter

Hallo und Happy New Year euch allen.
Unsere HR Fachfrau möchte eine Suchfunktion, die ihr nach Eingabe eines Mitarbeiters alle Besuchte Kurse dieses Mitarbeiters aller Jahre anzeigt. Ich habe schon diverse Ansätze überlegt wie Filter oder Pivot Table. Leider funktioniert alles nicht so wie es sollte.
Der Wunsch wäre ein Suchfeld mit Drop Down für den Namen des MA`s und dann werden alle Kurse mit einem x dieses Ma`s aller Jahre aufgelistet. Habt ihr eine mögliche Lösung dafür?
Beispieldatei hänge ich an..
Gruss Jürg

 

Hallo Jürg,

http://excel-inn.de/dateien/vba_beispiele/autofilterbereich_dynamische_anpassung.zip

 

Hallo Hajo
Danke für den Link. Dieser wäre aber nur über eine Tabelle. Wie du in der Beispieldatei siehst müsste es über alle Tabellen filtern und nur wenn der entsprechende Namen auch vorhanden ist..

 

Hi,

gibt es auch Fälle, dass ein MA mehrere Kurse im selben Jahr besucht hat oder ist es immer nur ein einziger pro Jahr?

---

 

Ja das gibt es.. seht ihr meine Beispieldatei? (Ist eigentlich die Originaldatei )

 

Klar sehen wir die Datei, aber wer hat schon die Zeit zu prüfen, in welchen Spalten bei welchem Namen ein "x" steht - das weißt du als Ersteller doch wesentlich besser und vor allem schneller...

Noch ein Tipp: Originaldaten sollte man aus Datenschutzgründen nicht hochladen - es gibt Möglichkeiten, Daten zu anonymisieren.

---

 

Kennst du dich ein wenig mit VBA aus? Mache einen Rechtsklick auf das Tabellenblatt "Kriterien", wo sich in A2 die Gültigkeitszelle zur Auswahl befindet. Kopiere dann folgenden Code ins rechte (obere) Codefenster. Sobald in A2 ein Name ausgewählt wird, werden die Einträge zu bem betreffenden Namen aus Zeile 1 jedes Tabellenblattes aufgelistet:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim wksTab As Worksheet
    Dim rngName As Range
    Dim rngX As Range
    Dim lngZeile As Long
    Dim intSpalte As Integer
    Dim strStartN As String
    Dim strStartX As String
    Dim strVorname As String
    Dim strNachname As String
    Dim lngLetzte As Long
    lngZeile = 2
    If Target.Cells(1).Address = "$A$2" And Target.Cells(1) <> "" Then
        lngLetzte = Columns("B:E").Find(What:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        Range(Cells(2, 2), Cells(lngLetzte, 5)).ClearContents
        strNachname = Left(Target, InStr(Target, " ") - 1)
        strVorname = Trim(Mid(Target, InStr(Target, " ") + 1))
        For Each wksTab In Worksheets
            If IsNumeric(wksTab.Name) Then
                With wksTab
                    Set rngName = .Columns(1).Find(strNachname, lookat:=xlPart, LookIn:=xlValues)
                    If Not rngName Is Nothing Then
                        strStartN = rngName.Address
                        Do
                            If rngName.Offset(0, 1) = strVorname Then
                                If Application.CountIf(.Range(.Cells(rngName.Row, 3), .Cells(rngName.Row, 13)), "x") > 0 Then
                                    Application.EnableEvents = False
                                    For intSpalte = 3 To 12
                                        If .Cells(rngName.Row, intSpalte) = "x" Then
                                            Cells(lngZeile, 3) = .Cells(1, intSpalte)
                                            Cells(lngZeile, 5) = "x"
                                            lngZeile = lngZeile + 1
                                        End If
                                    Next intSpalte
                                    Application.EnableEvents = True
                                End If
                            End If
                            Set rngName = .Columns(1).FindNext(rngName)
                        Loop While rngName.Address <> strStartN
                    End If
                End With
            End If
        Next wksTab
    End If
End Sub

Leider kann man den Namen des Lehrgangs und das Datum in dieser Datei nicht voneinander trennen, da es kein Kriterium zur Trennung gibt, welches man problemlos dafür verwenden könnte. Würde z.B. anstelle der mehrfachen Leerzeichen ein tatsächlicher Zeilenumbruch (Alt+Enter) in der Zelle verwendet, könnte man diese Kriterium verwenden.

Beachte bitte auch folgendes unbedingt: die Namen in den Jahres-Übersichten (Spalten A und B) müssten absolut identisch mit den Namen in der Liste sein, denn andernfalls können sie nicht gefunden werden.

Noch ein Hinweis am Ende: vergiss nicht, die Datei als "Excel-Arbeitsmappe mit Makros" (Typ xlsm) abzuspeichern.

---

 

Beachte
Regeln
Punkte 2.3 zu Crossposting.

 

Super Danke Beverly. Ja ich kenne mich etwas aus mit VBA. Danke für deine Arbeit und Vorschlag. Werde es Testen und eine Rückmeldung geben ( gerade nicht im Büro) Den Tipp mit dem Zeilenumbruch werde ich auch ausprobieren. Ich denke ich werde die Namen (Vor/Nachnamen) zusammenführen und mittels Dropdown eine Auswahl ermöglichen. So ist sichergestellt das der Name immer richtig geschrieben ist.
@Hajo: Was meinst du mit Crossposting? Ich habe diese Frage in keinem anderen Forum gestellt. Eine andere Fragen schon aber die ist zu einem ganz anderen Thema. Kenne diese Regel - (und sonst mit Verweis zum anderen Forum).
Lieber Gruss und herzlichen Dank für eure Unterstützung
Jürg

 

Beverly, ich habe es mit deinem Code ausprobiert und es funktioniert einwandfrei! Herzlichen Dank!