Office: (Office 2010) SummewennS und Teilergebnis

Einen schönen guten Tag,

ich habe mal wieder eine kleine Frage.

Ich möchte gerne in einer Tabelle mehrere Summen unter 2 Bedingungen bilden aus einer Zeile mit Autofilter aus einer anderen Tabelle in einer anderen Mappe.

Genauer gesagt möchte ich also "SummewennS" und "TEILERGEBNIS" kombinieren.

Ich habe im Internet schon ein paar Lösungen für Summewenn und Teilergebnis gefunden, allerdings nur für 1 Bedingung

Meist war es in dieser Art: =SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("A"&ZEILE(2:1000)))*(A2:A1000="x")


Außerdem habe ich noch das Problem das sich die Formeln auf eine andere Mappe beziehen

Hier mal meine Formel:

=SUMMEWENNS(Daten[Zeitabstand];Daten[Material];[Material];Daten[Abmaße];[Abmaße])*24

bzw in Zeilenform:

=SUMMEWENNS(Daten!A:A;Daten!B:B;A:A;Daten!C:C;B:B)*24

[table="width: 500"]
[tr]
[td]Summe_Bereich: [/td]
[td]Daten!A:A[/td]
[td]Daten[Zeitabstand]
[/td]
[/tr]
[tr]
[td]Kriterien_Bereich1:[/td]
[td]Daten!B:B[/td]
[td]Daten[Material]
[/td]
[/tr]
[tr]
[td]Kriterien1:[/td]
[td]A:A[/td]
[td][Material][/td]
[/tr]
[tr]
[td]Kriterien_Bereich2:[/td]
[td]Daten!C:C[/td]
[td]Daten[Abmaße][/td]
[/tr]
[tr]
[td]Kriterien2:[/td]
[td]B:B[/td]
[td][Abmaße][/td]
[/tr]
[/table]

Die 24 ist ein Faktor um von Tagen in Stunden umzurechnen notfalls kann ich das aber in einer weiteren Zeile

Eine Beispieldatei ist angehängt


Mit freundlichem Gruße

Rupes

 

Hola,

Code:

 =SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("A"&ZEILE(2:1000)))*(A2:A1000="x")*(B2:B1000="y"))

So sähe das aus wenn man 2 Bedingungen haben möchte.

Gruß,
steve1da

 

Hallo Steve,

vielen Dank für die Schnelle Antwort, das mit der 2. Bedingung ist also doch so einfach wie ich es mir gedacht habe...

Jetzt stehe ich aber noch vor dem Problem mit dem Bezug auf die andere Tabelle:

In der Formel wird die Spalte ja mit ....INDIREKT("A"&ZEILE(2:1000) beschrieben Wenn ich jetzt aber die Gesamte A der Tabelle "Daten" haben möchte wie sähe das dann aus? (Meine Originaldatei ist über 106000 Zeilen* Lang)

Code:

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("Daten!A"&ZEILE([B]?:?[/B])))*(Daten!B:B=A:A)*(Daten!C:C=B:B))

Gruß

Rupes

 

Hola,

Summenprodukt sollte man nie über ganze Spalten laufen lassen - je genauer du das eingrenzen kannst, umso besser. Außerdem versuchst du Bereich mit Bereich zu vergleichen, Daten!C:C=B:B - das funktioniert so nicht weil man immer nur einen Bereich mit einem Kriterium vergleich kann, also z.B. Daten!C:C=A2.
Wenn du das eingrenzt auf z.B. 110000 Zeilen, sähe ?:? auch so aus: 2:110000.

Gruß,
steve1da

 

Hey,

Danke schon mal für den Tipp, ich nehme mal an das Summenprodukt zu viele Ressourcen frist wenn man es über die ganze Zeile laufen lässt oder? Bei der Datei die ich gerade bearbeite kein Problem. Aber ich habe noch eine weitere Datei wo automatisch neue Einträge generiert werden, da bleibt mir keine Wahl als es über die ganze Spalte laufen zu lassen, damit die neuen Einträge mit berechnet werden.


Dann wäre meine Formel jetzt also

Code:

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("Daten!A"&ZEILE(2:110000)))*(Daten!B:B=A2)*(Daten!C:C=B2))

Leider gibt mir Excel da nur #NV aus

Außerdem laufen die Zeilen in der Tabelle mit also in Zeile 3 ist es dann (3:110001) in 4 (4:110002) usw. ich möchte aber das er immer alle Spalten aufsummiert, sofern sie den Kriterien entsprechen

Gruß

Rupes

Den Anhang Beispiel Summwenns Teilergebnis.xlsx betrachten

 

Hola,

#NV erscheint, weil die Bereiche beim Summenprodukt nicht gleich groß sind. B:B ist die ganze Spalte, aber 2:110000 ist nur ein Teil - jeder Bereich muss gleich groß sein.
(2:110000) musst du ersetzen durch ($1:$1048576)

Gruß,
steve1da

 

Hey,

super vielen Dank! Das war mein Problem. auf $ vor der Spaltenzahl hätte ich auch selber kommen können... so oft wie ich das verwende.

Aber auf die gleichen Bereiche wäre ich nicht gekommen.

So funktioniert es:

Code:

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("Daten!A"&ZEILE($2:$110000)))*(Daten!B$2:B$110000=A3)*(Daten!C$2:C$110000=B3))*24

Komischerweise funktioniert es nicht in meiner eigentlichen Datei, wahrscheinlich habe ich irgendwo einen Tipfehler...

Code:

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("HBO!D"&ZEILE($2:$110000)))*(HBO!I$2:I$110000=A4)*(HBO!C$2:C$110000=B4))*24

Bei der Formel kommt überall 0 Raus es ist zum Haareraufen


EDIT: Wie erwartet war es ein Tippfehler, es funktioniert wunderbar, vielen vielen Dank, dein Name hält was er verspricht, du bewirkst hier Wunder!

Grüße

Rupes

 

Hola,

dann ist entweder mindestens eine der Bedingungen nicht erfüllt, oder in H2:H110000 stehen keine zu summierenden Zahlen sondern Text.

Gruß,
steve1da

 

Es war ein Tippfehler die letzte Bedingung war in HBO!L und nicht C, wurde korrigiert und nun läuft alles.


Vielen Dank und beste Grüße

Rupes