Office: Summenprodukt ??

Hallo,

Habe da folgendes Problem, bezogen auf beigefügte Datei:
Möchte die Anzahl der soliden Veränderungen aufgeführt haben,
welche entweder unter Histo EUS "Adeno" oder unter Histo Sono als "Adeno" oder aber unter Histo EUS und Histo Adeno als "Adeno" aufgeführt werden.

Das ergebnis müßte also 3 sein,
die Formel bringt mir leider nicht das gewünschte Ergebnis:
=SUMMENPRODUKT((D1:D8="solide"); WENN(ODER(C1:C8="Adeno");(B1:B8="Adeno"))).

Wie muß sie richtig lauten?

 

Hallo,

wenn 4 als Ergebnis stimmt, dann so:

=SUMMENPRODUKT((D1:D8="solide")*(B1:C8="Adeno"))

hab allerdings nicht richtig verstanden, was Du haben möchtest!

 

Vielen Dank für die prompte Anwort, möchte aber meine Frage noch etwas näher erläutern:

Ich möchte die Anzahl der soliden Veränderungen in D1:D6 wissen, wenn in B oder C Adeno aufgeführt wird. Wenn in B und C gleichzeitig in einer Zeile Adeno und in D solide steht, soll dies als 1 gewertet werden.

Es sollte bei dem Beispiel also die Zahl 3 heraukommen. Und wie lautet die Formel, wenn die Angaben in Spalte B und C nicht in nebeneinanderliegende Spalten vorliegen, also Beispiel in Spalte A und C vorgegeben sind ? javascript:emoticon(':-?')

Gruß
R. H.

 

Hi,

=SUMMENPRODUKT((D2:D8="solide")*(ODER(B2:B8="Adeno";C2:C8="Adebo")))

Bis später,
Karin

 

Hallo Karin,

das funktioniert so nicht!! Eine Oder-Verknüpfung bei Summenprodukt sähe so aus:

Code:

(($C$2:$C$8="Adeno")+($B$2:$B$8="Adeno"))

Allerdings passt das hier auch nicht, da dann beide Wert addiert werden.
Siehe Beispiel Zyste. Deine Formel zählt einfach alle Zeilen, bei denen die Vorgabe der Spalte D erfüllt ist, statt (ODER(....)) hätte man auch 1 schreiben können.
So geht´s:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Geschlecht	Histo EUS	Histo Sono	Morphe
2		Adeno	Adeno	solide	3
3		Adeno		solide	4
4				zystisch	2
5			Adeno	solide	4
6		Zyste	Zyste	zystisch	3
7				zystisch
8			Zyste	zystisch
9				solide

Zelle	Formel
E2	=SUMMENPRODUKT(($D$2:$D$9="solide")*(($C$2:$C$9="Adeno")+($B$2:$B$9="Adeno")>0))
E3	=SUMMENPRODUKT(($D$2:$D$9="solide")*(ODER($B$2:$B$9="Adeno";$C$2:$C$9="Adeno")))
E4	=SUMMENPRODUKT(($D$2:$D$9="zystisch")*(($C$2:$C$9="Zyste")+($B$2:$B$9="Zyste")>0))
E5	=SUMMENPRODUKT(($D$2:$D$9="zystisch")*(ODER($B$2:$B$9="Zyste";$C$2:$C$9="Zyste")))
E6	=SUMMENPRODUKT(($D$2:$D$9="zystisch")*(($B$2:$B$9="Zyste")+($C$2:$C$9="Zyste")))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]
Gruß

Edgar

 

hi, ich hätte auch einen, obwohl zu spät und wahrscheinlich zu umständlich..:

Arbeitsblatt mit dem Namen 'Tabelle1 (5)'
	A	B	C	D	E	F	G
1	Histo EUS	Geschlecht	Histo Sono	Morphe
2	Adeno		Adeno	solide			4
3	Adeno			solide			3
4	Zyste			zystisch
5			Adeno	solide
6	Zyste		Zyste	solide
7	Adeno			zystisch
8

Zelle	Formel
G2	=SUMMENPRODUKT((D2:D8="solide")*(ODER(A2:A8="Adeno";C2:C8="Adeno")))
G3	=SUMMENPRODUKT(N((ZÄHLENWENN(BEREICH.VERSCHIEBEN(A1:C1;ZEILE(1:100););"Adeno")>0))*(D2:D101="solide"))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

Hallo,

na hier is ja was los, hät da auch noch einen! :-D

=SUMMENPRODUKT((D1:D8="solide")*(ISTZAHL(SUCHEN("adeno";C1:C8&B1:B8))))

 

Vielen Dank Euch allen.

Hat mir sehr geholfen.

Gruß
R. H.