Office: Summenprodukt mit Abhängigkeit in VBA

Hallo Zusammen,
bin leider bei den vorhandenen Beiträgen nicht fündig geworden.
Als Summenprodukt pro Zeile bekomme ich das hin, aber nicht in VBA.

Dies ist nur ein Auszug zur Verdeutlichung. Es handelt um über 50.000 Datenzeilen.
Habe in VBA diese Zeile eingegeben (später erfolgt dies über Variablen), aber es wird immer ein Fehler angezeigt. Ich mache hier also mehr als nur etwas falsch. Bin aber auch nur normaler Excel User. Vielleicht kann jemand helfen.
Dirk

 

bespielhaft
(A2:A8=F3)*(B2:B8)*(C2:C8)

 

hab noch ein bissel rumprobiert

Code:

Sub Makro1()

Dim i&

With ActiveSheet
i = 2
Do While .Cells(i, "F") <> ""
    
       .Cells(i, "G").Formula = "=SumProduct((" _
                            & .Range("A2:A8").Address & "=" & .Cells(i, "G").Offset(0, -1).Value _
                            & ")*1,(" _
                            & .Range("B2:B8").Address _
                            & "),(" _
                            & .Range("C2:C8").Address _
                            & "))"
      With .Cells(i, "G")
         .Value = .Value
      End With
  i = i + 1
 Loop
End With
End Sub

 

Vielen Dank. Manchmal ist die Lösung ganz einfach.

 

hinterher sieht es meistens "einfach" aus. Das sehen dann auch nur Diejenigen so, die sich die Lösung nicht erarbeitet haben.

 

Hi,

vorweg: ich habe nichts getestet, weil ich es nicht einsehe ein Bild abzutippen...

Wenn ich mir den Code aber so anschaue, dann Frage ich mich, wo der Unterschied von
.Range("A2:A8").Address zu "$A$2:$A$8" oder in diesem Fall sogar zu "A2:A8" sein soll.
Und genauso frage ich mich, was der Mehrwert von .Cells(i, "G").Offset(0, -1).Value im Vergleich zu .Cella(i, "F").Value ist.
Daher würde das Makro oben auch so aussehen können:

Code:

Sub Makro1()
Dim i&
With ActiveSheet
    i = 2
    Do While .Cells(i, "F") <> ""
        .Cells(i, "G").Formula = "=SumProduct((A2:A8=" _
                           & .Cells(i, "F").Value _
                           & ")*1,(B2:B8),(C2:C8))"
        With .Cells(i, "G")
            .Value = .Value
         End With
        i = i + 1
    Loop
End With
End Sub

Wobei ich das ohne Schleife machen würde:

Code:

Sub Makro1()
With Range(Cells(2, "G"), Cells(2, "F").End(xlDown).Offset(0, 1))
    .Formula = "=SUMPRODUCT(($A$2:$A$8=$F2)*1,($B$2:$B$8),($C$2:$C$8))"
    .Value = .Value
End With
End Sub

Das funktioniert, weil VBA die Formeln genauso anpasst, wie wenn man sie mit Copy&Paste in Excel kopieren würde. Falls einem das nicht geheuer ist, kann man auch .FormulaR1C1 benutzen:
.FormulaR1C1 = "=SUMPRODUCT((R2C1:R8C1=RC6)*1,(R2C2:R8C2),(R2C3:R8C3))"
bzw. wenn man nicht Spalte 6 ("F"), sondern die Spalte links der Zelle haben will:
.FormulaR1C1 = "=SUMPRODUCT((R2C1:R8C1=RC[-1])*1,(R2C2:R8C2),(R2C3:R8C3))"

Allerdings frage ich mich schon die ganze Zeit, wozu man so etwas unbedingt per VBA machen muss?