Office: (Office 2016 Mac) SummeWenn? Sverweis? Summe aus Zahlen mit bestimmten Eigenschaften

Guten Tag,

ich muss für meinen Vater eine Excel Tabelle erstellen.
Diese soll einzelne Subunternehmer auflisten und die Bauvorhaben an denen Sie arbeiten bzw. wie viel Geld sie dafür bekommen.
Es kann auch vorkommen, dass zwei Subunternehmer an einem Bauvorhaben arbeiten

Im Beispiel sind 2 Subunternehmer: Francu und Uka. Eigentlich sind es aber ca 10, deswegen sind meine bisherigen Lösungen wohl etwas kompliziert.

Bis jetzt habe ich in der Zusammenfassung die Auflistung der Kostenstellen geschafft und zusätzlich die Duplikate gelöscht.

Kostenstelle:
Zeile 2: =MIN(Francu:Uka!A:A)
Zeile 3: =WENN(MAX(Francu:Uka!A:A)=MAX(A$2:A2);"";KGRÖSSTE(Francu:Uka!A:A;ZÄHLENWENN(Francu!A:A;">"&A2)+ZÄHLENWENN(Uka!A:A;">"&A2)))

Dann habe ich mittels SVerweis den Namen der Kostenstelle zugewiesen. Diese werden händisch bei den einzelnen Subunternehmern reingeschrieben und dann per SVerweis in die Zusammenfassung übernommen.

=wenn(istnv(SVERWEIS(A2;INDIREKT("'"&INDEX({"Francu";"Uka"};VERGLEICH(1;(ZÄHLENWENN(INDIREKT("'"&{"Francu";"Uka"}&"'!A:A");A2)>0)+0;0))&"'!A:Z");4;0));"";SVERWEIS(A2;INDIREKT("'"&INDEX({"Francu";"Uka"};VERGLEICH(1;(ZÄHLENWENN(INDIREKT("'"&{"Francu";"Uka"}&"'!A:A");A2)>0)+0;0))&"'!A:Z");4;0))

Jetzt stecke ich aber irgendwie fest.
Für jeden Subunternehmer sollen alle geprüften Rechnungsbeträge UND die Sicherheitseinbehalte für die jeweiligen Bauvorhaben summiert werden und in die Zusammenfassung eingetragen werden.

Das anschließende Summieren des Gesamtbetrags ist ja dann kein Problem mehr, aber kann mir dafür irgendjemand helfen?

Grüße
Stefan

PS: Das Beispiel ist im Anhang.

 

Hallo,

hier mal die gängigen Varianten, die ich kenne:
=SUMMENPRODUKT((Francu!D2:E16=B2)*Francu!F2:G16)
=SUMME((Francu!D2:E16="Bauvorhaben 1")*Francu!F2:G16)
=SUMMEWENN(Francu!D2:E16;"Bauvorhaben 1";Francu!F2:F16)+SUMMEWENN(Francu!D2:E16;"Bauvorhaben 1";Francu!G2:G16)

wobei bei mir komischerweise nur die letzte Variante funktioniert... Verstehe ich gerade auch nicht.

 

Vielen Dank erstmal für die schnelle Antwort.

Hab direkt die 3te Variante probiert und sie würde mir das richtige anzeigen, aber macht das ganze unflexibel, dadurch dass in die Formel "Bauvorhaben 1" eingegeben werden muss.

Hast du dafür noch eine Idee?

 

Hola,

wird der Einbehalt abgezogen?
Wenn ja, teste mal:

Code:

=SUMMENPRODUKT((INDIREKT(C$1&"!D2:D16")=$B2)*(INDIREKT(C$1&"!F2:F16")-INDIREKT(C$1&"!G2:G16")))

Gruß,
steve1da

 

Danke auch dir steve1da (:
Ne, der Einbehalt wird addiert. Muss noch n wenig testen, aber scheint zu funktionieren wenn ich einfach das minus mit einem plus tausche! Vielen Dank !!!

 

Hola,

Code:

=SUMMENPRODUKT((INDIREKT(C$1&"!D2:D16")=$B2)*(INDIREKT(C$1&"!F2:G16")))

Gruß,
steve1da

 

So läufts! Vielen Dank! (:

 

HEy steve1da,

kannst du mir erklären für was das INDIREKT hier verwendet wird?

Gruß

 

Hola,

durch Indirekt() wird hier auf den Zellinhalt von C1 verwiesen. Dort steht der gesuchte Name, der auch gleichzeitig der Blattname ist, in dem gesucht werden soll.

Gruß,
steve1da

 

Ah jetzt habe ich es auch verstanden, hat bei mir einen Moment gedauert ;)

Danke fürs Erklären!