Office: (Office 2007) Summe fortsetzen

Hallo,

ich habe eine Frage zum "runterziehen" der Summenfunktion:
Ich habe einen großen Datensatz und würde diese Daten gerne in Paketen von 95 Zellen aufsummieren. Das heißt die erste Summe sollte die Zellen A2-A97 enthalten, die nächste Summe die Zellen A98-A193, die nächste A194-A289 usw.
Wenn ich jetzt die erste Summe bilde, und diese dann "runterziehe" bildet Excel mir klarerweise die Summe A3-A98. Wie kann ich Excel also sagen, dass beim Runterziehen der Summenformel die nächste Zelle nach der letzten Zelle der vorigen Summe als erste Zelle verwendet werden soll?

Ich hoffe ich habe mein Problem verständlich ausgedrückt *wink.gif*
Über Tipps oder auch andere Lösungsvorschläge würde ich mich freuen!

lg

:)

 

hmm sehe es als schwierig an, da es wahrscheinlich nicht übersichtlich wird

versuch doch die zu summierenden Zellen untereinander zu bekommen.
a1:a97 -> A98=Summe(A1:A97)
B1:B97 -> B98=Summe(B1:B98)

weil dann könntest du A98 nach rechts ziehen

vielleicht gibt es bessere lösungen weiss ich nicht
könntest ja noch auf andere vorschläge warten

 

oder

B2:B97 =Summe(A2:A97) in die zelle eingeben
Anschliessend mit strg+shift(gross) bestätigen

sieht dann so aus

{=Summe(A2:A97}

diese zelle musst du anfangs 1malig bis a97 kopieren und prüfen ob diese gleich bleibt also b2:b97 muss stehen
{=Summe(A2:A97}

anschliessend markierst du B2-B97 komplett und kannst dann einfach den kompletten block herunter ziehen bis zum ende des Arbeitsblattes
So sollte dann in B98 folgendes stehen {=Summe(A98:A193)}

dann steht in b die summe aus den jeweiligen 95 benötigten zellen

bitte kontrollier die formel vorab in den jeweiligen "95er" blöcken bevor es einen fehler gibt


anders scheint es sonst nicht möglich zu sein

 

Hallo!
Es sind jeweils 96 Zeilen!
Um den Zeilenbezug zu dynamisieren, musst Du zunächst mit der Funktion Zeile arbeiten.
Die Zahlenreihe 2, 98, 194, 290 erhältst Du mit: =ZEILE(A1)*95+ZEILE(A1)+1-95
97, 193, 289, 385 mit: =ZEILE(A1)*95+ZEILE(A1)+1

*	A	B
2	2	97
3	98	193
4	194	289
5	290	385

Zelle	Formel
A2	=ZEILE(A1)*95+ZEILE(A1)+1-95
B2	=ZEILE(A1)*95+ZEILE(A1)+1

Um die Summe zu dynamisieren, nutzt Du die Funktion Index iVm Summe:
=SUMME(INDEX(A:A;ZEILE(A1)*95+ZEILE(A1)+1-95):INDEX(A:A;ZEILE(A1)*95+ZEILE(A1)+1))

*	A	B	C	D
1	Werte:	*	*	*
2	1	96	2	97
3	1	97	98	193
4	1	100	194	289
5	1	*	290	385

Zelle	Formel
B2	=SUMME(INDEX(A:A;ZEILE(A1)*95+ZEILE(A1)+1-95):INDEX(A:A;ZEILE(A1)*95+ZEILE(A1)+1))
C2	=ZEILE(A1)*95+ZEILE(A1)+1-95
D2	=ZEILE(A1)*95+ZEILE(A1)+1

Die Formeln lassen sich alle nach unten ziehen.

Gruß Ralf

 

Hallo Ralf, erst findest Du korrekt die 96 statt 95, dann aber bleibst Du auf halbem Wege stecken *wink.gif* :

=SUMME(INDEX(A:A;ZEILE(A1)*96-94):INDEX(A:A;ZEILE(A1)*96+1))

 

Hi lupo1!
Weiter im Änderungsmodus:
Jetzt liefern unsere Formeln das gleiche Ergebnis (wobei Deine kürzer und leichter nachvollziehbar sind):

*	C	D	E	F
1	RPP	lupo	RPP	lupo
2	2	2	97	97
3	98	98	193	193
4	194	194	289	289
5	290	290	385	385

Zelle	Formel
C2	=ZEILE(A1)*95+ZEILE(A2)-95
D2	=ZEILE(A1)*96-94
E2	=ZEILE(A1)*95+ZEILE(A2)
F2	=ZEILE(A1)*96+1

Gruß Ralf

 

Es ist bei linearem Versatz pro Bereichsankerung IMMER nur eine Variable ZEILE(A1) nötig. Sie entspricht dem x in y=mx+n. m und n sind konstant.

 

Nun, eine simple Auflösung des Gleichungssystems hätte mich ja auch auf die Verkürzung bringen können ...
Aus meinem ersten Lösungsansatz:

y1=ZEILE(A1)*95+ZEILE(A1)+1-95
y1=ZEILE(A1)*95+ZEILE(A1)-94
y1=ZEILE(A1)*96-94

y2=ZEILE(A1)*95+ZEILE(A1)+1
y2=ZEILE(A1)*96+1

*cool.gif*