Office: (Office 365) Suchfunktion in Listbox

Auf die Userform Material gehen.
Programm starten
Dann kommt direkt die Fehlermeldung

 

Es ist schon lange her, dass ich mich mit dem Füllen von mehr als 10 Spalten in einer ListBox beschäftigt habe und mein Wissen war etwas eingerostet - Fazit: wenn man eine ListBox mittels RowSource füllt, dann spielt die Spaltenanzahl keine Rolle, mittels AddItem kann man nur 10 Spalten füllen. Jetzt kommt jedoch ein ABER, welches ich sozusagen in Erinnerung hatte und was mich zu meiner fehlerhaften Äußerung veranlasst hat: man kann stattdessen ein Array mit mehr als 10 Spalten benutzen, in das man die Daten aus dem Tabellenblatt einliest und dieses Array dann der List-Eigenschaft der ListBox zuweisen. Damit wäre das eigentliche Problem nun geklärt.

Nun zu deinem konkreten Beispiel: du füllst doch 2 getrennte ListBoxen mit quasi demselben Code in 2 getrennten Prozeduren - das kann man zusammenfassen, indem man zuerst eben das Array füllt und dieses dann beiden ListBoxen zuweist. Das geht mit folgendem Code:

Code:

Private Sub UserForm_Activate()
    Call listboxfuellen
End Sub

Private Sub listboxfuellen()
    'beide ListBoxen füllen
    Dim lngZeile As Long
    Dim arrDaten()
    lngZeile = 2
    Do Until Tabelle6.Cells(lngZeile, 1) = ""
        ReDim Preserve arrDaten(10, 0 To lngZeile - 2)
        arrDaten(0, lngZeile - 2) = Tabelle6.Cells(lngZeile, 1)
        arrDaten(1, lngZeile - 2) = Tabelle6.Cells(lngZeile, 2)
        arrDaten(2, lngZeile - 2) = Tabelle6.Cells(lngZeile, 3)
        arrDaten(3, lngZeile - 2) = Tabelle6.Cells(lngZeile, 4)
        arrDaten(4, lngZeile - 2) = Tabelle6.Cells(lngZeile, 5)
        arrDaten(5, lngZeile - 2) = Tabelle6.Cells(lngZeile, 6)
        arrDaten(6, lngZeile - 2) = Tabelle6.Cells(lngZeile, 7)
        arrDaten(7, lngZeile - 2) = Tabelle6.Cells(lngZeile, 8)
        arrDaten(8, lngZeile - 2) = Tabelle6.Cells(lngZeile, 11)
        arrDaten(9, lngZeile - 2) = Tabelle6.Cells(lngZeile, 12)
        arrDaten(10, lngZeile - 2) = lngZeile
        lngZeile = lngZeile + 1
    Loop
    With Me.lstMaterial
        .ColumnCount = 11
        .ColumnWidths = "80;80;80;80;80;80;80;80;80;80;0"
        .Font.Size = 12
        .List = Application.Transpose(arrDaten())
        'erstes Element auswählen
        .Selected(0) = True
    End With
    With Me.lstMaterialBuchen
        .ColumnCount = 11
        .ColumnWidths = "80;80;80;80;80;80;80;80;80;80;0"
        .Font.Size = 12
        .List = Application.Transpose(arrDaten())
        'erstes Element auswählen
        .Selected(0) = True
    End With
End Sub

Die Private Sub listboxfuellenBuchen() kannst du folglich löschen.

Übrigens war bei dir die Zuweisung der Spaltenbreiten falsch geschrieben, sodass dort schon ein Laufzeitfehler ausgelöst wurde - das habe ich korrigiert.

---

 

Vielen dank jetzt funktioniert es :))))

 

Hallo Karin,
weiß nicht wirklich wie ich auf die Zeile im Tabellenblatt durch die zusätzliche Spalte der laufenden Zeile zugreife.
Die Suchfunktion soll ja Dynamisch bleiben.

 

Hi Christian,

mit folgendem Beispielcode kannst du auf die Spalte 11 der ListBox zugreifen und somit die Zeilennummer heraus bekommen:

Code:

CLng(lstMaterial.List(lstMaterial.ListIndex, 10))

---