Office: Sverweis mehrere Ergebnisse anzeigen lassen

Hallo miteinander,

ich hänge mich hier auch mal dran mit der freundlichen Bitte um Unterstützung bei einem kleineren Problem:

Ich möchte aus einer sehr umfangreichen Tabelle gesuchte Daten in einer kompakten "druckbaren" Tabelle anzeigen lassen und verwende dafür die Formel aus #10. Funktioniert auch wunderbar, ich erhalte exakt die Datensätze die ich benötige. Vielen Dank schon mal dafür. Jetzt hat sich herausgestellt, dass die Daten aufgrund eines weiteren Kriteriums ausgewählt werden müssen und da komme ich gerade nicht weiter.

Meine jetzige Formel die die Daten nach nur einem Kriterium auswählt sieht so aus:
=WENNFEHLER(INDEX('Blatt A'!A:A;KKLEINSTE(WENN('Blatt A'!$Z$2:$Z$10000=Suche!$B$4;ZEILE($2:$10000));ZEILE('Blatt A'!A1)));"")
Das läuft wie es laufen soll.

Nun möchte ich gewisse Daten in Vorlage A ausgeben und andere in Vorlage B. Beide Vorlagen greifen dann auf die Stammdaten zu aber mit unterschiedlichen Bedingungen, sodass die Daten nur in einer der beiden Vorlagen auftauchen und nicht wie momentan in beiden. Das Kriterium dafür sollen bestehende Einträge einer Spalte in der Stammtabelle sein. Ich gehe davon aus, dass man dies mit einer weiteren Bedingung in der WENN Klausel umsetzen kann. Mein Versuch sieht so aus:
=WENNFEHLER(INDEX('Blatt A'!A:A;KKLEINSTE(WENN(UND('Blatt A'!$Z$2:$Z$10000=Suche!$B$4;'Blatt A'!$T$2:$T$10000='Blatt C'!B2);ZEILE($2:$10000));ZEILE('Blatt A'!A1)));"")

In Blatt C B2 steht die Bedingung die erfüllt werden muss damit in dieser Vorlage etwas angezeigt wird. Leider zeigt mir Excel bei dieser Formel den Zellinhalt von Blatt A A1 an, obwohl die Bedingung erfüllt sein sollte.

Sieht jemand wo ich etwas falsch gemacht habe? Ich hoffe ich habe die Problemstellung verständlich dargelegt... sry dass es so lang geworden ist..


VG

 

Hallo!

Teste mal bitte:

=WENNFEHLER(INDEX('Blatt A'!A:A;KKLEINSTE(WENN(('Blatt A'!$Z$2:$Z$10000=Suche!$B$4)*('Blatt A'!$T$2:$T$10000='Blatt C'!B2);ZEILE($2:$10000));ZEILE(A1)));"")

 

Hi,

vielen vielen Dank für die schnelle Hilfe! Mit deiner Schreibweise lässt sich die Formel um beliebig viele Kriterien erweitern, nur die Performance leidet unter den Prüfungen aber wen kümmerts ;)

Danke nochmal!

 

HI,

== erste einmal ein gesundes neues Jahr allen hier ===

ich habe ein ähnliches Problem, wie oben beschrieben, habe die angegebenen Formeln probiert, aber irgendwo habe ich einen Fehler.

Ich habe auf einem Datenblatt "Personal" eine Liste von Personen (Name, Alter) und möchte auf einem anderen Datenblatt eine Liste der Personen mit runden Geburtstagen (ab 60 aufwärts) haben. Namen stehen in Spalte B, das Alter in Spalte M.

Auf dem zweiten Datenblatt nutze ich nun die Formel (abgewandelt von oben):
=INDEX(Personal!B:B;KKLEINSTE(WENN(ODER(Personal!$M$2:$M$200=60;Personal!$M$2:$M$200=65);ZEILE(Personal!$2:$200));ZEILE($A1)))

Eine Fehlermeldung bekomme ich nicht, aber auch nicht das gewünschte Ergebnis ... es wird einfach der erste Name der Personalliste (steht in B2)ausgegeben, obwohl das Alter nicht stimmt.

Hat einer eine Idee, wo der Fehler stecken kann?

Eine Zusatzfrage habe ich dann noch: Geht das Abfragen mehrerer Werte eleganter als mit ODER?

 

Hola,

schreib in eine Hilfsspalte im Blatt Personal folgende Formel:

=(M2=60)+(M2=65)+(M2=70)

Du erhälst eine 1 wenn ein Alter passt. Auf diese 1 lässt du die Abfrage von oben laufen.

Gruß,
steve1da

 

Also so ähnlich habe ich es gemacht ... hab jetzt auf dem Datenblatt eine Spalte N, in der - falls ein runder Geburtstag vorliegt - ein "x" drinsteht. Hab dann meine Formel abgewandelt:

=INDEX(Personal!B:B;KKLEINSTE(WENN(Personal!$N$2:$N$200="x";ZEILE(Personal!$2:$200));ZEILE($A1)))

Leider ist das Ergebnis das Gleiche: er gibt nicht den ersten Namen mit rundem Geburtstag aus, sondern einfach den ersten der Liste ...

 

Hola,

hast du die Formel auch mit Strg Shift Enter abgeschlossen?

Gruß,
steve1da

 

Ja, habe ich ... er zeigt ja etwas an ... als ich es nur mit Enter gemacht habe, kam eine Fehlermeldung.

 

Hola,

ich habe das bei mir nachgebaut und es funktioniert. Kannst du dein Problem anhand einer Beispieldatei deutlich machen?

Gruß,
steve1da

 

Also ich habe mal die Datei vereinfacht ... der Fehler ist nach wie vor vorhanden ... verzweifel

 

Hola,

tja, was soll ich sagen. Deine Formel ist NICHT mit Strg-Shift-Enter abgeschlossen und die hier im Thread genannte funktioniert hervorragend!

Und das nur Brommel und nicht Erlinger ausgegeben wird, liegt daran, dass du den Bereich von Zeile 2-5 eingegrenzt hast - Erlinger steht in Zeile 6.

Gruß,
steve1da

 

Danke für den Wink mit dem Zaunpfahl ... habs verdient!

Da habe ich drei Tage probiert, den Hinweis gelesen ... und dann nicht genaue gelesen ... Shift != Space

Danke !!!