Office: SUMMENPRODUKT

Hallo zusammen

habe folgendes Problem: in unten stehender Tabelle soll die Anzahl B5:B12 dann addiert werden, wenn eine beliebige oder mehrere Bedingung in Spalte R/S/T/U erfüllt ist.
(Jetzt müssen alle Bedingungen zutreffen!)


=SUMMENPRODUKT(($B$5:$B$12="II.Quartal 2009")*($R$5:$R$12>0)*($S$5:$S$12>0)*($T$5:$T$12>0)*($U$5:$U$12>0))/ZÄHLENWENN($B$5:$B$12;"II.Quartal 2009")

Bitte um Hilfe. Vielen Dank!!

Gruß Andi

 

Hallo,

SUMMENPRODUKT ist hier m.E. etwas dämlitsch. Richte Dir ne Hilfsspalte ein, wo die Abfrage rein kann, ob eine Deiner Bedingungen erfüllt ist.
z.B.
=ZÄHLENWENN(R5:U5;">0")

Und dann kann SUMMENPRODUKT bzw. SUMMEWENN angewendet werden.

 

Hallo Silex 1

Vielen Dank für den Tipp.

Vielleicht gibt es noch eine einfachere Lösung?

Gruß Andi

 

Hallo!

=SUMMENPRODUKT(($B$5:$B$12="II.Quartal 2009")*(($R$5:$R$12>0)+($S$5:$S$12>0)+($T$5:$T$12>0)+($U$5:$U$12>0)>0))/ZÄHLENWENN($B$5:$B$12;"II.Quartal 2009")

 

Hallo Schatzi

Die Lösung ist ja einfach!!

Kapieren tue ich sie aber nicht!

Danke für Deine Hilfe!!

Gruß Andi :-D

 

Hallo!

Eine Multiplikation steht für das logische UND,
eine Addition steht für das logische ODER.
Ist also irgendein Wert (z.B. S7) in den Spalten R:U größer Null, so ergibt der entsprechende Teil WAHR (bzw. 1):

($R$5:$R$12>0)+($S$5:$S$12>0)+($T$5:$T$12>0)+($U$5:$U$12>0)>0
FALSCH+WAHR+FALSCH+FALSCH>0
0+1+0+0>0
1>0
WAHR

 

Sehr gut mein Schatzi

Ich habe kapiert!

Vielen Dank und Gruß Andi