Office: (Office 365) summewenns ohne negative Werte

Hallo,
ich bräuche mal wieder eure Hilfe, ich habe folgende Formel:

=WENN(A2="";"";SUMMEWENNS(Rechnung[Brutto];Rechnung[Kunde/Firma];Firmenumsätze!A2))

aber es soll nur Beträge summiert werden die >0 sind keine negativen

was mache ich gedanklich gerade sehr falsch?

danke für eure Hilfe
gruss Stephan

 

Hi,

du brauchst doch nur eine weitere Bedingung in dein SUMMEWENNS mit einzufügen:

=WENN(A2="";"";SUMMEWENNS(Rechnung[Brutto];Rechnung[Kunde/Firma];Firmenumsätze!A2;Rechnung[Brutto];">0"))

 

Danke,
hab den Wald wie immer vor lauter Bäumen nicht gesehen
gruss stephan

 

habe doch noch eine Frage ich möchte das auch via Teilergebnis bei gefilterten Werten aus Tabelle machen, leider fliegen mir egal was ich mache die Fehlermeldungen um die Ohren: hier mein letzter Versuch mal:

=SUMMENPRODUKT(TEILERGEBNIS(109;Rechnung[Brutto]);"> 0")

=TEILERGEBNIS(109;(SUMMEWENN((Rechnung[Brutto]);">0")

gruss Stephan

 

Hallo,
mit der Formel bekomme ich es die Summe hin die nur positivie Werte hat:

=SUMMEWENN(Rechnung[Brutto];">0")

aber nicht wenn ich gefiltert habe, da möchte ich nur die Werte von der Filterung summiert haben.

gruss stephan

 

Hola,
schau mal hier:
SUMMEWENN in einer gefilterten Liste
An Stelle von ="x" muss dann natürlich >0 hin.
Gruß,
steve1da

 

Danke steve1da,

ich bin wohl zu blöd das umzuschreiben:
=SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("E"&ZEILE(T4:T999)))*(H4:H999>0))
kommt immer 0 als Wert
anbei doch mal die Tabelle
im Moment liegt es auf E1 soll aber unter H1 später stehen, das andere sind meine Tests ...
gruss stephan

 

=SUMMENPRODUKT(TEILERGEBNIS(109;INDIREKT("H"&ZEILE(4:281)))*(H4:H281>0))

 

Hi,

mal zum Nachdenken: was könnte wohl die Summe aus z.B. "Monttoni" und "Ekici" sein?

Ich würde sowieso kein TEILERGEBNIS(109;INDIREKT(...)) verwenden, da mir das wegen INDIREKT zu viel Rechenaufwand verursachen würde. Statt dessen ist es sinnvoller eine weitere Spalte in die Tabelle einzufügen, die ich üblicherweise einfach "sichtbar?" nenne. Diese bekommt die Formel =TEILERGEBNIS(103;[@[Pos.]]) wobei als zweiter Parameter eine Zelle der selben Zeile in einer Spalte verwendet wird, die auf alle Fälle gefüllt ist. Damit hast du nun eine Spalte, in der eine 1 steht, falls die Zeile sichtbar ist und eine 0, falls sie nicht sichtbar ist, Somit kann man alle xxxWENNS()-Funktionen (oder auch Summenprodukt) verwenden um gefilterte Daten auszuwerten.

Übrigens, die Formel in der Spalte POS. =WENNFEHLER(BEREICH.VERSCHIEBEN(A4;-1;0)+1;1) ist genauso unglücklich. Denn BEREICH.VERSCHIEBEN ist ebenso wie INDIREKT volatil und wird daher ständig neu berechnet, Hier wäre es geschickter =SUMME(A3;1) zu verwenden. Das funktioniert allerdings nur, wenn zwischendurch keine Zeilen gelöscht oder eingefügt werden. Falls du das möchtest, dann bietet sich die Formel =ZEILE()-Rechnung[#Kopfzeilen] an.

Zur Formel in Spalte R.-Nr. =WENNFEHLER(BEREICH.VERSCHIEBEN(B4;Variablen!$B$3&"-"&-1;0)+1;Variablen!$B$3&"-"&Variablen!$B$2+ZEILE(A1)-1) Hier ist der BEREICH.VERSCHIEBEN()-Teil Humbug, da er immer zu einen Fehler führt und daher sowieso nur der Fehler-Teil ausgeführt wird. Wieso? Weil - egal was in Variablen!$B$3 steht - die Verknüpfung von "-" mit -1 zu einem Text führt, den Excel nicht in eine Zahl überführen kann. Dadurch liefert BEREICH.VERSCHIEBEN einen #WERT!-Fehler. Und wie gesagt, sollte man BEREICH.VERSCHIEBEN so oder so meiden. Ebenso ist es nicht gerade geschickt, hier die Rechnungsnummer aufgrund der Position in der Tabelle zu berechnen. Die Nummer muss doch fest mit Kunde und Datum verbunden sein, oder nicht?

 

Danke für eure Hilfe.
Sorry bin grad gewesen, lag mit einer Grippe im Bett.
Gruss Stephan