Office: (Office 365) Summewenns mit Datum und Zwei Buchstaben eingrenzen

Guten Abend Zusammen,

ich versuche aus einer Tabelle mit Summewenns (sumifs) die Beträge vom Kalendermonat abweichend zu errechnen. Das funktioniert mittlerweile auch.
Da das Datum über den Bericht mit 11.04.23 angegeben wird habe ich eine Hilfsspalte eingefügt und umgewandelt. Ich weiß nicht ob es auch einfacher ginge ohne Hilfsspalte?
Jetzt hätte ich gerne für die Umsatzsteuer-ID'en noch nur nach alles fuer EU außer DE gefiltert und da hakt es, d.h. ohne CH, RS, DE.
Müsste ich hier vielleicht eher Sumproduct nehmen? Mit der kenne ich mich allerdings noch nicht richtig aus. Habe sie in Zelle D9 probiert. Kam #Value! raus.
Viele Gruesse und
einen schoenen Abend noch
Matthias

 

Hola,
#WERT bekommst du, weil im Bereich der summiert werden soll Text steht - die Überschrift.
Und dann wäre die Syntax:
=SUMMENPRODUKT((Sheet0!AJ2:AJ367)*(Sheet0!O2:O367>='Overview ESL''s 2023_24'!A9)*(Sheet0!O2:O367<='Overview ESL''s 2023_24'!B9))
Hier ginge das aber auch mit Summewenns().
Wo da allerdings DE, CH, RS stehen soll, keine Ahnung.
Gruß,
steve1da

 

Vielen Dank. Entschuldige, das hatte ich vergessen zu erwaehnen. In Spalte U stehen die Umsatzsteuer-ID'en, die mit DE, CH, RS und dann den weitereren zu filternden anfangen.

 

=SUMMENPRODUKT((Sheet0!$O$2:$O$367>=A3)*(Sheet0!$O$2:$O$367<=B3)*(LINKS(Sheet0!$U$2:$U$367;2)<>"de")*(LINKS(Sheet0!$U$2:$U$367;2)<>"ch")*(LINKS(Sheet0!$U$2:$U$367;2)<>"rs")*(Sheet0!$AJ$2:$AJ$367))

 

Das geht natürlich auch weiterhin mit Summewenns(), da wären die Bedingungen dann:
"<>rs*"
"<>de*"
"<>ch*"

 

Super, vielen Dank nochmal.

 

Danke, gerade erst gesehen: Geht es dann so?
=SUMIFS(Sheet0!AJ:AJ,Sheet0!O:O,">="&TEXT(DATE(YEAR($A9),MONTH($A9),DAY(A9)),"dd/mm/yyyy"),Sheet0!O:O,"<="&TEXT(DATE(YEAR($B9),MONTH($B9),DAY(B9)),"dd/mm/yyyy"),Sheet0!U:U,"<>RS*",Sheet0!U:U,"DE*",Sheet0!U:U,"CH*") oder muesste ich mehrere Formeln und addieren? Es kommt momentan 0 raus

 

Wenn dann musst du schon alle Bedingungen gleich schreiben:
=SUMIFS(Sheet0!AJ:AJ,Sheet0!O:O,">="&TEXT(DATE(YEAR($A9),MONTH($A9),DAY(A9)),"dd/mm/yyyy"),Sheet0!O:O,"<="&TEXT(DATE(YEAR($B9),MONTH($B9),DAY(B9)),"dd/mm/yyyy"),Sheet0!U:U,"<>RS*",Sheet0!U:U,"<>DE*",Sheet0!U:U,"<>CH*")

 

Hallo,

oder einfacher (ohne doppelte Datumskonversion):
=SUMIFS(Sheet0!AJ:AJ,
Sheet0!O:O,">="&TEXT($A9,"dd/mm/yyyy"), Sheet0!O:O,"<="&TEXT($B9,"dd/mm/yyyy"),
Sheet0!U:U,"<>RS*",Sheet0!U:U,"<>DE*",Sheet0!U:U,"<>CH*")
oder noch einfacher:
=SUMIFS(Sheet0!AJ:AJ,
Sheet0!O:O,">="&$A9, Sheet0!O:O,"<="&$B9,
Sheet0!U:U,"<>RS*",Sheet0!U:U,"<>DE*",Sheet0!U:U,"<>CH*")

 

Oh man, danke, das habe ich natürlich nicht gesehen.