Office: (Office 2007) Summenprodukt...

Hi,

ich habe folgende Formel in der ich versuche eine Summe in Spalte P zu bilden.
Diese Summe ist zum Schluss aber größer, als wie sie eigentlich ist. Das liegt vermutlich daran, dass die Formel die Zahlen nicht ausschließt, sondern diese teilweise doppelt zählt.
Wie kann ich das umgehen? Evtl. noch "Summewenns" oder ähnliches mit einbinden?
Wenn ihr noch nähere Infos braucht, füge ich die morgen gerne noch bei.

=SUMMENPRODUKT(((MONAT('[Juli 16.xlsx]Tabelle1'!$AY$2:$AY$6263)=MONAT($A14))*(JAHR('[Juli 16.xlsx]Tabelle1'!$AY$2:$AY$6263)=JAHR($A14))*('[Juli 16.xlsx]Tabelle1'!$AK$2:$AK$6263=$L$4))*('[Juli 16.xlsx]Tabelle1'!$P$2:$P$6263))

Vielen Dank schonmal :)

Gruß Robin

 

Hola,

ausgeschlossen wird in der Formel gar nichts.
Eine Beispieldatei die das Problem zeigt wäre hilfreich.
Natürlich mit deiner Formel und der Angabe, was du als Ergebnis erwartest.

Gruß,
steve1da

 

Moin,

mir ist schon klar das dort nichts ausgeschlossen wird ;)
Genau das ist ja eigentlich die Frage.
Hier die Beschreibung zum Bild:

Ich habe ein Wasserfallmodel wo die Monate, in der die Rechnung kommt, in Zeile 4 stehen. (Für jeden Monat habe ich eine extra "Tabelle1", daher unrelevant)
In Spalte B für welchen Monat die Rechnung ist.
In Spalte D soll dann die Formel mit der Lösung stehen.
Da ich mehrere Projekte und Nummern habe, muss ich zusätzlich zum Datum, auch nach diesen beiden Kriterien auswählen.
Die Zahlen in Spalte B sind natürlich als Datum formatiert.

 

Hallo,


ein Bild ist Mist, man sieht weder die Formel, noch kann man die Daten überprüfen. Außerdem fehlt die Spalte AK! Nach Deinem Bild müsste das Ergebnis deutlich höher ausfallen!

Für Deinen Fall sollte diese Formel reichen:

Code:

=SUMMENPRODUKT((TEXT('[Juli 16.xlsx]Tabelle1'!$AY$2:$AY$6263;"MMJJ")=TEXT($A14;"MMJJ"))*('[Juli 16.xlsx]Tabelle1'!$AK$2:$AK$6263=$L$4)*('[Juli 16.xlsx]Tabelle1'!$P$2:$P$6263))

 

Ja sorry, hab keinen Möglichkeit gefunden eine Datei anzuhängen, nur halt eine Grafik.
Die Datei habe ich eben extra für das Forum jetzt hier entworfen, die Formel passt somit nicht dazu.
Aber vom Prinzip ist es das Gleiche.
Ich werd die Formel aber gleich mal ausprobieren, meld mich dann nochmal.
Vielen Dank schonmal für die schnell Hilfe.

 

Hola,

neben "Antworten" gibt es "Erweitert". Dort kann man Anhänge hochladen.

Gruß,
steve1da

 

Aaach daaaaa :)
Okay, das nächste Mal dann mit Anhang.

Aber ich glaube dieses Problem hat sich scheinbar schon erledigt.
Auf die Idee, den Monat und das Jahr in einem Array zu vergleichen bin ich noch gar nicht gekommen.
Vermutlich hatte Excel dort die doppelten Datensätze hergeholt.

Vielen Dank nochmal und bis bald vielleicht mal... ;)

 

Moin,

ich hab zu diesem Thema noch eine kleine Ergänzungsfrage.

In Zelle "E5" und "H5" sollen jetzt nur die Summen aus dem Reiter "Daten" summiert werden, wo die zugehörige Aktion mit der Bezeichnung passt.
Siehe "D4", bzw. "G4" und die entsprechende Hilfstabelle ab "J11:K21"

Die relevanten Felder habe ich gelb markiert.

Den Anhang Test.xlsx betrachten

Gruß RobbiRob

 

Hola,

mach in "Daten" eine Hilfsspalte, z.B. in H2:H25. Dort ermittelst du per Sverweis das Unterprojekt:

Code:

=WENNFEHLER(SVERWEIS(A2;'Auswertung nach Monat'!$J$12:$N$21;2;0);"")

In "Auswertung nach Monat" dann:

Code:

=SUMMENPRODUKT((TEXT(Daten!$F$2:$F$14411;"MMJJ")=TEXT(A1;"MMJJ"))*(Daten!$D$2:$D$14411=A4)*(Daten!$H$2:$H$14411=D4)*(Daten!$C$2:$C$14411))

Code:

=SUMMENPRODUKT((TEXT(Daten!$F$2:$F$14411;"MMJJ")=TEXT(A1;"MMJJ"))*(Daten!$D$2:$D$14411=A4)*(Daten!$H$2:$H$14411=G4)*(Daten!$C$2:$C$14411))

Gruß,
steve1da

 

Jo, sehr schön.
Vielen Dank, läuft ;)