Office: Tabelle auswerten lassen

Hallo,

ich habe eine Exceltabelle mit den Preisen pro Kg von verschiedenen KEP-Diensten erstellt.

Gibt es nun eine Weg, dass ich in eine Zeile nur das Gewicht eines Paketes und in eine andere den Bestimmungsort eintrage, damit automatisch alle Möglichkeiten mit Preis ausgegeben werden? Würde das mit VB gehen?

Bisher habe ich ein extra Arbeitsblatt mit Hyperlinks für jedes Land zu jedem KEP-Dienst erstellt, aber das ist etwas umständlich^^

Gruß Gjonny

 

Hi kannst du ne Beispielmappe anhängen?

 

Jap, hier ist sie.

 

Hallo!

Mal ein Beispiel für UPS-Standard:
Gewicht in Q2
Zone in R2

Diese Formel errechnet den Preis:

=INDEX(B4:H37;VERGLEICH(Q2;A4:A37);VERGLEICH(R2;B3:H3;0))

 

Danke schön, funktioniert einwandfrei. Allerdings weiß ich nicht wofür die letzte 0 in der Formel steht..

Gruß Gjonny

 

Hallo!

Durch die Null wird Excel angewiesen, nach einer GENAUEN Übereinstimmung zu suchen (siehe Excel-Hilfe).

 

Ah ok. Soweit so gut, aber kann man die Formel auch so verändern dass sie bei einem Kommawert den nächst höheren Wert nimmt?

 

Hallo!

Das bezieht sich jetzt aber auf die Gewichte, oder nicht?
Teste mal

=INDEX(B4:H37;VERGLEICH(Q2;A4:A37)+(ZÄHLENWENN(A4:A37;Q2)=0);VERGLEICH(R2;B3:H3;0))

 

Richtig, zwecks den Gewichten und wieder funktioniert es einwandfrei *vor Freude dich mal drück*^^

Aber könntest du mir erklären wie das ZählenWenn vorgeht, bzw funktioniert? Irgendwie kapiere ich den Zusatz nicht so..

 

Hallo!

Die Funktion VERGLEICH (ohne die Null hinten) liefert bei keiner genauen Übereinstimmung die Position des nächstKLEINEREN Wertes zurück. Du möchtest aber die Position des nächstGRÖßEREN Wertes erhalten. Daher dieser Trick:

ZÄHLENWENN(A4:A37;Q2)
zählt, wie oft der Wert Q2 in A4:A37 auftaucht.
Taucht er NICHT auf, dann liefert ZÄHLENWENN(...)=0 den Wert WAHR (bzw. 1) zurück; es wird also auf eine Zeile tiefer verwiesen.
Taucht der Wert auf, dann ergibt ZÄHLENWENN(...)=0 den Wert FALSCH (bzw. 0) und alles bleibt beim alten.

Ab Excel2003 (vielleicht auch schon ab ExcelXP) gibt es im Menü Daten den Punkt "Formelauswertung" (oder so ähnlich). Hier kannst du die Formel Step-by-Step auswerten lassen.
In früheren Versionen kannst du einen dir unklaren Formelteil in der Bearbeitungszeile mit der Maus markieren, und diesen (Einzel-)Teil durch [F9] auswerten lassen.
(Danach die Bearbeitungszeile wieder mit [Esc] verlassen, sonst wird der markierte Teil durch den angezeigten Festwert ersetzt!!!)

 

Aha...jetzt ist mir alles klar, danke für alles :mrgreen:

 

Hab leider wieder ein kleines Problem:

Wenn ich ein Gewicht habe, das niedriger ist als das erste Vergleichsgewicht in der Preistabelle zeigt er mir nichts an.

Die Preistabelle fängt erst bei 5 Kg an und ich habe 4kg
Formel: =INDEX(PreiseB4:F7;VERGLEICH(C66;PreiseA4:A7);VERGLEICH(H68;PreiseB3:F3;0))

In C66 steht das Gewicht und H68 die Zone.

Selbst wenn ich im Vergleich für das Gewicht "+(ZÄHLENEWENN(PreiseA4:A7;C66)=0)" eingebe, funktioniert es nicht.

Mfg Sascha

 

Hallo!

Am einfachsten wäre es, wenn du in deiner Preistabelle statt den jeweiligen OBERgrenzen die jeweiligen UNTERgrenzen angibst, da der VERGLEICH ja den nächstKLEINEREN Wert sucht.
Ansonsten schau mal hier; da wird dieser Fall auch behandelt.

 

Leider kann ich die Obergrenze nicht zur Untergrenze machen...

Und leider funktioniert es noch nicht ganz. Zum besseren Verständnis häng ich mal die Excelliste an^^

Ich bekomme jetzt zwar immer den nächst größten oder gleichen wert ausgegeben, aber ich kann keinen zweiten Vergleich dranhängen der noch für die jeweilige Zone nötig ist..

 

Hab jetzt schon selber die Lösung gefunden und endlich kapier ich die Formeln :mrgreen:

Lösungsformel für angehängtes Beispiel in B13:

=INDEX(B3:F6;VERGLEICH(KGRÖSSTE(A3:A5;ZÄHLENWENN(A3:A5;">="&C10));A3:A5;0);VERGLEICH(C9;B2:F2;0))

Danke für die Hilfe :-D